[gentoo-commits] gentoo-x86 commit in kde-base/kopete: metadata.xml ChangeLog kopete-4.4.2-r1.ebuild

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    10/04/04 15:51:47

  Modified:             metadata.xml ChangeLog
  Added:                kopete-4.4.2-r1.ebuild
  Log:
  [kde-base/kopete-4.4.2-r1] Revbumped kopete to apply a few fixes:
  Added upstream patch to fix issues with yahoo and stealth. Fixes bug 311445 - thanks to Navid Zamani <navid.zamani@××××××××××.com>.
  Replaced bonjour with zeroconf use flag. Fixes bug 307105 - thanks to Doktor Notor <notordoktor@×××××.com>.
  Added explicit dep on kde-base/qimageblitz. Fixes bug 307803.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 kde-base/kopete/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/metadata.xml?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/metadata.xml?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/metadata.xml?r1=1.16&r2=1.17

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kopete/metadata.xml,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- metadata.xml	15 Feb 2010 21:01:15 -0000	1.16
+++ metadata.xml	4 Apr 2010 15:51:47 -0000	1.17
@@ -37,6 +37,7 @@
 	<flag name="testbed">Enable the testbed protocol.</flag>
 	<flag name="winpopup">Enable pop-up messages sending on windows. (same as good old "net send" messages ;])</flag>
 	<flag name="yahoo">Enable yahoo protocol support.</flag>
+	<flag name="zeroconf">Enable Link-Local Messaging via the bonjour protocol.</flag>
 </use>
 <herd>kde</herd>
 </pkgmetadata>



1.246                kde-base/kopete/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/ChangeLog?rev=1.246&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/ChangeLog?rev=1.246&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/ChangeLog?r1=1.245&r2=1.246

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v
retrieving revision 1.245
retrieving revision 1.246
diff -u -r1.245 -r1.246
--- ChangeLog	31 Mar 2010 22:57:47 -0000	1.245
+++ ChangeLog	4 Apr 2010 15:51:47 -0000	1.246
@@ -1,6 +1,18 @@
 # ChangeLog for kde-base/kopete
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v 1.245 2010/03/31 22:57:47 spatz Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v 1.246 2010/04/04 15:51:47 jmbsvicetto Exp $
+
+*kopete-4.4.2-r1 (04 Apr 2010)
+
+  04 Apr 2010; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +kopete-4.4.2-r1.ebuild, +files/kopete-4.4.2-yahoo-stealth-fix.patch,
+  metadata.xml:
+  [kde-base/kopete-4.4.2-r1] Revbumped kopete to apply a few fixes:
+  Added upstream patch to fix issues with yahoo and stealth. Fixes bug
+  311445 - thanks to Navid Zamani <navid.zamani@××××××××××.com>.
+  Replaced bonjour with zeroconf use flag. Fixes bug 307105 - thanks to
+  Doktor Notor <notordoktor@×××××.com>.
+  Added explicit dep on kde-base/qimageblitz. Fixes bug 307803.
 
   31 Mar 2010; Dror Levin <spatz@g.o> -kopete-4.3.4.ebuild,
   -kopete-4.4.0.ebuild:



1.1                  kde-base/kopete/kopete-4.4.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/kopete-4.4.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/kopete-4.4.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: kopete-4.4.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/kopete-4.4.2-r1.ebuild,v 1.1 2010/04/04 15:51:47 jmbsvicetto Exp $

EAPI="3"

KMNAME="kdenetwork"
inherit kde4-meta

DESCRIPTION="KDE multi-protocol IM client"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="debug +handbook ssl v4l2"

# tests hang, last checked for 4.2.96
RESTRICT=test

# Available plugins
#
#	addbookmarks: NO DEPS
#	alias: NO DEPS (disabled upstream)
#	autoreplace: NO DEPS
#	contactnotes: NO DEPS
#	highlight: NO DEPS
#	history: NO DEPS
#	latex: virtual/latex as RDEPEND
#	nowlistening: NO DEPS
#	otr: libotr
#	pipes: NO DEPS
#	privacy: NO DEPS
#	statistics: dev-db/sqlite:3
#	texteffect: NO DEPS
#	translator: NO DEPS
#	urlpicpreview: NO DEPS
#	webpresence: libxml2 libxslt
# NOTE: By default we enable all plugins that don't have any dependencies
PLUGINS="+addbookmarks +autoreplace +contactnotes +highlight +history latex
+nowlistening otr +pipes +privacy +statistics +texteffect +translator
+urlpicpreview webpresence"

