[gentoo-commits] gentoo-x86 commit in dev-python/gevent: gevent-1.0.1.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    14/05/01 04:41:48

  Modified:             ChangeLog
  Added:                gevent-1.0.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.23                 dev-python/gevent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	18 Mar 2014 22:54:11 -0000	1.22
+++ ChangeLog	1 May 2014 04:41:48 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/gevent
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v 1.22 2014/03/18 22:54:11 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v 1.23 2014/05/01 04:41:48 radhermit Exp $
+
+*gevent-1.0.1 (01 May 2014)
+
+  01 May 2014; Tim Harder <radhermit@g.o> +gevent-1.0.1.ebuild:
+  Version bump.
 
   18 Mar 2014; Tim Harder <radhermit@g.o> -gevent-0.13.7.ebuild,
   -gevent-0.13.8.ebuild, -gevent-1.0_beta2.ebuild, -gevent-1.0_beta2-r1.ebuild,



1.1                  dev-python/gevent/gevent-1.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/gevent-1.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/gevent-1.0.1.ebuild?rev=1.1&content-type=text/plain

Index: gevent-1.0.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/gevent-1.0.1.ebuild,v 1.1 2014/05/01 04:41:48 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="ssl"

inherit distutils-r1 flag-o-matic

MY_PV=${PV/_/}
MY_P=${PN}-${MY_PV}

DESCRIPTION="Python networking library that uses greenlet to provide synchronous API"
HOMEPAGE="http://gevent.org/ http://pypi.python.org/pypi/gevent/"
SRC_URI="https://github.com/surfly/${PN}/releases/download/${MY_PV}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples"

RDEPEND="dev-libs/libev
	net-dns/c-ares
	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"

# Tests take long and fail terribly a few times.
# It also seems that they require network access.
RESTRICT="test"

S=${WORKDIR}/${MY_P}

python_prepare_all() {
	rm -r {libev,c-ares} || die

	distutils-r1_python_prepare_all
}

python_configure_all() {
	append-flags -fno-strict-aliasing
}

python_compile_all() {
	use doc && emake -C doc html
}

python_test() {
	cd greentest || die
	"${PYTHON}" testrunner.py || die "Tests fail with ${EPYTHON}"
}

python_install_all() {
	use doc && local HTML_DOCS=( doc/_build/html/. )

	distutils-r1_python_install_all

	dodoc changelog.rst

	if use examples; then
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi
}