[gentoo-commits] repo/proj/guru:dev commit in: net-im/nheko/

[Ronny Gutbrod]

commit:     358b20224f9df0285b2f050e1e88b34d0c8c3ed5
Author:     Ronny (tastytea) Gutbrod <gentoo <AT> tastytea <DOT> de>
AuthorDate: Sat Oct 16 16:19:54 2021 +0000
Commit:     Ronny Gutbrod <gentoo <AT> tastytea <DOT> de>
CommitDate: Sat Oct 16 16:19:54 2021 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=358b2022

net-im/nheko: Add image format dependencies.

GIF, JPEG, PNG.

Signed-off-by: Ronny (tastytea) Gutbrod <gentoo <AT> tastytea.de>

 net-im/nheko/nheko-0.9.0_pre20211003-r1.ebuild | 58 ++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/net-im/nheko/nheko-0.9.0_pre20211003-r1.ebuild b/net-im/nheko/nheko-0.9.0_pre20211003-r1.ebuild
new file mode 100644
index 000000000..ccf722579
--- /dev/null
+++ b/net-im/nheko/nheko-0.9.0_pre20211003-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+MY_COMMIT="c43c2bd4b9481f761e9f1b16453f0e7f5b1beabe"
+DESCRIPTION="Desktop client for Matrix using Qt and C++14"
+HOMEPAGE="https://github.com/Nheko-Reborn/nheko"
+SRC_URI="https://github.com/Nheko-Reborn/${PN}/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="video voip"
+REQUIRED_USE="video? ( voip )"
+
+MY_GST_V="1.18"
+RDEPEND="
+	app-text/cmark
+	>=dev-db/lmdb++-1.0.0
+	>=dev-libs/mtxclient-0.5.2_pre20210916
+	>=dev-libs/qtkeychain-0.12.0
+	dev-libs/spdlog
+	dev-qt/qtconcurrent:5
+	dev-qt/qtgraphicaleffects:5
+	dev-qt/qtgui:5[gif,jpeg,png]
+	dev-qt/qtmultimedia:5[qml]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsvg:5
+	voip? (
+		dev-qt/qtmultimedia:5[gstreamer]
+		>=media-plugins/gst-plugins-dtls-${MY_GST_V}
+		>=media-plugins/gst-plugins-meta-${MY_GST_V}[opus]
+		>=media-plugins/gst-plugins-srtp-${MY_GST_V}
+		>=media-plugins/gst-plugins-webrtc-${MY_GST_V}
+		video? (
+			>=media-libs/gst-plugins-base-${MY_GST_V}[opengl]
+			>=media-plugins/gst-plugins-meta-${MY_GST_V}[v4l,vpx]
+			>=media-plugins/gst-plugins-qt5-${MY_GST_V}
+			>=media-plugins/gst-plugins-ximagesrc-${MY_GST_V}
+			x11-libs/xcb-util-wm
+		)
+	)
+"
+DEPEND="
+	dev-cpp/nlohmann_json
+	${RDEPEND}
+"
+BDEPEND="dev-qt/linguist-tools:5"
+
+src_prepare() {
+	use voip || sed -i '/^pkg_check_modules(GSTREAMER/d' CMakeLists.txt || die
+
+	cmake_src_prepare
+}