[gentoo-commits] gentoo-x86 commit in net-libs/serf: serf-1.3.4.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     14/02/09 19:23:00

  Modified:             ChangeLog
  Added:                serf-1.3.4.ebuild
  Log:
  Version bump. Ebuild by Arfrever.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.121                net-libs/serf/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/serf/ChangeLog?rev=1.121&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/serf/ChangeLog?rev=1.121&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/serf/ChangeLog?r1=1.120&r2=1.121

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/serf/ChangeLog,v
retrieving revision 1.120
retrieving revision 1.121
diff -u -r1.120 -r1.121
--- ChangeLog	2 Feb 2014 11:00:21 -0000	1.120
+++ ChangeLog	9 Feb 2014 19:23:00 -0000	1.121
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/serf
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/serf/ChangeLog,v 1.120 2014/02/02 11:00:21 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/serf/ChangeLog,v 1.121 2014/02/09 19:23:00 floppym Exp $
+
+*serf-1.3.4 (09 Feb 2014)
+
+  09 Feb 2014; Mike Gilbert <floppym@g.o> +serf-1.3.4.ebuild:
+  Version bump. Ebuild by Arfrever.
 
   02 Feb 2014; Agostino Sarubbo <ago@g.o> serf-1.3.3.ebuild:
   Stable for ppc, wrt bug #498868



1.1                  net-libs/serf/serf-1.3.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/serf/serf-1.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/serf/serf-1.3.4.ebuild?rev=1.1&content-type=text/plain

Index: serf-1.3.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/serf/serf-1.3.4.ebuild,v 1.1 2014/02/09 19:23:00 floppym Exp $

EAPI="5"

inherit eutils scons-utils toolchain-funcs

DESCRIPTION="HTTP client library"
HOMEPAGE="http://code.google.com/p/serf/"
SRC_URI="http://serf.googlecode.com/svn/src_releases/${P}.tar.bz2"

LICENSE="Apache-2.0"
SLOT="1"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="kerberos"

RDEPEND="dev-libs/apr:1=
	dev-libs/apr-util:1=
	dev-libs/openssl:0=
	sys-libs/zlib:0=
	kerberos? ( virtual/krb5 )"
DEPEND="${RDEPEND}
	>=dev-util/scons-2.3.0"

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.3.2-disable_linking_against_unneeded_libraries.patch"

	# http://code.google.com/p/serf/issues/detail?id=133
	sed -e "/env.Append(CCFLAGS='-O2')/d" -i SConstruct
}

src_compile() {
	local myesconsargs=(
		PREFIX="${EPREFIX}/usr"
		LIBDIR="${EPREFIX}/usr/$(get_libdir)"
		APR="${EPREFIX}/usr/bin/apr-1-config"
		APU="${EPREFIX}/usr/bin/apu-1-config"
		OPENSSL="${EPREFIX}/usr"
		CC="$(tc-getCC)"
		CPPFLAGS="${CPPFLAGS}"
		CFLAGS="${CFLAGS}"
		LINKFLAGS="${LDFLAGS}"
	)

	if use kerberos; then
		myesconsargs+=(GSSAPI="${EPREFIX}/usr/bin/krb5-config")
	fi

	escons
}

src_test() {
	escons check
}

src_install() {
	escons install --install-sandbox="${D}"
}