[gentoo-commits] gentoo-x86 commit in dev-ml/findlib: ChangeLog findlib-1.2.6.ebuild

[Alexis Ballier (aballier)]

aballier    10/11/07 16:33:18

  Modified:             ChangeLog
  Added:                findlib-1.2.6.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

Revision  Changes    Path
1.64                 dev-ml/findlib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/findlib/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/findlib/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/findlib/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/findlib/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	5 Nov 2010 18:23:30 -0000	1.63
+++ ChangeLog	7 Nov 2010 16:33:18 -0000	1.64
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/findlib
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/findlib/ChangeLog,v 1.63 2010/11/05 18:23:30 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/findlib/ChangeLog,v 1.64 2010/11/07 16:33:18 aballier Exp $
+
+*findlib-1.2.6 (07 Nov 2010)
+
+  07 Nov 2010; Alexis Ballier <aballier@g.o> +findlib-1.2.6.ebuild:
+  version bump
 
   05 Nov 2010; Markos Chandras <hwoarang@g.o> findlib-1.2.5.ebuild:
   Stable on amd64 wrt bug #343751



1.1                  dev-ml/findlib/findlib-1.2.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/findlib/findlib-1.2.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/findlib/findlib-1.2.6.ebuild?rev=1.1&content-type=text/plain

Index: findlib-1.2.6.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/findlib/findlib-1.2.6.ebuild,v 1.1 2010/11/07 16:33:18 aballier Exp $

EAPI=2

inherit multilib

RESTRICT="installsources"

DESCRIPTION="OCaml tool to find/use non-standard packages."
HOMEPAGE="http://projects.camlcity.org/projects/findlib.html"
SRC_URI="http://download.camlcity.org/download/${P}.tar.gz"
IUSE="doc +ocamlopt tk"

LICENSE="MIT"

SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

DEPEND=">=dev-lang/ocaml-3.10[ocamlopt?,tk?]"
RDEPEND="${DEPEND}"

ocamlfind_destdir="/usr/$(get_libdir)/ocaml"
stublibs="${ocamlfind_destdir}/stublibs"

src_configure() {
	local myconf
	use tk && myconf="-with-toolbox"
	./configure -bindir /usr/bin -mandir /usr/share/man \
		-sitelib ${ocamlfind_destdir} \
		-config ${ocamlfind_destdir}/findlib/findlib.conf \
		${myconf} || die "configure failed"
}

src_compile() {
	emake all || die
	if use ocamlopt; then
		emake opt || die # optimized code
	else
		# If using bytecode we dont want to strip the binary as it would remove the
		# bytecode and only leave ocamlrun...
		export STRIP_MASK="*/bin/*"
	fi
}

src_install() {
	dodir `ocamlc -where`

	emake prefix="${D}" install || die

	dodir "${stublibs}"

	cd "${S}/doc"
	dodoc QUICKSTART README DOCINFO
	use doc && dohtml -r ref-html guide-html
}

check_stublibs() {
	local ocaml_stdlib=`ocamlc -where`
	local ldconf="${ocaml_stdlib}/ld.conf"

	if [ ! -e ${ldconf} ]
	then
		echo "${ocaml_stdlib}" > ${ldconf}
		echo "${ocaml_stdlib}/stublibs" >> ${ldconf}
	fi

	if [ -z `grep -e ${stublibs} ${ldconf}` ]
	then
		echo ${stublibs} >> ${ldconf}
	fi
}

pkg_postinst() {
	check_stublibs
}