[gentoo-commits] repo/gentoo:master commit in: sys-fs/f2fs-tools/

[Anthony G. Basile]

commit:     e0fee33fc6aa312e2ca62ace9c05cf2eafd64b97
Author:     Harry Kurn <alternate-se7en <AT> pm <DOT> me>
AuthorDate: Mon Aug 15 01:05:08 2022 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Tue Aug 16 13:51:21 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0fee33f

sys-fs/f2fs-tools: add live ebuild

Signed-off-by: Harry Kurn <alternate-se7en <AT> pm.me>
Signed-off-by: Anthony G. Basile <blueness <AT> gentoo.org>

 sys-fs/f2fs-tools/f2fs-tools-9999.ebuild | 38 ++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

diff --git a/sys-fs/f2fs-tools/f2fs-tools-9999.ebuild b/sys-fs/f2fs-tools/f2fs-tools-9999.ebuild
new file mode 100644
index 000000000000..106339c983bf
--- /dev/null
+++ b/sys-fs/f2fs-tools/f2fs-tools-9999.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit git-r3 autotools
+
+DESCRIPTION="Tools for Flash-Friendly File System (F2FS)"
+HOMEPAGE="https://git.kernel.org/cgit/linux/kernel/git/jaegeuk/f2fs-tools.git/about/"
+EGIT_REPO_URI="https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/${PN}.git"
+EGIT_BRANCH="dev"
+
+LICENSE="GPL-2"
+SLOT="0/9"
+IUSE="selinux"
+
+RDEPEND="
+	selinux? ( sys-libs/libselinux )
+	elibc_musl? ( sys-libs/queue-standalone )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	#This is required to install to /sbin, bug #481110
+	econf \
+		--bindir="${EPREFIX}"/sbin \
+		--disable-static \
+		$(use_with selinux)
+}
+
+src_install() {
+	default
+	find "${D}" -name "*.la" -delete || die
+}