[gentoo-commits] gentoo-x86 commit in app-office/texmacs: ChangeLog texmacs-1.0.7.19.ebuild

[Andrey Grozin (grozin)]

grozin      13/03/28 13:41:15

  Modified:             ChangeLog
  Added:                texmacs-1.0.7.19.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha170/cvs/Linux i686, signed Manifest commit with key 0x3AFFCE974D34BD8C!)

Revision  Changes    Path
1.108                app-office/texmacs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/ChangeLog?r1=1.107&r2=1.108

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -u -r1.107 -r1.108
--- ChangeLog	23 Mar 2013 10:01:03 -0000	1.107
+++ ChangeLog	28 Mar 2013 13:41:15 -0000	1.108
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/texmacs
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v 1.107 2013/03/23 10:01:03 grozin Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v 1.108 2013/03/28 13:41:15 grozin Exp $
+
+*texmacs-1.0.7.19 (28 Mar 2013)
+
+  28 Mar 2013; Andrey Grozin <grozin@g.o> +texmacs-1.0.7.19.ebuild:
+  Version bump
 
 *texmacs-1.0.7.18 (23 Mar 2013)
 



1.1                  app-office/texmacs/texmacs-1.0.7.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/texmacs-1.0.7.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/texmacs-1.0.7.19.ebuild?rev=1.1&content-type=text/plain

Index: texmacs-1.0.7.19.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/texmacs-1.0.7.19.ebuild,v 1.1 2013/03/28 13:41:15 grozin Exp $

EAPI=4

inherit autotools eutils fdo-mime gnome2-utils

MY_P=${P/tex/TeX}-src

DESCRIPTION="Wysiwyg text processor with high-quality maths"
HOMEPAGE="http://www.texmacs.org/"
# Due to some changes at ftp.texmacs.org, files can no longer be fetched by wget,
# only by wget --no-passive-ftp
#SRC_URI="ftp://ftp.texmacs.org/pub/TeXmacs/tmftp/source/${MY_P}.tar.gz"
SRC_URI="http://dev.gentoo.org/~grozin/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
IUSE="imlib jpeg netpbm qt4 svg spell"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x86-interix ~amd64-linux ~x86-linux"

RDEPEND="dev-scheme/guile[deprecated]
	virtual/latex-base
	app-text/ghostscript-gpl
	media-libs/freetype
	x11-libs/libXext
	x11-apps/xmodmap
	qt4? ( dev-qt/qtgui:4 )
	imlib? ( media-libs/imlib2 )
	jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
	svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
	netpbm? ( media-libs/netpbm )
	spell? ( app-text/aspell )"
DEPEND="${RDEPEND}
	x11-proto/xproto"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# respect LDFLAGS, bug #338459
	epatch "${FILESDIR}"/${PN}-plugins.patch

	# dont update mime and desktop databases and icon cache
	epatch "${FILESDIR}"/${PN}-updates.patch

	eautoreconf
}

src_configure() {
	econf \
		$(use_with imlib imlib2) \
		--enable-optimize="${CXXFLAGS}" \
		$(use_enable qt4 qt)
}

src_install() {
	default
	domenu "${FILESDIR}"/TeXmacs.desktop
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}