[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: ChangeLog alsa-utils-1.0.23-r1.ebuild

[Pacho Ramos (pacho)]

pacho       10/09/07 11:57:12

  Modified:             ChangeLog
  Added:                alsa-utils-1.0.23-r1.ebuild
  Log:
  Revision bump to fix bug #299362 following upstream indications and applying upstream patches that will be included in 1.0.24.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.296                media-sound/alsa-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.296&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.296&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?r1=1.295&r2=1.296

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v
retrieving revision 1.295
retrieving revision 1.296
diff -u -r1.295 -r1.296
--- ChangeLog	16 Apr 2010 22:21:09 -0000	1.295
+++ ChangeLog	7 Sep 2010 11:57:12 -0000	1.296
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/alsa-utils
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.295 2010/04/16 22:21:09 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.296 2010/09/07 11:57:12 pacho Exp $
+
+*alsa-utils-1.0.23-r1 (07 Sep 2010)
+
+  07 Sep 2010; Pacho Ramos <pacho@g.o> +alsa-utils-1.0.23-r1.ebuild,
+  +files/alsa-utils-1.0.23-alsactl-output.patch,
+  +files/alsa-utils-1.0.23-alsactl-output2.patch:
+  Revision bump to fix bug #299362 following upstream indications and
+  applying upstream patches that will be included in 1.0.24.
 
 *alsa-utils-1.0.23 (16 Apr 2010)
 



1.1                  media-sound/alsa-utils/alsa-utils-1.0.23-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.23-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.23-r1.ebuild?rev=1.1&content-type=text/plain

Index: alsa-utils-1.0.23-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.23-r1.ebuild,v 1.1 2010/09/07 11:57:12 pacho Exp $

EAPI=2
inherit eutils

MY_P=${P/_rc/rc}
ALSA_DRIVER_VER="1.0.23"

DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/utils/${MY_P}.tar.bz2
	mirror://alsaproject/driver/alsa-driver-${ALSA_DRIVER_VER}.tar.bz2"

LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="doc nls minimal"

DEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-${PV}
	doc? ( app-text/xmlto )"
RDEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-${PV}
	virtual/modutils
	!minimal? ( sys-apps/pciutils )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if [[ -e "${ROOT}etc/modules.d/alsa" ]]; then
		eerror "Obsolete config /etc/modules.d/alsa found."
		die "Move /etc/modules.d/alsa to /etc/modprobe.d/alsa.conf."
	fi

	if [[ -e "${ROOT}etc/modprobe.d/alsa" ]]; then
		eerror "Obsolete config /etc/modprobe.d/alsa found."
		die "Move /etc/modprobe.d/alsa to /etc/modprobe.d/alsa.conf."
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-modprobe.d.patch

	# Exit code 99 will be the same than 0 for us per bug #299362 as suggested
	# by upstream: http://www.spinics.net/lists/alsa-devel/msg31430.html
	sed -i -e 's/EXIT="99"/EXIT="0"/g' alsactl/init/00main || die

	# Apply upstream patches to clarify initialization
	epatch "${FILESDIR}/${P}-alsactl-output.patch"
	epatch "${FILESDIR}/${P}-alsactl-output2.patch"
}

src_configure() {
	local myconf=""
	use doc || myconf="--disable-xmlto"

	econf ${myconf} \
		$(use_enable nls)
}

src_install() {
	local ALSA_UTILS_DOCS="ChangeLog README TODO
		seq/aconnect/README.aconnect
		seq/aseqnet/README.aseqnet"

	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc ${ALSA_UTILS_DOCS} || die

	newbin "${WORKDIR}/alsa-driver-${ALSA_DRIVER_VER}/utils/alsa-info.sh" \
		alsa-info

	newinitd "${FILESDIR}/alsasound.initd-r4" alsasound
	newconfd "${FILESDIR}/alsasound.confd-r3" alsasound
	insinto /etc/modprobe.d
	newins "${FILESDIR}/alsa-modules.conf-rc" alsa.conf

	keepdir /var/lib/alsa
}

pkg_postinst() {
	echo
	elog "To take advantage of the init script, and automate the process of"
	elog "saving and restoring sound-card mixer levels you should"
	elog "add alsasound to the boot runlevel. You can do this as"
	elog "root like so:"
	elog "	# rc-update add alsasound boot"
	echo
	elog "The script will load ALSA modules, if you choose to use a modular"
	elog "configuration. The Gentoo ALSA developers recommend you to build"
	elog "your audio drivers into the kernel unless the device is hotpluggable"
	elog "or you need to supply specific options (such as model= to HD Audio)."
	echo
	ewarn "Automated unloading of ALSA modules is deprecated and unsupported."
	ewarn "Should you choose to use it, bug reports will not be accepted."
	echo
	if use minimal; then
		ewarn "The minimal use flag disables the dependency on pciutils that"
		ewarn "is needed by alsaconf at runtime."
	fi
}