[gentoo-commits] repo/gentoo:master commit in: dev-util/umockdev/

[Matt Turner]

commit:     03383a5691771d0b50a4eef2e51fa09b4bc6af9d
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Mar  1 20:35:43 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Mar  1 20:37:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03383a56

dev-util/umockdev: Version bump to 0.17.7

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-util/umockdev/Manifest               |  1 +
 dev-util/umockdev/umockdev-0.17.7.ebuild | 53 ++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-util/umockdev/Manifest b/dev-util/umockdev/Manifest
index e5f24bc74557..bfa7fc1ce1f6 100644
--- a/dev-util/umockdev/Manifest
+++ b/dev-util/umockdev/Manifest
@@ -1,2 +1,3 @@
 DIST umockdev-0.16.2.tar.xz 478388 BLAKE2B 8fb2116ec7d48b238898052d959c596f4f91a65cf7b8292de8b8731e6fe50600282cb56093b8d6ca1afdc082a12c9af3c4a4f443283538ffb2aeae4c2b775596 SHA512 82020c068d5a158a762f865f4b25d1ee8596785a5b379c316c652004e1b1b9c533d4dad87818a490f89983a4c065f34e4ff5ca91360bac6d79b141dfa2139eea
 DIST umockdev-0.17.6.tar.xz 486668 BLAKE2B 973c195b8fccd1c080665b65ffd47f8fe110118de9c541d5dda383e51e4dbcc36f77eeda6af5c774f4570a7b839190130fe95559fb3148e9937dae19dace6331 SHA512 05a86e2a583972d02fb3cfa26b017d44600831b6ed1415769d7cc7344357f484d34228b1593de2cfbfcce302611c0c22f045ee9fbd7fea76d8ae0b4ccd28d6ef
+DIST umockdev-0.17.7.tar.xz 486964 BLAKE2B f3c4021198c8adea47383f3d0c111f921c35550ca9b70c0711e71799ba89a44031356a687b88cc80aa51b1bf4606cfcf48a1d24d16501b0ea08f805e4e30cf83 SHA512 6fc611787c9679f450ce7cdf7dccb93a5d7435470b0b5f5cb1803036cf3c8ce73521af9e7777bec68485834cddfddba0ed9379a0818bfb072bb643cf6419c17d

diff --git a/dev-util/umockdev/umockdev-0.17.7.ebuild b/dev-util/umockdev/umockdev-0.17.7.ebuild
new file mode 100644
index 000000000000..7a53f924c567
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.17.7.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-libs/libpcap[${MULTILIB_USEDEP}]
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_src_prepare
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}