# Available protocols
#
#	gadu: net-libs/libgadu @since 4.3
#	groupwise: app-crypt/qca:2
#	irc: NO DEPS, probably will fail so inform user about it
#	jabber: net-dns/libidn app-crypt/qca:2 ENABLED BY DEFAULT NETWORK
#	jingle: media-libs/speex net-libs/ortp DISABLED BY UPSTREAM
#	meanwhile: net-libs/meanwhile
#	msn: libmsn == this is wlm plugin, we disable msn one
#	oscar: NO DEPS
#	qq: NO DEPS
#   telepathy: net-libs/decibel
#   testbed: NO DEPS
#	winpopup: NO DEPS
#	yahoo: NO DEPS
#	zeroconfg: (bonjour) NO DEPS
PROTOCOLS="gadu groupwise +jabber jingle meanwhile msn oscar qq skype sms
testbed winpopup yahoo zeroconf"

# disabled protocols
#   telepathy: net-libs/decibel
#   irc: NO DEPS

IUSE="${IUSE} ${PLUGINS} ${PROTOCOLS}"

COMMONDEPEND="
	dev-libs/libpcre
	$(add_kdebase_dep kdepimlibs)
	kde-base/qimageblitz
	>=x11-libs/qt-gui-4.4.0:4[mng]
	!aqua? ( x11-libs/libXScrnSaver )
	gadu? ( >=net-libs/libgadu-1.8.0[threads] )
	groupwise? ( app-crypt/qca:2 )
	jabber? (
		app-crypt/qca:2
		net-dns/libidn
	)
	jingle? (
		>=media-libs/mediastreamer-2.3.0
		media-libs/speex
		net-libs/ortp
	)
	meanwhile? ( net-libs/meanwhile )
	msn? ( >=net-libs/libmsn-4.0 )
	otr? ( >=net-libs/libotr-3.2.0 )
	statistics? ( dev-db/sqlite:3 )
	webpresence? ( dev-libs/libxml2 dev-libs/libxslt )
	v4l2? ( media-libs/libv4l )
"
RDEPEND="${COMMONDEPEND}
	latex? (
		media-gfx/imagemagick
		virtual/latex-base
	)
	sms? ( app-mobilephone/smssend )
	ssl? ( app-crypt/qca-ossl )
"
#	telepathy? ( net-libs/decibel )"
DEPEND="${COMMONDEPEND}
	!aqua? ( x11-proto/scrnsaverproto )
"

PATCHES=( "${FILESDIR}/${P}-yahoo-stealth-fix.patch" )

src_prepare() {
	sed -e "s:lib/mozilla:$(get_libdir)/mozilla:" \
		-i kopete/protocols/skype/skypebuttons/CMakeLists.txt || die "sed failed"
	sed -e '/set (LIBV4L2_REQUIRED TRUE)/s/TRUE/FALSE/' \
		-i kopete/CMakeLists.txt || die 'failed to make v4l2 optional'

	kde4-meta_src_prepare
}

src_configure() {
	local x x2
	# Handle common stuff
	mycmakeargs=(
		$(cmake-utils_use_with jingle GOOGLETALK)
		$(cmake-utils_use_with jingle LiboRTP)
		$(cmake-utils_use_with jingle Mediastreamer)
		$(cmake-utils_use_with jingle Speex)
		$(cmake-utils_use_with v4l2 LibV4L2)
	)
	# enable protocols
	for x in ${PROTOCOLS}; do
		[[ ${x/+/} = msn ]] && x2=Libmsn || x2=""
		mycmakeargs+=($(cmake-utils_use_with ${x/+/} ${x2}))
		[[ ${x/+/} = zeroconf ]] && x2=bonjour || x2=""
		mycmakeargs+=($(cmake-utils_use_with ${x/+/} ${x2}))
	done

	# enable plugins
	for x in ${PLUGINS}; do
		mycmakeargs+=($(cmake-utils_use_with ${x/+/}))
	done

	kde4-meta_src_configure
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	#if use telepathy; then
	#	elog "To use kopete telepathy plugins, you need to start gabble first:"
	#	elog "GABBLE_PERSIST=1 telepathy-gabble &"
	#	elog "export TELEPATHY_DATA_PATH='${EPREFIX}/usr/share/telepathy/managers/'"
	#fi

	if ! use ssl; then
		if use jabber || use msn; then # || use irc; then
			echo
			#elog "In order to use ssl in jabber, msn and irc you'll need to"
			elog "In order to use ssl in jabber and msn you'll need to"
			elog "install app-crypt/qca-ossl package."
			echo
		fi
	fi
}