[gentoo-commits] gentoo-x86 commit in net-im/bitlbee: metadata.xml ChangeLog bitlbee-3.0.ebuild

[Tim Harder (radhermit)]

radhermit    10/10/28 19:53:41

  Modified:             metadata.xml ChangeLog
  Added:                bitlbee-3.0.ebuild
  Log:
  Version bump (thanks to wired for helping). This version adds support for file transfers, OTR encryption, plugins, optional libpurple support, event handling using libevent, and many other updates. Added myself to the maintainer list.
  
  (Portage version: 2.2.0_alpha2/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  net-im/bitlbee/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/bitlbee/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	8 Sep 2010 14:03:39 -0000	1.6
+++ metadata.xml	28 Oct 2010 19:53:41 -0000	1.7
@@ -9,9 +9,17 @@
 		<email>wired@g.o</email>
 		<name>Alex Alexander</name>
 	</maintainer>
+	<maintainer>
+		<email>radhermit@g.o</email>
+		<name>Tim Harder</name>
+	</maintainer>
 	<use>
+		<flag name='libevent'>Use libevent for event handling</flag>
 		<flag name='nss'>Use NSS for SSL support in MSN and Jabber</flag>
-		<flag name='twitter'>Enabel Twitter protocol support</flag>
+		<flag name='otr'>Enable support for encrypted conversations</flag>
+		<flag name='plugins'>Enable support for plugins</flag>
+		<flag name='purple'>Use libpurple instead of the built-in IM protocol support</flag>
+		<flag name='twitter'>Enable Twitter protocol support</flag>
 	</use>
 	<longdescription>
 		Bitlbee as an IRC to IM gateway. It provides an irc server that allows



1.129                net-im/bitlbee/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/bitlbee/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	8 Sep 2010 14:03:39 -0000	1.128
+++ ChangeLog	28 Oct 2010 19:53:41 -0000	1.129
@@ -1,6 +1,16 @@
 # ChangeLog for net-im/bitlbee
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/ChangeLog,v 1.128 2010/09/08 14:03:39 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/ChangeLog,v 1.129 2010/10/28 19:53:41 radhermit Exp $
+
+*bitlbee-3.0 (28 Oct 2010)
+
+  28 Oct 2010; Tim Harder <radhermit@g.o> +bitlbee-3.0.ebuild,
+  +files/bitlbee-3.0-configure.patch, +files/bitlbee-3.0-jabber.patch,
+  metadata.xml:
+  Version bump (thanks to wired for helping). This version adds support for
+  file transfers, OTR encryption, plugins, optional libpurple support, event
+  handling using libevent, and many other updates. Added myself to the
+  maintainer list.
 
 *bitlbee-1.2.8 (08 Sep 2010)
 



1.1                  net-im/bitlbee/bitlbee-3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/bitlbee-3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/bitlbee/bitlbee-3.0.ebuild?rev=1.1&content-type=text/plain

Index: bitlbee-3.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/bitlbee-3.0.ebuild,v 1.1 2010/10/28 19:53:41 radhermit Exp $

EAPI="3"
inherit eutils toolchain-funcs confutils

DESCRIPTION="irc to IM gateway that support multiple IM protocols"
HOMEPAGE="http://www.bitlbee.org/"
SRC_URI="http://get.bitlbee.org/src/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="debug gnutls ipv6 +jabber libevent msn nss +oscar otr +plugins purple ssl test twitter +yahoo xinetd" # ldap - Bug 195758

COMMON_DEPEND="purple? ( net-im/pidgin )
	libevent? ( dev-libs/libevent )
	!libevent? ( >=dev-libs/glib-2.4 )
	msn? ( gnutls? ( net-libs/gnutls )
		!gnutls? ( nss? ( dev-libs/nss ) )
		!gnutls? ( !nss? ( ssl? ( dev-libs/openssl ) ) )
		)
	jabber? ( gnutls? ( net-libs/gnutls )
		!gnutls? ( nss? ( dev-libs/nss ) )
		!gnutls? ( !nss? ( ssl? ( dev-libs/openssl ) ) )
		)"
	# ldap? ( net-nds/openldap )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	test? ( dev-libs/check )"

RDEPEND="${COMMON_DEPEND}
	virtual/logger
	xinetd? ( sys-apps/xinetd )"

pkg_setup() {
	if use purple ; then
		elog "You have enabled libpurple support. This disables all the other"
		elog "    protocol modules, since everything is handled by libpurple."
		elog
	else
		elog "Support for all IM protocols are controlled by use flags."
		elog "    Make sure you've enabled the flags you want."
		elog
	fi

	confutils_require_any jabber msn oscar twitter yahoo purple

	# At the request of upstream, die if MSN Messenger support is enabled
	# but no SSL support has been enabled
	confutils_use_depend_any msn gnutls nss ssl

	if use jabber && ! use gnutls && ! use ssl ; then
		if use nss ; then
			ewarn ""
			ewarn "You have enabled nss and jabber"
			ewarn "but nss doesn't work with jabber"
			ewarn "Enable ONE of the following use instead"
			ewarn "flags: gnutls or ssl"
			ewarn ""
			die "nss with jabber doesn't work"
		fi
		elog ""
		elog "You have enabled support for Jabber but do not have SSL"
		elog "support enabled.  This *will* prevent bitlbee from being"
		elog "able to connect to SSL enabled Jabber servers.  If you need to"
		elog "connect to Jabber over SSL, enable ONE of the following use"
		elog "flags: gnutls or ssl"
		elog ""
	fi

	enewgroup bitlbee
	enewuser bitlbee -1 -1 /var/lib/bitlbee bitlbee
}

src_prepare() {
	sed -i \
		-e "s@/usr/local/sbin/bitlbee@/usr/sbin/bitlbee@" \
		-e "s/nobody/bitlbee/" \
		-e "s/}/	disable         = yes\n}/" \
		doc/bitlbee.xinetd || die "sed failed in xinetd"

	sed -i \
		-e "s@mozilla-nss@nss@g" \
		configure || die "sed failed in configure"

	epatch "${FILESDIR}"/${P}-configure.patch
	epatch "${FILESDIR}"/${P}-jabber.patch
}

src_configure() {
	# ldap hard-disabled for now
	local myconf="--ldap=0"

	# setup plugins, protocol, ipv6 and debug
	for flag in debug ipv6 msn jabber oscar plugins purple twitter yahoo ; do
		if use ${flag} ; then
			myconf="${myconf} --${flag}=1"
		else
			myconf="${myconf} --${flag}=0"
		fi
	done

	# set otr
	if use otr && use plugins ; then
		myconf="${myconf} --otr=plugin"
	else
		if use otr ; then
			ewarn "OTR support has been disabled automatically because it"
			ewarn "requires the plugins USE flag."
		fi
		myconf="${myconf} --otr=0"
	fi

	# setup ssl use flags
	if use gnutls ; then
		myconf="${myconf} --ssl=gnutls"
		einfo "Using gnutls for SSL support"
	elif use ssl ; then
		myconf="${myconf} --ssl=openssl"
		einfo "Using openssl for SSL support"
	elif use nss ; then
		myconf="${myconf} --ssl=nss"
		einfo "Using nss for SSL support"
	else
		myconf="${myconf} --ssl=bogus"
		einfo "You will not have any encryption support enabled."
	fi

	# set event handler
	if use libevent ; then
		myconf="${myconf} --events=libevent"
	else
		myconf="${myconf} --events=glib"
	fi

	# NOTE: bitlbee's configure script is not an autotool creation,
	# so that is why we don't use econf.
	./configure --prefix=/usr --datadir=/usr/share/bitlbee \
		--etcdir=/etc/bitlbee --strip=0 ${myconf} || die "econf failed"

	sed -i \
		-e "s/CFLAGS=.*$/CFLAGS=${CFLAGS}/" \
		-e "/^EFLAGS/s:=:&${LDFLAGS} :" \
		Makefile.settings || die "sed failed"
}

src_install() {
	emake install install-etc install-doc install-dev DESTDIR="${D}" ||
		die "install failed"

	keepdir /var/lib/bitlbee
	fperms 700 /var/lib/bitlbee
	fowners bitlbee:bitlbee /var/lib/bitlbee

	dodoc doc/{AUTHORS,CHANGES,CREDITS,FAQ,README}
	dodoc doc/user-guide/user-guide.txt
	dohtml -A xml doc/user-guide/*.xml
	dohtml -A xsl doc/user-guide/*.xsl
	dohtml doc/user-guide/*.html

	doman doc/bitlbee.8 doc/bitlbee.conf.5

	if use xinetd ; then
		insinto /etc/xinetd.d
		newins doc/bitlbee.xinetd bitlbee
	fi

	newinitd "${FILESDIR}"/bitlbee.initd bitlbee || die
	newconfd "${FILESDIR}"/bitlbee.confd bitlbee || die

	keepdir /var/run/bitlbee
	fowners bitlbee:bitlbee /var/run/bitlbee

	dodir /usr/share/bitlbee
	insinto /usr/share/bitlbee
	cd utils
	doins convert_purple.py bitlbee-ctl.pl
}

pkg_postinst() {
	chown -R bitlbee:bitlbee "${ROOT}"/var/lib/bitlbee
	chown -R bitlbee:bitlbee "${ROOT}"/var/run/bitlbee

	elog "The utils included in bitlbee are now located in /usr/share/bitlbee"
	elog
	elog "NOTE: The IRSSI script is no longer provided by BitlBee."
	elog
	elog "The bitlbeed init script has been replaced by bitlbee."
	elog "You must update your configuration."
}