[gentoo-commits] gentoo-x86 commit in media-libs/libsdl: metadata.xml ChangeLog libsdl-1.2.13-r1.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    09/01/21 23:05:37

  Modified:             metadata.xml ChangeLog
  Added:                libsdl-1.2.13-r1.ebuild
  Log:
  move away from the no* use flags
  (Portage version: 2.1.6.4/cvs/Linux 2.6.27.8 i686)

Revision  Changes    Path
1.3                  media-libs/libsdl/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libsdl/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	23 Aug 2008 06:01:21 -0000	1.2
+++ metadata.xml	21 Jan 2009 23:05:37 -0000	1.3
@@ -20,8 +20,11 @@
 </longdescription>
   <use>
     <flag name="custom-cflags">Allow users to use any CFLAGS they like completely (at their own risk)</flag>
-    <flag name="noaudio">Allow users to disable audio support completely (at their own risk)</flag>
-    <flag name="nojoystick">Allow users to disable joystick support completely (at their own risk)</flag>
-    <flag name="novideo">Allow users to disable video support completely (at their own risk)</flag>
+    <flag name="noaudio">Allow users to disable audio support completely (at their own risk) (deprecated)</flag>
+    <flag name="nojoystick">Allow users to disable joystick support completely (at their own risk) (deprecated)</flag>
+    <flag name="novideo">Allow users to disable video support completely (at their own risk) (deprecated)</flag>
+    <flag name="audio">Allow users to disable audio support completely (at their own risk)</flag>
+    <flag name="joystick">Allow users to disable joystick support completely (at their own risk)</flag>
+    <flag name="video">Allow users to disable video support completely (at their own risk)</flag>
   </use>
 </pkgmetadata>



1.147                media-libs/libsdl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/ChangeLog?rev=1.147&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/ChangeLog?rev=1.147&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/ChangeLog?r1=1.146&r2=1.147

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v
retrieving revision 1.146
retrieving revision 1.147
diff -u -r1.146 -r1.147
--- ChangeLog	27 Sep 2008 17:02:41 -0000	1.146
+++ ChangeLog	21 Jan 2009 23:05:37 -0000	1.147
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libsdl
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.146 2008/09/27 17:02:41 armin76 Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.147 2009/01/21 23:05:37 mr_bones_ Exp $
+
+*libsdl-1.2.13-r1 (21 Jan 2009)
+
+  21 Jan 2009; Michael Sterrett <mr_bones_@g.o> metadata.xml,
+  +libsdl-1.2.13-r1.ebuild:
+  move away from the no* use flags
 
   27 Sep 2008; Raúl Porcel <armin76@g.o> libsdl-1.2.13.ebuild:
   arm/sh stable wrt #236249



1.1                  media-libs/libsdl/libsdl-1.2.13-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/libsdl-1.2.13-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsdl/libsdl-1.2.13-r1.ebuild?rev=1.1&content-type=text/plain

Index: libsdl-1.2.13-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/libsdl-1.2.13-r1.ebuild,v 1.1 2009/01/21 23:05:37 mr_bones_ Exp $

EAPI=2
inherit flag-o-matic toolchain-funcs eutils libtool autotools

DESCRIPTION="Simple Direct Media Layer"
HOMEPAGE="http://www.libsdl.org/"
SRC_URI="http://www.libsdl.org/release/SDL-${PV}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
# WARNING:
# if you disable the audio, video, joystick use flags or turn on the custom-cflags use flag
# in USE and something breaks, you pick up the pieces.  Be prepared for
# bug reports to be marked INVALID.
IUSE="oss alsa esd arts nas X dga xv xinerama fbcon directfb ggi svga aalib opengl libcaca +audio +video +joystick custom-cflags pulseaudio"

RDEPEND="audio? ( >=media-libs/audiofile-0.1.9 )
	alsa? ( media-libs/alsa-lib )
	esd? ( >=media-sound/esound-0.2.19 )
	arts? ( kde-base/arts )
	nas? (
		media-libs/nas
		x11-libs/libXt
		x11-libs/libXext
		x11-libs/libX11
	)
	X? (
		x11-libs/libXt
		x11-libs/libXext
		x11-libs/libX11
		x11-libs/libXrandr
	)
	directfb? ( >=dev-libs/DirectFB-0.9.19 )
	ggi? ( >=media-libs/libggi-2.0_beta3 )
	svga? ( >=media-libs/svgalib-1.4.2 )
	aalib? ( media-libs/aalib )
	libcaca? ( >=media-libs/libcaca-0.9-r1 )
	opengl? ( virtual/opengl virtual/glu )
	pulseaudio? ( media-sound/pulseaudio )"
