[gentoo-commits] repo/gentoo:master commit in: dev-python/nbdime/

[Andrew Ammerlaan]

commit:     70650f7d76ea8dd749b2427ff3a104e50cdc5bf3
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 10 09:52:38 2021 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Thu Jun 10 09:58:15 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=70650f7d

dev-python/nbdime: add 3.1.0

Closes: https://bugs.gentoo.org/783243
Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/nbdime/Manifest            |  1 +
 dev-python/nbdime/nbdime-3.1.0.ebuild | 78 +++++++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)

diff --git a/dev-python/nbdime/Manifest b/dev-python/nbdime/Manifest
index 5518da014d1..8c8d213e295 100644
--- a/dev-python/nbdime/Manifest
+++ b/dev-python/nbdime/Manifest
@@ -1 +1,2 @@
 DIST nbdime-2.0.0.tar.gz 7768807 BLAKE2B a92ed166ae863185d06e4b3e667df4323b4cd9af9211999109186c1b559522f39ab235b710c7993515aa3c44a55ac3c4b90c424cdc28d04cc013a58add7d61cd SHA512 e68e69e37f6ece701ba8d6e59d8ee321ddaca78d9338e0c52f92b6942bfd3fbf0ec2407e9ae98cb820eb4c26509644a1770f249b815c53265dfdbffbe2b55142
+DIST nbdime-3.1.0.tar.gz 7508382 BLAKE2B 10ca59684df06e922afbba30d5419a20490508af8bb9d4f371b1a06db49df7b665195c9aec21c3a303b3fa0c60e5c0c1e57badaba27ac81599b311f9a5000244 SHA512 be19fc058a918cd2aad38a8f727504a01c7830dfaba7fbf06caa0a6799770824499a70f4efe1ebf0a82847dc79d84896baf9aa86d3e7cd16dd7163023fed3855

diff --git a/dev-python/nbdime/nbdime-3.1.0.ebuild b/dev-python/nbdime/nbdime-3.1.0.ebuild
new file mode 100644
index 00000000000..5a7c22168e0
--- /dev/null
+++ b/dev-python/nbdime/nbdime-3.1.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Diff and merge of Jupyter Notebooks"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="webtools"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/GitPython[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_server[${PYTHON_USEDEP}]
+	dev-python/jupyter_server_mathjax[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+	webtools? ( net-libs/nodejs[npm] )"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs/source \
+		dev-python/recommonmark \
+		dev-python/sphinx_rtd_theme
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# yield tests were removed in pytest 4.0
+	sed -i -e 's/test_offline_mathjax/_&/' \
+		-e 's/test_api_merge/_&/' \
+		-e 's/test_fetch_merge/_&/' \
+		-e 's/test_api_diff/_&/' \
+		-e 's/test_fetch_diff/_&/' \
+		nbdime/tests/test_web.py || die
+	sed -i -e 's/test_git_difftool/_&/' \
+		nbdime/tests/test_server_extension.py || die
+	# reason: [NOTRUN] flaws in deep diffing of lists, not identifying almost equal sublists
+	sed -i -e 's/test_deep_merge_lists_delete_no_conflict__currently_expected_failures/_&/' \
+		nbdime/tests/test_merge.py || die
+	sed -i -e 's/test_diff_to_json_patch/_&/' \
+		nbdime/tests/test_diff_json_conversion.py || die
+	sed -i -e 's/test_build_diffs_unsorted/_&/' \
+		nbdime/tests/test_decision_tools.py || die
+	sed -i -e 's/test_merge_multiline_cell_source_conflict/_&/' \
+		-e 's/test_merge_interleave_cell_add_remove/_&/' \
+		-e 's/test_merge_conflicts_get_diff_indices_shifted/_&/' \
+		-e 's/test_merge_inserts_within_deleted_range/_&/' \
+		nbdime/tests/test_merge_notebooks.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	use webtools || mydistutilsargs=( --skip-npm )
+}
+
+src_test() {
+	# user.email and user.name are not configured in the sandbox
+	git config --global user.email "larry@g.o" || die
+	git config --global user.name "Larry the Cow" || die
+	python_foreach_impl python_test
+}