[gentoo-commits] repo/gentoo:master commit in: dev-qt/qtwayland/

[Andreas Sturmlechner]

commit:     f2ba1acf37637ffe00b08642ce98772ef6853a4c
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 26 19:22:05 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Feb 26 21:56:43 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f2ba1acf

dev-qt/qtwayland: Fix USE libinput

Upstream commit a8fed201

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-qt/qtwayland/qtwayland-5.14.1-r1.ebuild | 43 +++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-qt/qtwayland/qtwayland-5.14.1-r1.ebuild b/dev-qt/qtwayland/qtwayland-5.14.1-r1.ebuild
new file mode 100644
index 00000000000..0602db2ff59
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-5.14.1-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit qt5-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="+libinput xcomposite"
+
+DEPEND="
+	>=dev-libs/wayland-1.6.0
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}[egl,libinput=]
+	media-libs/mesa[egl]
+	>=x11-libs/libxkbcommon-0.2.0
+	xcomposite? (
+		x11-libs/libX11
+		x11-libs/libXcomposite
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt_use_disable_config libinput xkbcommon \
+		src/client/client.pro \
+		src/compositor/wayland_wrapper/wayland_wrapper.pri \
+		src/plugins/shellintegration/ivi-shell/ivi-shell.pro \
+		src/plugins/shellintegration/wl-shell/wl-shell.pro \
+		src/plugins/shellintegration/xdg-shell/xdg-shell.pro \
+		src/plugins/shellintegration/xdg-shell-v5/xdg-shell-v5.pro \
+		src/plugins/shellintegration/xdg-shell-v6/xdg-shell-v6.pro \
+		tests/auto/compositor/compositor/compositor.pro
+
+	use xcomposite || rm -r config.tests/xcomposite || die
+
+	qt5-build_src_prepare
+}