[gentoo-commits] gentoo-x86 commit in x11-terms/gnome-terminal: gnome-terminal-3.6.2.ebuild ChangeLog

[Gilles Dartiguelongue (eva)]

eva         13/03/31 18:29:34

  Modified:             ChangeLog
  Added:                gnome-terminal-3.6.2.ebuild
  Log:
  Version bump, translation updates.
  
  (Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.266                x11-terms/gnome-terminal/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/ChangeLog?rev=1.266&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/ChangeLog?rev=1.266&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/ChangeLog?r1=1.265&r2=1.266

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v
retrieving revision 1.265
retrieving revision 1.266
diff -u -r1.265 -r1.266
--- ChangeLog	30 Mar 2013 17:22:27 -0000	1.265
+++ ChangeLog	31 Mar 2013 18:29:34 -0000	1.266
@@ -1,6 +1,12 @@
 # ChangeLog for x11-terms/gnome-terminal
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v 1.265 2013/03/30 17:22:27 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v 1.266 2013/03/31 18:29:34 eva Exp $
+
+*gnome-terminal-3.6.2 (31 Mar 2013)
+
+  31 Mar 2013; Gilles Dartiguelongue <eva@g.o>
+  +gnome-terminal-3.6.2.ebuild:
+  Version bump, translation updates.
 
   30 Mar 2013; Gilles Dartiguelongue <eva@g.o>
   gnome-terminal-2.32.1.ebuild, -gnome-terminal-3.4.1.1-r1.ebuild,



1.1                  x11-terms/gnome-terminal/gnome-terminal-3.6.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.6.2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-terminal-3.6.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.6.2.ebuild,v 1.1 2013/03/31 18:29:34 eva Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit autotools eutils gnome2

DESCRIPTION="The Gnome Terminal"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-3+"
SLOT="0"
IUSE=""
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux"

# FIXME: automagic dependency on gtk+[X]
RDEPEND="
	>=dev-libs/glib-2.26.0:2
	>=x11-libs/gtk+-3.3.17:3[X]
	>=x11-libs/vte-0.30.0:2.90
	>=gnome-base/gconf-2.31.3
	>=gnome-base/gsettings-desktop-schemas-0.1.0
	x11-libs/libSM
	x11-libs/libICE
"
# gtk+:2 needed for gtk-builder-convert, bug 356239
DEPEND="${RDEPEND}
	|| ( dev-util/gtk-builder-convert <=x11-libs/gtk+-2.24.10:2 )
	app-text/yelp-tools
	>=dev-util/intltool-0.40
	sys-devel/gettext
	virtual/pkgconfig

	gnome-base/gnome-common
"
# eautoreconf needs gnome-base/gnome-common

src_prepare() {
	# https://bugzilla.gnome.org/show_bug.cgi?id=692233
	epatch "${FILESDIR}/${PN}-3.6.1-no-gnome-doc-utils.patch"

	eautoreconf
	gnome2_src_prepare
}

src_configure() {
	DOCS="AUTHORS ChangeLog HACKING NEWS README"
	# FIXME: leave smclient configure unset until it accepts values from the
	# switch and not from GDK_TARGET, bug #363033
	gnome2_src_configure --with-gtk=3.0
}

pkg_postinst() {
	gnome2_pkg_postinst
	if [[ ${REPLACING_VERSIONS} < 3.6.1-r1 && ${REPLACING_VERSIONS} != 2.32.1-r1 &&
	      ${REPLACING_VERSIONS} != 3.4.1.1-r1 ]]; then
		elog "Gnome Terminal no longer uses login shell by default, switching"
		elog "to upstream default. Because of this, if you have some command you"
		elog "want to be run, be sure to have it placed in your ~/.bashrc file."
	fi
}