[gentoo-commits] gentoo-x86 commit in app-backup/cyphertite: cyphertite-2.0.2-r1.ebuild ChangeLog cyphertite-2.0.2.ebuild

[Brian Evans (grknight)]

grknight    14/07/06 15:49:17

  Modified:             ChangeLog
  Added:                cyphertite-2.0.2-r1.ebuild
  Removed:              cyphertite-2.0.2.ebuild
  Log:
  Revision bump to fix CFLAGS and deps as per bug 516498 and bug 516500
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)

Revision  Changes    Path
1.2                  app-backup/cyphertite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	26 Jun 2014 00:56:07 -0000	1.1
+++ ChangeLog	6 Jul 2014 15:49:17 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for app-backup/cyphertite
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v 1.1 2014/06/26 00:56:07 grknight Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v 1.2 2014/07/06 15:49:17 grknight Exp $
+
+*cyphertite-2.0.2-r1 (06 Jul 2014)
+
+  06 Jul 2014; Brian Evans <grknight@g.o> +cyphertite-2.0.2-r1.ebuild,
+  -cyphertite-2.0.2.ebuild, files/cyphertite-2.0.2-fix-build.patch:
+  Revision bump to fix CFLAGS and deps as per bug 516498 and bug 516500
 
 *cyphertite-2.0.2 (26 Jun 2014)
 



1.1                  app-backup/cyphertite/cyphertite-2.0.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/cyphertite-2.0.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/cyphertite-2.0.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: cyphertite-2.0.2-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/cyphertite-2.0.2-r1.ebuild,v 1.1 2014/07/06 15:49:17 grknight Exp $

EAPI=5

inherit toolchain-funcs eutils multilib

DESCRIPTION="High Security, Zero-Knowledge Online Backup"
HOMEPAGE="https://www.cyphertite.com/"
SRC_URI="https://www.cyphertite.com/snapshots/source/${PV}/${PN}-full-${PV}.tar.gz"
LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="
	app-arch/xz-utils:0=
	dev-db/sqlite:3=
	>=dev-libs/openssl-1.0.1g:0=
	dev-libs/expat:0=
	dev-libs/libbsd:0=
	dev-libs/libedit:0=
	dev-libs/libevent:0=
	>=dev-libs/lzo-2.0:2=
	>=net-misc/curl-7.15.1:0=
	sys-libs/zlib:0=
"
RDEPEND="${DEPEND}"

src_prepare() {
	# Fix build system that assumes that modules are installed to the live system
	epatch "${FILESDIR}/${P}-fix-build.patch"
}

src_compile() {
	# Package has a home grown Makefile system. Make it work for Gentoo
	emake INCDIR="${S}" WARNFLAGS="-Wall" OPTLEVEL="" DEBUG="" CC=$(tc-getCC) \
		AR=$(tc-getAR) LOCALBASE="/usr" LIB.LINKSTATIC="" LIB.LINKDYNAMIC=""
}

src_install() {
	# Only the main executable needs to be installed
	emake -C cyphertite/cyphertite DESTDIR="${D}" LOCALBASE=usr LIBDIR=usr/$(get_libdir) LNFORCE=-s install

	# Fix up broken man symlinks
	rm "${D}"usr/share/man/man1/ct*.1 || die
	dosym /usr/share/man/man1/cyphertite.1.bz2 /usr/share/man/man1/ct.1.bz2
	dosym /usr/share/man/man1/cyphertitectl.1.bz2 /usr/share/man/man1/ctctl.1.bz2
	dosym /usr/share/man/man1/cyphertitefb.1.bz2 /usr/share/man/man1/ctfb.1.bz2
}