[gentoo-commits] repo/gentoo:master commit in: net-im/telegram-desktop-bin/

[Michał Górny]

commit:     e8d2d24e879b8e34c719edeb333872338985d205
Author:     Henning Schild <henning <AT> hennsch <DOT> de>
AuthorDate: Wed Oct 24 10:49:14 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct 26 13:04:04 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e8d2d24e

net-im/telegram-desktop-bin: fix Icon in .desktop file

Closes: https://bugs.gentoo.org/667784
Signed-off-by: Henning Schild <henning <AT> hennsch.de>
Closes: https://github.com/gentoo/gentoo/pull/10212
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../telegram-desktop-bin-1.4.3-r1.ebuild           | 80 ++++++++++++++++++++++
 1 file changed, 80 insertions(+)

diff --git a/net-im/telegram-desktop-bin/telegram-desktop-bin-1.4.3-r1.ebuild b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.4.3-r1.ebuild
new file mode 100644
index 00000000000..a035e7e7871
--- /dev/null
+++ b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.4.3-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop gnome2-utils xdg
+
+DESCRIPTION="Official desktop client for Telegram (binary package)"
+HOMEPAGE="https://desktop.telegram.org"
+SRC_URI="
+	https://github.com/telegramdesktop/tdesktop/archive/v${PV}.tar.gz -> tdesktop-${PV}.tar.gz
+	amd64? ( https://updates.tdesktop.com/tlinux/tsetup.${PV}.tar.xz )
+	x86? ( https://updates.tdesktop.com/tlinux32/tsetup32.${PV}.tar.xz )
+"
+
+LICENSE="telegram"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+
+QA_PREBUILT="usr/lib/${PN}/Telegram"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=sys-apps/dbus-1.4.20
+	x11-libs/libX11
+	>=x11-libs/libxcb-1.10[xkb]
+	>=media-libs/fontconfig-2.13
+"
+
+S="${WORKDIR}/Telegram"
+
+src_prepare() {
+	sed -i -e 's/^Icon=telegram$/Icon=telegram-desktop/' "${WORKDIR}/tdesktop-${PV}"/lib/xdg/telegramdesktop.desktop || die
+	eapply_user
+}
+
+src_install() {
+	exeinto /usr/lib/${PN}
+	doexe "Telegram"
+	newbin "${FILESDIR}"/${PN}-r2 "telegram-desktop"
+
+	local icon_size
+	for icon_size in 16 32 48 64 128 256 512; do
+		newicon -s "${icon_size}" \
+			"${WORKDIR}/tdesktop-${PV}/Telegram/Resources/art/icon${icon_size}.png" \
+			telegram-desktop.png
+	done
+
+	dodir /etc/${PN}
+	insinto /etc/${PN}/
+	doins "${FILESDIR}"/fonts.conf
+
+	domenu "${WORKDIR}/tdesktop-${PV}"/lib/xdg/telegramdesktop.desktop
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+	einfo
+	einfo "Previous versions of ${PN} have created "
+	einfo "\"~/.local/share/applications/telegram.desktop\". These files"
+	einfo "conflict with the one shipped by portage and should be removed"
+	einfo "from all homedirs. (https://bugs.gentoo.org/618662)"
+	einfo
+	einfo "This versions fixes fontconfig issues that have been reported"
+	einfo "by several users. However, the fix might have side-effects on"
+	einfo "non-latin fonts. If you have font issues with this version just"
+	einfo "delete \"/etc/${PN}/fonts.conf\" and leave a comment here"
+	einfo "https://bugs.gentoo.org/664872"
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+}