[gentoo-commits] gentoo-x86 commit in media-libs/libquicktime: ChangeLog libquicktime-1.0.1-r1.ebuild

[Alexis Ballier (aballier)]

aballier    08/01/02 13:59:36

  Modified:             ChangeLog
  Added:                libquicktime-1.0.1-r1.ebuild
  Log:
  Fix pkg-config initialisation when alsa is not used, fix nls build with as-needed on non glibc systems, add missing dep on virtual/libintl for non glibc systems
  (Portage version: 2.1.4_rc14)

Revision  Changes    Path
1.99                 media-libs/libquicktime/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/ChangeLog?rev=1.99&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/ChangeLog?rev=1.99&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/ChangeLog?r1=1.98&r2=1.99

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v
retrieving revision 1.98
retrieving revision 1.99
diff -u -r1.98 -r1.99
--- ChangeLog	25 Dec 2007 17:19:28 -0000	1.98
+++ ChangeLog	2 Jan 2008 13:59:35 -0000	1.99
@@ -1,6 +1,16 @@
 # ChangeLog for media-libs/libquicktime
-# Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v 1.98 2007/12/25 17:19:28 phreak Exp $
+# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v 1.99 2008/01/02 13:59:35 aballier Exp $
+
+*libquicktime-1.0.1-r1 (02 Jan 2008)
+
+  02 Jan 2008; Alexis Ballier <aballier@g.o>
+  +files/libquicktime-1.0.1-nls-asneeded.patch,
+  +files/libquicktime-1.0.1-pkgconfig_init.patch,
+  +libquicktime-1.0.1-r1.ebuild:
+  Fix pkg-config initialisation when alsa is not used, fix nls build with
+  as-needed on non glibc systems, add missing dep on virtual/libintl for non
+  glibc systems
 
   25 Dec 2007; Christian Heim <phreak@g.o> metadata.xml:
   Removing zypher from metadata.xml as per #26909.



1.1                  media-libs/libquicktime/libquicktime-1.0.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/libquicktime-1.0.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/libquicktime-1.0.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: libquicktime-1.0.1-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/libquicktime-1.0.1-r1.ebuild,v 1.1 2008/01/02 13:59:35 aballier Exp $

WANT_AUTOMAKE="latest"
WANT_AUTOCONF="latest"
inherit libtool eutils autotools

DESCRIPTION="A library based on quicktime4linux with extensions"
HOMEPAGE="http://libquicktime.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"

IUSE="mmx X opengl dv gtk alsa aac encode png jpeg vorbis lame x264 ffmpeg"

RDEPEND="dv? ( media-libs/libdv )
	gtk? ( >=x11-libs/gtk+-2.4.0 )
	aac? (
		media-libs/faad2
		encode? ( media-libs/faac )
	)
	alsa? ( media-libs/alsa-lib )
	png? ( media-libs/libpng )
	jpeg? ( media-libs/jpeg )
	vorbis? ( media-libs/libvorbis media-libs/libogg )
	lame? ( media-sound/lame )
	ffmpeg? ( media-video/ffmpeg )
	x264? ( >=media-libs/x264-svn-20060810 )
	X? ( x11-libs/libXaw
		x11-libs/libXv
		x11-libs/libXext
		x11-libs/libX11
		opengl? ( media-libs/mesa )
	)
	virtual/libintl
	!virtual/quicktime"
DEPEND="${RDEPEND}
	X? (
		x11-proto/videoproto
		x11-proto/xextproto
	)
	dev-util/pkgconfig
	sys-devel/gettext"

PROVIDE="virtual/quicktime"


src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-pkgconfig_init.patch"
	epatch "${FILESDIR}/${P}-nls-asneeded.patch"
	# Copy config.rapth to avoid failures..
	cp /usr/share/gettext/config.rpath .
	AT_M4DIR="m4" eautoreconf
}
src_compile() {
	local MY_OPTS=""
	if use !encode || use !aac; then
		MY_OPTS="--without-faac"
	fi

	econf --enable-shared \
		--enable-static \
		--enable-gpl \
		$(use_enable mmx) \
		$(use_with X x) \
		$(use_with gtk) \
		$(use_with dv libdv) \
		$(use_with alsa) \
		$(use_with aac faad2) \
		$(use_with png libpng) \
		$(use_with jpeg libjpeg) \
		$(use vorbis || echo "--without-vorbis") \
		$(use_with lame) \
		$(use_with x264) \
		$(use_with ffmpeg) \
		$(use_with opengl) \
		${MY_OPTS} \
		--without-cpuflags || die "econf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc README TODO ChangeLog
	# Compatibility with software that uses quicktime prefix, but
	# don't do that when building for Darwin/MacOS
	[[ ${CHOST} != *-darwin* ]] && \
	dosym /usr/include/lqt /usr/include/quicktime
}

pkg_preinst() {
	if [[ -d /usr/include/quicktime && ! -L /usr/include/quicktime ]]; then
		elog "For compatibility with other quicktime libraries, ${PN} was"
		elog "going to create a /usr/include/quicktime symlink, but for some"
		elog "reason that is a directory on your system."

		elog "Please check that is empty, and remove it, or submit a bug"
		elog "telling us which package owns the directory."
		die "/usr/include/quicktime is a directory."
	fi
}



-- 
gentoo-commits@g.o mailing list