[gentoo-commits] gentoo-x86 commit in dev-python/cython: cython-0.20.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    14/01/23 08:03:46

  Modified:             ChangeLog
  Added:                cython-0.20.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.106                dev-python/cython/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/ChangeLog?rev=1.106&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/ChangeLog?rev=1.106&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/ChangeLog?r1=1.105&r2=1.106

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v
retrieving revision 1.105
retrieving revision 1.106
diff -u -r1.105 -r1.106
--- ChangeLog	7 Dec 2013 10:26:12 -0000	1.105
+++ ChangeLog	23 Jan 2014 08:03:46 -0000	1.106
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/cython
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v 1.105 2013/12/07 10:26:12 hattya Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v 1.106 2014/01/23 08:03:46 radhermit Exp $
+
+*cython-0.20 (23 Jan 2014)
+
+  23 Jan 2014; Tim Harder <radhermit@g.o> +cython-0.20.ebuild:
+  Version bump.
 
   07 Dec 2013; Akinori Hattori <hattya@g.o> cython-0.19.1.ebuild:
   ia64 stable



1.1                  dev-python/cython/cython-0.20.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/cython-0.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/cython-0.20.ebuild?rev=1.1&content-type=text/plain

Index: cython-0.20.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/cython-0.20.ebuild,v 1.1 2014/01/23 08:03:46 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )

inherit distutils-r1 flag-o-matic

MY_PN="Cython"
MY_P="${MY_PN}-${PV/_/}"

DESCRIPTION="A Python to C compiler"
HOMEPAGE="http://www.cython.org/ http://pypi.python.org/pypi/Cython"
SRC_URI="http://www.cython.org/release/${MY_P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris ~x64-solaris"
IUSE="doc test"

RDEPEND=""
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? ( dev-python/numpy[$(python_gen_usedep python{2_6,2_7,3_2,3_3})] )"

S="${WORKDIR}/${MY_PN}-${PV%_*}"

python_compile() {
	if [[ ${EPYTHON} == python2* ]]; then
		local CFLAGS CXXFLAGS
		append-flags -fno-strict-aliasing
	fi

	# Python gets confused when it is in sys.path before build.
	local PYTHONPATH
	export PYTHONPATH

	distutils-r1_python_compile
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
		|| die "Tests fail with ${EPYTHON}"
}

python_install_all() {
	local DOCS=( CHANGES.rst README.txt ToDo.txt USAGE.txt )
	use doc && local HTML_DOCS=( docs/build/html/. )

	distutils-r1_python_install_all
}