DEPEND="${RDEPEND}
	nas? (
		x11-proto/xextproto
		x11-proto/xproto
	)
	X? (
		x11-proto/xextproto
		x11-proto/xproto
	)
	x86? ( || ( >=dev-lang/yasm-0.6.0 >=dev-lang/nasm-0.98.39-r3 ) )"

S=${WORKDIR}/SDL-${PV}

pkg_setup() {
	if use !audio || use !video || use !joystick ; then
		ewarn "Since you've chosen to turn off some of libsdl's functionality,"
		ewarn "don't bother filing libsdl-related bugs until trying to remerge"
		ewarn "libsdl with the audio, video, and joystick flags in USE."
		ewarn "You need to know what you're doing to selectively turn off parts of libsdl."
		epause 30
	fi
	if use custom-cflags ; then
		ewarn "Since you've chosen to use possibly unsafe CFLAGS,"
		ewarn "don't bother filing libsdl-related bugs until trying to remerge"
		ewarn "libsdl without the custom-cflags use flag in USE."
		epause 10
	fi
}

src_prepare() {
	# patches for bugs #40224 #145917 #198147 #217097
	epatch \
		"${FILESDIR}"/${PN}-1.2.13-libcaca-new-api.patch \
		"${FILESDIR}"/${PN}-1.2.11-sdl-config.patch \
		"${FILESDIR}"/${PN}-1.2.11-xinerama-head-0.patch \
		"${FILESDIR}"/${P}-pulseaudio.patch \
		"${FILESDIR}"/${P}-cld.patch

	./autogen.sh
	elibtoolize
}

src_configure() {
	local myconf=
	if [[ $(tc-arch) != "x86" ]] ; then
		myconf="${myconf} --disable-nasm"
	else
		myconf="${myconf} --enable-nasm"
	fi
	use custom-cflags || strip-flags
	use audio || myconf="${myconf} --disable-audio"
	use video \
		&& myconf="${myconf} --enable-video-dummy" \
		|| myconf="${myconf} --disable-video"
	use joystick || myconf="${myconf} --disable-joystick"

	local directfbconf="--disable-video-directfb"
	if use directfb ; then
		# since DirectFB can link against SDL and trigger a
		# dependency loop, only link against DirectFB if it
		# isn't broken #61592
		echo 'int main(){}' > directfb-test.c
		$(tc-getCC) directfb-test.c -ldirectfb 2>/dev/null \
			&& directfbconf="--enable-video-directfb" \
			|| ewarn "Disabling DirectFB since libdirectfb.so is broken"
	fi

	myconf="${myconf} ${directfbconf}"

	econf \
		--disable-dependency-tracking \
		--disable-rpath \
		--enable-events \
		--enable-cdrom \
		--enable-threads \
		--enable-timers \
		--enable-endian \
		--enable-file \
		--enable-cpuinfo \
		$(use_enable oss) \
		$(use_enable alsa) \
		$(use_enable esd) \
		$(use_enable pulseaudio) \
		$(use_enable arts) \
		$(use_enable nas) \
		$(use_enable X video-x11) \
		$(use_enable dga) \
		$(use_enable xv video-x11-xv) \
		$(use_enable xinerama video-x11-xinerama) \
		$(use_enable X video-x11-xrandr) \
		$(use_enable dga video-dga) \
		$(use_enable fbcon video-fbcon) \
		$(use_enable ggi video-ggi) \
		$(use_enable svga video-svga) \
		$(use_enable aalib video-aalib) \
		$(use_enable libcaca video-caca) \
		$(use_enable opengl video-opengl) \
		$(use_with X x) \
		--disable-video-x11-xme \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc BUGS CREDITS README README-SDL.txt README.CVS TODO WhatsNew
	dohtml -r ./
}