[gentoo-commits] gentoo-x86 commit in app-laptop/laptop-mode-tools: laptop-mode-tools-1.60.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    12/01/01 16:04:34

  Modified:             ChangeLog
  Added:                laptop-mode-tools-1.60.ebuild
  Log:
  Non maintainer version bump. Bug #359187. Thanks to Ondrej Grover <ondrej.grover@×××××.com>
  
  (Portage version: 2.2.0_alpha82/cvs/Linux x86_64)

Revision  Changes    Path
1.57                 app-laptop/laptop-mode-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog?rev=1.57&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog?rev=1.57&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog?r1=1.56&r2=1.57

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v
retrieving revision 1.56
retrieving revision 1.57
diff -u -r1.56 -r1.57
--- ChangeLog	1 Jan 2012 14:44:49 -0000	1.56
+++ ChangeLog	1 Jan 2012 16:04:34 -0000	1.57
@@ -1,6 +1,14 @@
 # ChangeLog for app-laptop/laptop-mode-tools
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v 1.56 2012/01/01 14:44:49 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v 1.57 2012/01/01 16:04:34 hwoarang Exp $
+
+*laptop-mode-tools-1.60 (01 Jan 2012)
+
+  01 Jan 2012; Markos Chandras <hwoarang@g.o>
+  +files/laptop-mode-tools-1.60-pm-utils-1.4.0.patch,
+  +laptop-mode-tools-1.60.ebuild:
+  Non maintainer version bump. Bug #359187. Thanks to Ondrej Grover
+  <ondrej.grover@×××××.com>
 
 *laptop-mode-tools-1.55-r5 (01 Jan 2012)
 



1.1                  app-laptop/laptop-mode-tools/laptop-mode-tools-1.60.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-laptop/laptop-mode-tools/laptop-mode-tools-1.60.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-laptop/laptop-mode-tools/laptop-mode-tools-1.60.ebuild?rev=1.1&content-type=text/plain

Index: laptop-mode-tools-1.60.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/laptop-mode-tools-1.60.ebuild,v 1.1 2012/01/01 16:04:34 hwoarang Exp $

EAPI=2
inherit eutils

MY_P=${PN}_${PV}

DESCRIPTION="Linux kernel laptop_mode user-space utilities"
HOMEPAGE="http://www.samwel.tk/laptop_mode/"
SRC_URI="http://www.samwel.tk/laptop_mode/tools/downloads/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="acpi apm bluetooth scsi"

RDEPEND="sys-apps/ethtool
	acpi? ( sys-power/acpid )
	apm? ( sys-apps/apmd )
	bluetooth? ( net-wireless/bluez )
	scsi? ( sys-apps/sdparm )
	sys-apps/hdparm"
DEPEND=""

S=${WORKDIR}/${MY_P}

src_prepare() {
	# Patching to avoid !sys-power/pm-utils depend wrt #327443
	epatch "${FILESDIR}"/${P}-pm-utils-1.4.0.patch
}

src_compile() { :; }

src_install() {
	DESTDIR="${D}" \
		INIT_D="none" \
		MAN_D="/usr/share/man" \
		ACPI="$(use acpi && echo force || echo disabled)" \
		PMU="$(false && echo force || echo disabled)" \
		APM="$(use apm && echo force || echo disabled)" \
		./install.sh || die

	dodoc Documentation/*.txt README || die
	newinitd "${FILESDIR}"/laptop_mode.init-1.4 laptop_mode

	# Commented out to avoid !sys-power/pm-utils depend wrt #327443
	# exeinto /etc/pm/power.d
	# newexe "${FILESDIR}"/laptop_mode_tools.pmutils laptop_mode_tools
}

pkg_postinst() {
	if  use acpi ||  use apm; then
		if use acpi; then
			daemon_name="acpid"
		elif use apm; then
			deamon_name="apmd"
		fi
		ewarn
		ewarn "To enable automatic power state event handling,"
		ewarn "e.g. enabling laptop_mode after unplugging the battery,"
		ewarn "both laptop_mode and the ${daemon_name} daemon"
		ewarn "must be added to a runlevel,"
		ewarn "		rc-update add laptop_mode default"
		ewarn "		rc-update add ${daemon_name} default"
		ewarn
	else
		ewarn
		ewarn "Without USE=\"acpi\" or USE=\"apm\" ${PN} can not"
		ewarn "automatically disable laptop_mode on low battery."
		ewarn
		ewarn "This means you can lose up to 10 minutes of work if running"
		ewarn "out of battery while laptop_mode is enabled."
		ewarn
		ewarn "Please see /usr/share/doc/${PF}/laptop-mode.txt.gz for further"
		ewarn "information."
		ewarn
	fi
}