[gentoo-commits] gentoo-x86 commit in net-dialup/accel-ppp: ChangeLog accel-ppp-1.8.0.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    14/06/06 09:09:37

  Modified:             ChangeLog
  Added:                accel-ppp-1.8.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

Revision  Changes    Path
1.8                  net-dialup/accel-ppp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dialup/accel-ppp/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	5 Jun 2014 08:09:28 -0000	1.7
+++ ChangeLog	6 Jun 2014 09:09:36 -0000	1.8
@@ -1,6 +1,11 @@
 # ChangeLog for net-dialup/accel-ppp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dialup/accel-ppp/ChangeLog,v 1.7 2014/06/05 08:09:28 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dialup/accel-ppp/ChangeLog,v 1.8 2014/06/06 09:09:36 pinkbyte Exp $
+
+*accel-ppp-1.8.0 (06 Jun 2014)
+
+  06 Jun 2014; Sergey Popov <pinkbyte@g.o> +accel-ppp-1.8.0.ebuild:
+  Version bump
 
   05 Jun 2014; Sergey Popov <pinkbyte@g.o> accel-ppp-1.7.4.ebuild,
   accel-ppp-1.7.9999.ebuild:



1.1                  net-dialup/accel-ppp/accel-ppp-1.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/accel-ppp-1.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/accel-ppp/accel-ppp-1.8.0.ebuild?rev=1.1&content-type=text/plain

Index: accel-ppp-1.8.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/accel-ppp/accel-ppp-1.8.0.ebuild,v 1.1 2014/06/06 09:09:37 pinkbyte Exp $

EAPI=5

inherit cmake-utils linux-info multilib

DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
HOMEPAGE="http://accel-ppp.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc postgres radius shaper snmp valgrind"

RDEPEND="postgres? ( dev-db/postgresql-base )
	snmp? ( net-analyzer/net-snmp )
	dev-libs/libpcre
	dev-libs/openssl:0"
DEPEND="${RDEPEND}
	valgrind? ( dev-util/valgrind )"

DOCS=( README )
CONFIG_CHECK="~L2TP ~PPPOE ~PPTP"

src_prepare() {
	sed -i  -e "/mkdir/d" \
		-e "/echo/d" \
		-e "s: RENAME accel-ppp.conf.dist::" accel-pppd/CMakeLists.txt || die 'sed on accel-pppd/CMakeLists.txt failed'

	epatch_user
}

src_configure() {
	local libdir="$(get_libdir)"
	# There must be also dev-libs/tomcrypt (TOMCRYPT) as crypto alternative to OpenSSL
	# IPoE driver does not build properly :-(
	local mycmakeargs=(
		-DLIB_PATH_SUFFIX="${libdir#lib}"
		-DBUILD_PPTP_DRIVER=FALSE
		-DBUILD_IPOE_DRIVER=FALSE
		-DCRYPTO=OPENSSL
		$(cmake-utils_use debug MEMDEBUG)
		$(cmake-utils_use postgres LOG_PGSQL)
		$(cmake-utils_use radius RADIUS)
		$(cmake-utils_use shaper SHAPER)
		$(cmake-utils_use snmp NETSNMP)
		$(cmake-utils_use valgrind VALGRIND)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	use doc && dodoc -r rfc

	if use snmp; then
		insinto /usr/share/snmp/mibs
		doins accel-pppd/extra/net-snmp/ACCEL-PPP-MIB.txt
	fi

	newinitd "${FILESDIR}"/${PN}.initd ${PN}d
	newconfd "${FILESDIR}"/${PN}.confd ${PN}d

	dodir /var/log/accel-ppp
}