[gentoo-commits] gentoo-x86 commit in media-libs/hamlib: ChangeLog hamlib-1.2.15.ebuild

[Thomas Beierlein (tomjbe)]

tomjbe      12/02/06 13:12:06

  Modified:             ChangeLog
  Added:                hamlib-1.2.15.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.45/cvs/Linux x86_64)

Revision  Changes    Path
1.65                 media-libs/hamlib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/hamlib/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	28 Jan 2012 15:35:37 -0000	1.64
+++ ChangeLog	6 Feb 2012 13:12:06 -0000	1.65
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/hamlib
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/hamlib/ChangeLog,v 1.64 2012/01/28 15:35:37 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/hamlib/ChangeLog,v 1.65 2012/02/06 13:12:06 tomjbe Exp $
+
+*hamlib-1.2.15 (06 Feb 2012)
+
+  06 Feb 2012; Thomas Beierlein <tomjbe@g.o> +hamlib-1.2.15.ebuild:
+  Version bump
 
   28 Jan 2012; Pawel Hajdan jr <phajdan.jr@g.o> hamlib-1.2.14.ebuild:
   x86 stable wrt bug #400377



1.1                  media-libs/hamlib/hamlib-1.2.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/hamlib-1.2.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/hamlib-1.2.15.ebuild?rev=1.1&content-type=text/plain

Index: hamlib-1.2.15.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/hamlib/hamlib-1.2.15.ebuild,v 1.1 2012/02/06 13:12:06 tomjbe Exp $

EAPI="3"
PYTHON_DEPEND="python? 2"

inherit autotools-utils eutils multilib python

DESCRIPTION="Ham radio backend rig control libraries"
HOMEPAGE="http://sourceforge.net/apps/mediawiki/hamlib"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~x86 ~x86-fbsd"
IUSE="doc python tcl"

RESTRICT="test"

RDEPEND="
	=virtual/libusb-0*
	dev-libs/libxml2
	tcl? ( dev-lang/tcl )"

DEPEND=" ${RDEPEND}
	dev-util/pkgconfig
	dev-lang/swig
	>=sys-devel/libtool-2.2
	doc? ( app-doc/doxygen )"

DOCS=(AUTHORS NEWS PLAN README README.betatester README.developer TODO)

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	# fix hardcoded libdir paths
	sed -i -e "s#fix}/lib#fix}/$(get_libdir)/hamlib#" \
		-e "s#fix}/include#fix}/include/hamlib#" \
		hamlib.pc.in || die "sed failed"

	# make building of documentation compatible with autotools-utils
	sed -i -e "s/doc:/html:/g" doc/Makefile.am || die "sed failed"

	# fix tcl lib path
	epatch "${FILESDIR}"/${PN}-1.2.11-bindings.diff

	eautoreconf
}

src_configure() {
	local myeconfargs=(
		--libdir=/usr/$(get_libdir)/hamlib
		--disable-static
		--with-rpc-backends
		--without-perl-binding
		$(use_with python python-binding)
		$(use_enable tcl tcl-binding)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	use doc && autotools-utils_src_compile html
}

src_install() {
	use doc && HTML_DOCS=("${AUTOTOOLS_BUILD_DIR}/doc/html/")
	autotools-utils_src_install

	insinto /usr/$(get_libdir)/pkgconfig
	doins "${AUTOTOOLS_BUILD_DIR}"/hamlib.pc || die "doins failed"

	echo "LDPATH=/usr/$(get_libdir)/hamlib" > "${T}"/73hamlib
	doenvd "${T}"/73hamlib || die "doenvd failed"
}

pkg_postinst()  {
	use python && python_mod_optimize Hamlib.py
}

pkg_postrm()  {
	use python && python_mod_cleanup Hamlib.py
}