[gentoo-commits] gentoo-x86 commit in gnome-extra/cinnamon: ChangeLog cinnamon-1.6.1.ebuild cinnamon-1.4_p1.ebuild cinnamon-1.4.ebuild cinnamon-1.4_p1-r1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/09/28 08:13:29

  Modified:             ChangeLog cinnamon-1.4_p1.ebuild
                        cinnamon-1.4.ebuild cinnamon-1.4_p1-r1.ebuild
  Added:                cinnamon-1.6.1.ebuild
  Log:
  Version bump to the stable 1.6 series (bug #435828, thanks to Anton Bolshakov). Lots of new features - nameable workspaces, new and improved applets, and a new file manager. See http://cinnamon.linuxmint.com/?p=207 and http://cinnamon.linuxmint.com/?p=216 for the release notes.
  
  (Portage version: 2.2.0_alpha132/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 gnome-extra/cinnamon/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	11 Sep 2012 08:27:57 -0000	1.16
+++ ChangeLog	28 Sep 2012 08:13:29 -0000	1.17
@@ -1,6 +1,17 @@
 # ChangeLog for gnome-extra/cinnamon
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v 1.16 2012/09/11 08:27:57 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v 1.17 2012/09/28 08:13:29 tetromino Exp $
+
+*cinnamon-1.6.1 (28 Sep 2012)
+
+  28 Sep 2012; Alexandre Rostovtsev <tetromino@g.o> cinnamon-1.4.ebuild,
+  cinnamon-1.4_p1.ebuild, cinnamon-1.4_p1-r1.ebuild, +cinnamon-1.6.1.ebuild,
+  +files/cinnamon-1.6.1-automagic-gnome-bluetooth.patch,
+  +files/cinnamon-1.6.1-optional-networkmanager.patch:
+  Version bump to the stable 1.6 series (bug #435828, thanks to Anton
+  Bolshakov). Lots of new features - nameable workspaces, new and improved
+  applets, and a new file manager. See http://cinnamon.linuxmint.com/?p=207 and
+  http://cinnamon.linuxmint.com/?p=216 for the release notes.
 
 *cinnamon-1.4_p1-r1 (11 Sep 2012)
 



1.2                  gnome-extra/cinnamon/cinnamon-1.4_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1.ebuild?r1=1.1&r2=1.2

Index: cinnamon-1.4_p1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- cinnamon-1.4_p1.ebuild	9 Sep 2012 00:31:58 -0000	1.1
+++ cinnamon-1.4_p1.ebuild	28 Sep 2012 08:13:29 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1.ebuild,v 1.1 2012/09/09 00:31:58 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1.ebuild,v 1.2 2012/09/28 08:13:29 tetromino Exp $
 
 EAPI="4"
 GCONF_DEBUG="no"
@@ -18,7 +18,7 @@
 
 SRC_URI="https://github.com/linuxmint/Cinnamon/tarball/${MY_PV} -> ${MY_P}.tar.gz"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 IUSE="+bluetooth +networkmanager"
 KEYWORDS="~amd64 ~x86"



1.5                  gnome-extra/cinnamon/cinnamon-1.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4.ebuild?r1=1.4&r2=1.5

Index: cinnamon-1.4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- cinnamon-1.4.ebuild	22 May 2012 03:22:44 -0000	1.4
+++ cinnamon-1.4.ebuild	28 Sep 2012 08:13:29 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4.ebuild,v 1.4 2012/05/22 03:22:44 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4.ebuild,v 1.5 2012/09/28 08:13:29 tetromino Exp $
 
 EAPI="4"
 GCONF_DEBUG="no"
@@ -15,7 +15,7 @@
 
 SRC_URI="https://github.com/linuxmint/Cinnamon/tarball/${PV} -> ${P}.tar.gz"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 IUSE="+bluetooth +networkmanager"
 KEYWORDS="~amd64 ~x86"



1.2                  gnome-extra/cinnamon/cinnamon-1.4_p1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1-r1.ebuild?r1=1.1&r2=1.2

Index: cinnamon-1.4_p1-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- cinnamon-1.4_p1-r1.ebuild	11 Sep 2012 08:27:57 -0000	1.1
+++ cinnamon-1.4_p1-r1.ebuild	28 Sep 2012 08:13:29 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1-r1.ebuild,v 1.1 2012/09/11 08:27:57 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.4_p1-r1.ebuild,v 1.2 2012/09/28 08:13:29 tetromino Exp $
 
 EAPI="4"
 GCONF_DEBUG="no"
@@ -18,7 +18,7 @@
 
 SRC_URI="https://github.com/linuxmint/Cinnamon/tarball/${MY_PV} -> ${MY_P}.tar.gz"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 IUSE="+bluetooth +networkmanager"
 KEYWORDS="~amd64 ~x86"



1.1                  gnome-extra/cinnamon/cinnamon-1.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.6.1.ebuild?rev=1.1&content-type=text/plain

Index: cinnamon-1.6.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.6.1.ebuild,v 1.1 2012/09/28 08:13:29 tetromino Exp $

EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_DEPEND="2:2.5"
PYTHON_USE_WITH="xml"

inherit autotools eutils gnome2 multilib pax-utils python

DESCRIPTION="A fork of GNOME Shell with layout similar to GNOME 2"
HOMEPAGE="http://cinnamon.linuxmint.com/"

MY_PV="${PV/_p/-UP}"
MY_P="${PN}-${MY_PV}"

SRC_URI="https://github.com/linuxmint/Cinnamon/tarball/${MY_PV} -> ${MY_P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
IUSE="+bluetooth +networkmanager"
KEYWORDS="~amd64 ~x86"

# gnome-desktop-2.91.2 is needed due to header changes, db82a33 in gnome-desktop
# latest gsettings-desktop-schemas is needed due to commit 602fa1c6
# latest g-c-c is needed due to https://bugs.gentoo.org/show_bug.cgi?id=360057
# libXfixes-5.0 needed for pointer barriers
# gnome-menus-3.2.0.1-r1 needed for new 10-xdg-menu-gnome
COMMON_DEPEND=">=dev-libs/glib-2.29.10:2
	>=dev-libs/gjs-1.29.18
	>=dev-libs/gobject-introspection-0.10.1
	x11-libs/gdk-pixbuf:2[introspection]
	>=x11-libs/gtk+-3.0.0:3[introspection]
	>=media-libs/clutter-1.7.5:1.0[introspection]
	app-misc/ca-certificates
	>=dev-libs/json-glib-0.13.2
	>=gnome-base/gnome-desktop-2.91.2:3[introspection]
	>=gnome-base/gsettings-desktop-schemas-2.91.91
	>=media-libs/gstreamer-0.10.16:0.10
	>=media-libs/gst-plugins-base-0.10.16:0.10
	net-libs/libsoup:2.4[introspection]
	>=sys-auth/polkit-0.100[introspection]
	>=x11-wm/muffin-1.0.5[introspection]

	dev-libs/dbus-glib
	dev-libs/libxml2:2
	x11-libs/pango[introspection]
	>=dev-libs/libcroco-0.6.2:0.6

	gnome-base/gconf:2[introspection]
	>=gnome-base/gnome-menus-3.2.0.1-r1:3[introspection]
	gnome-base/librsvg
	media-libs/libcanberra
	media-sound/pulseaudio

	>=x11-libs/startup-notification-0.11
	x11-libs/libX11
	>=x11-libs/libXfixes-5.0
	x11-apps/mesa-progs

	bluetooth? ( >=net-wireless/gnome-bluetooth-3.4[introspection] )
	networkmanager? (
		gnome-base/libgnome-keyring
		>=net-misc/networkmanager-0.8.999[introspection] )"
# Runtime-only deps are probably incomplete and approximate.
# Each block:
# 2. Introspection stuff + dconf needed via imports.gi.*
# 3. gnome-session is needed for gnome-session-quit
# 4. Control shell settings
# 5. accountsservice is needed for GdmUserManager (0.6.14 needed for fast
#    user switching with gdm-3.1.x)
# 6. caribou needed for on-screen keyboard
# 7. xdg-utils needed for xdg-open, used by extension tool
# 8. gconf-python needed for cinnamon-settings
# 9. gnome-icon-theme-symbolic needed for various icons
# 10. pygobject needed for menu editor
# 11. nemo - default file manager, tightly integrated with cinnamon
# 12. timedated or DateTimeMechanism implementation for cinnamon-settings
RDEPEND="${COMMON_DEPEND}
	>=gnome-base/dconf-0.4.1
	>=gnome-base/libgnomekbd-2.91.4[introspection]
	sys-power/upower[introspection]

	>=gnome-base/gnome-session-3.2.1-r1

	>=gnome-base/gnome-settings-daemon-2.91
	>=gnome-base/gnome-control-center-2.91.92-r1

	>=sys-apps/accountsservice-0.6.14[introspection]

	>=app-accessibility/caribou-0.3

	x11-misc/xdg-utils

	dev-python/dbus-python
	dev-python/gconf-python:2
	dev-python/imaging

	x11-themes/gnome-icon-theme-symbolic

	dev-python/pygobject:3

	gnome-extra/nemo

	|| (
		app-admin/openrc-settingsd
		>=sys-apps/systemd-30
		<gnome-base/gnome-settings-daemon-3.3.5 )

	networkmanager? (
		net-misc/mobile-broadband-provider-info
		sys-libs/timezone-data )"
DEPEND="${COMMON_DEPEND}
	>=sys-devel/gettext-0.17
	virtual/pkgconfig
	>=dev-util/intltool-0.40
	gnome-base/gnome-common
	!!=dev-lang/spidermonkey-1.8.2*"
# libmozjs.so is picked up from /usr/lib while compiling, so block at build-time
# https://bugs.gentoo.org/show_bug.cgi?id=360413

S="${WORKDIR}/linuxmint-Cinnamon-1359845"

pkg_setup() {
	DOCS="AUTHORS NEWS README"
	# Don't error out on warnings
	G2CONF="${G2CONF}
		--enable-compile-warnings=maximum
		--disable-schemas-compile
		--disable-jhbuild-wrapper-script
		$(use_with bluetooth)
		$(use_enable networkmanager)
		--with-ca-certificates=${EPREFIX}/etc/ssl/certs/ca-certificates.crt
		BROWSER_PLUGIN_DIR=${EPREFIX}/usr/$(get_libdir)/nsbrowser/plugins"
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# Fix automagic gnome-bluetooth dep, bug #398145
	epatch "${FILESDIR}/${PN}-1.6.1-automagic-gnome-bluetooth.patch"

	# Make networkmanager optional, bug #398593
	epatch "${FILESDIR}/${PN}-1.6.1-optional-networkmanager.patch"

	# Gentoo uses /usr/libexec
	sed -e "s:/usr/lib/gnome-session/gnome-session-check-accelerated:${EPREFIX}/usr/libexec/gnome-session-check-accelerated:" \
		-i "files/usr/share/gnome-session/sessions/cinnamon.session" || die "sed 1 failed"

	# Gentoo uses /usr/$(get_libdir), not /usr/lib even for python
	sed -e "s:/usr/lib/:/usr/$(get_libdir)/:" \
		-e 's:"/usr/lib":"/usr/'"$(get_libdir)"'":' \
		-i files/usr/bin/cinnamon-menu-editor \
		-i files/usr/bin/cinnamon-settings \
		-i files/usr/lib/cinnamon-menu-editor/Alacarte/config.py \
		-i files/usr/lib/cinnamon-menu-editor/Alacarte/MainWindow.py \
		-i files/usr/lib/cinnamon-settings/cinnamon-settings.py || die "sed 2 failed"
	if [[ "$(get_libdir)" != lib ]]; then
		mv files/usr/lib "files/usr/$(get_libdir)" || die "mv failed"
	fi

	if ! use bluetooth; then
		rm -rv files/usr/share/cinnamon/applets/bluetooth@××××××××.org || die
	fi

	if ! use networkmanager; then
		rm -rv files/usr/share/cinnamon/applets/network@××××××××.org || die
	fi

	eautoreconf
	gnome2_src_prepare

	# Drop G_DISABLE_DEPRECATED for sanity on glib upgrades; bug #384765
	# Note: sed Makefile.in because it is generated from several Makefile.ams
	sed -e 's/-DG_DISABLE_DEPRECATED//g' \
		-i src/Makefile.in browser-plugin/Makefile.in || die "sed 3 failed"
}

src_install() {
	gnome2_src_install
	python_convert_shebangs 2 "${ED}usr/bin/cinnamon-extension-tool" \
		"${ED}usr/bin/cinnamon-launcher" \
		"${ED}usr/bin/cinnamon-menu-editor" \
		"${ED}usr/bin/cinnamon-settings" \
		"${ED}usr/$(get_libdir)/cinnamon-settings/cinnamon-settings.py"

	# Required for gnome-shell on hardened/PaX, bug #398941
	pax-mark mr "${ED}usr/bin/cinnamon"
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_mod_optimize "/usr/$(get_libdir)/"cinnamon-{menu-editor,settings}

	if ! has_version '>=media-libs/gst-plugins-good-0.10.23' || \
	   ! has_version 'media-plugins/gst-plugins-vp8'; then
		ewarn "To make use of Cinnamon's built-in screen recording utility,"
		ewarn "you need to either install >=media-libs/gst-plugins-good-0.10.23"
		ewarn "and media-plugins/gst-plugins-vp8, or use dconf-editor to change"
		ewarn "apps.gnome-shell.recorder/pipeline to what you want to use."
	fi

	if ! has_version ">=x11-base/xorg-server-1.11"; then
		ewarn "If you use multiple screens, it is highly recommended that you"
		ewarn "upgrade to >=x11-base/xorg-server-1.11 to be able to make use of"
		ewarn "pointer barriers which will make it easier to use hot corners."
	fi

	if has_version "<x11-drivers/ati-drivers-12"; then
		ewarn "Cinnamon has been reported to show graphical corruption under"
		ewarn "x11-drivers/ati-drivers-11.*; you may want to use GNOME in"
		ewarn "fallback mode, or switch to open-source drivers."
	fi

	if has_version "media-libs/mesa[video_cards_radeon]"; then
		elog "Cinnamon is unstable under classic-mode r300/r600 mesa drivers."
		elog "Make sure that gallium architecture for r300 and r600 drivers is"
		elog "selected using 'eselect mesa'."
		if ! has_version "media-libs/mesa[gallium]"; then
			ewarn "You will need to emerge media-libs/mesa with USE=gallium."
		fi
	fi

	if has_version "media-libs/mesa[video_cards_intel]"; then
		elog "Cinnamon is unstable under gallium-mode i915/i965 mesa drivers."
		elog "Make sure that classic architecture for i915 and i965 drivers is"
		elog "selected using 'eselect mesa'."
		if ! has_version "media-libs/mesa[classic]"; then
			ewarn "You will need to emerge media-libs/mesa with USE=classic."
		fi
	fi
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup "/usr/$(get_libdir)/"cinnamon-{menu-editor,settings}
}