[gentoo-commits] gentoo-x86 commit in x11-libs/qt-gui: metadata.xml ChangeLog qt-gui-4.4.0_rc1.ebuild Manifest

[Caleb Tennis (caleb)]

caleb       07/12/21 19:10:35

  Added:                metadata.xml ChangeLog qt-gui-4.4.0_rc1.ebuild
                        Manifest
  Log:
  Initial ebuild
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.1                  x11-libs/qt-gui/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>qt</herd> 
</pkgmetadata>



1.1                  x11-libs/qt-gui/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for x11-libs/qt-gui
# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-gui/ChangeLog,v 1.1 2007/12/21 19:10:35 caleb Exp $

*qt-gui-4.4.0_rc1 (21 Dec 2007)

  21 Dec 2007; Caleb Tennis <caleb@g.o> +metadata.xml,
  +qt-gui-4.4.0_rc1.ebuild:
  Initial ebuild




1.1                  x11-libs/qt-gui/qt-gui-4.4.0_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/qt-gui-4.4.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/qt-gui-4.4.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: qt-gui-4.4.0_rc1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-gui/qt-gui-4.4.0_rc1.ebuild,v 1.1 2007/12/21 19:10:35 caleb Exp $

inherit eutils qt4-build

SRCTYPE="preview-opensource-src"
DESCRIPTION="The GUI module(s) for the Qt toolkit."
HOMEPAGE="http://www.trolltech.com/"

MY_PV=${PV/_rc/-tp}

SRC_URI="ftp://ftp.trolltech.com/pub/qt/source/qt-x11-${SRCTYPE}-${MY_PV}.tar.gz"
S=${WORKDIR}/qt-x11-${SRCTYPE}-${MY_PV}

LICENSE="|| ( QPL-1.0 GPL-2 )"
SLOT="4"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

IUSE_INPUT_DEVICES="input_devices_wacom"

IUSE="accessibility cups dbus debug mng nas nis tiff xinerama ${IUSE_INPUT_DEVICES}"

RDEPEND="~x11-libs/qt-core-${PV}
	~x11-libs/qt-script-${PV}
	dbus? ( ~x11-libs/qt-dbus-${PV} )
	x11-libs/libXrandr
	x11-libs/libXcursor
	x11-libs/libXfont
	x11-libs/libSM
	xinerama? ( x11-libs/libXinerama )
	media-libs/fontconfig
	>=media-libs/freetype-2
	media-libs/libpng
	media-libs/jpeg
	sys-libs/zlib
	mng? ( >=media-libs/libmng-1.0.9 )
	tiff? ( media-libs/tiff )
	nas? ( >=media-libs/nas-1.5 )
	cups? ( net-print/cups )
	input_devices_wacom? ( x11-libs/libXi x11-drivers/linuxwacom )"

DEPEND="${RDEPEND}
	xinerama? ( x11-proto/xineramaproto )
	x11-proto/xextproto
	x11-proto/inputproto"

src_unpack() {
	qt4-build_src_unpack

	skip_qmake_build_patch
	skip_project_generation_patch
	install_binaries_to_buildtree

	# Don't build plugins this go around, because they depend on qt3support lib
	sed -i -e "s:CONFIG(shared:#CONFIG(shared:g" "${S}"/tools/designer/src/src.pro
}

src_compile() {
	export PATH="${S}/bin:${PATH}"
	export LD_LIBRARY_PATH="${S}/lib:${LD_LIBRARY_PATH}"

	local myconf=$(standard_configure_options)

	myconf="${myconf} $(qt_use accessibility) $(qt_use cups) $(qt_use xinerama)"
	myconf="${myconf} $(qt_use nis)"

	use nas		&& myconf="${myconf} -system-nas-sound"

	myconf="${myconf} -qt-gif -system-libpng -system-libjpeg"
	myconf="${myconf} $(qt_use tiff libtiff system)"
	myconf="${myconf} $(qt_use mng libmng system)"

	myconf="${myconf} -no-sql-mysql -no-sql-psql -no-sql-ibase -no-sql-sqlite -no-sql-sqlite2 -no-sql-odbc"

	if built_with_use ~x11-libs/qt-core-${PV} glib; then
		myconf="${myconf} -glib"
	else
		myconf="${myconf} -no-glib"
	fi

	if built_with_use ~x11-libs/qt-core-${PV} qt3support; then
		myconf="${myconf} -qt3support"
	else
		myconf="${myconf} -no-qt3support"
	fi

	use input_devices_wacom	&& myconf="${myconf} -tablet" || myconf="${myconf} -no-tablet"

	myconf="${myconf} -xrender -xrandr -xkb -xshape -sm"

	# Explictly don't compile these packages.
	# Emerge "qt-webkit", "qt-phonon", etc for their functionality.
	myconf="${myconf} -no-webkit -no-phonon -no-qdbus -no-opengl"

	use dbus && myconf="${myconf} -qdbus" || myconf="${myconf} -no-qdbus"

	echo ./configure ${myconf}
	./configure ${myconf} || die

	build_directories src/gui tools/assistant tools/designer tools/linguist
	use dbus && build_directories tools/qdbus/qdbusviewer
}

src_install() {
	install_directories src/gui tools/assistant tools/designer tools/linguist
	use dbus && install_directories tools/qdbus/qdbusviewer

	fix_library_files

	# Install .desktop files, from bug #174033
	insinto /usr/share/applications
	doins "${FILESDIR}"/qt4/*.desktop
}

pkg_postinst()
{
	qconfig_add_option x11sm
	qconfig_add_option xshape
	qconfig_add_option xcursor
	qconfig_add_option xfixes
	qconfig_add_option xrandr
	qconfig_add_option xrender
	qconfig_add_option xkb
	qconfig_add_option fontconfig
	use input_devices_wacom && qconfig_add_option tablet
	use accessibility && qconfig_add_option accessibility
	use xinerama && qconfig_add_option xinerama
	use cups && qconfig_add_option cups
	use nas && qconfig_add_option nas

	qconfig_remove_option no-gif
	qconfig_add_option gif

	qconfig_remove_option no-png
	qconfig_add_option png
	qconfig_add_option system-png

	# Need to do the same for tiff and mng
}

pkg_postrm()
{
	qconfig_remove_option x11sm
	qconfig_remove_option xshape
	qconfig_remove_option xcursor
	qconfig_remove_option xfixes
	qconfig_remove_option xrandr
	qconfig_remove_option xrender
	qconfig_remove_option xkb
	qconfig_remove_option fontconfig

	qconfig_remove_option tablet
	qconfig_remove_option accessibility
	qconfig_remove_option xinerama
	qconfig_remove_option cups
	qconfig_remove_option nas

	qconfig_remove_option png
	qconfig_remove_option system-png
	qconfig_add_option no-png

	qconfig_remove_option gif
	qconfig_add_option no-gif

	# Need to do the same for tiff and mng
}



1.1                  x11-libs/qt-gui/Manifest

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
DIST qt-x11-preview-opensource-src-4.4.0-tp1.tar.gz 56029137 RMD160 dd2dee9afaa9d16bdf5ca2bed82a3b9e2162bdd2 SHA1 e242dc542eb1424a51c47e7c80aaefd26668451c SHA256 1757416bda52c34ade3a49b5896bafe9e3cfe092d3180da32d520f94324c0b88
EBUILD qt-gui-4.4.0_rc1.ebuild 4571 RMD160 ee2b943a9377502d51e929318e4730d26b0a8ef8 SHA1 f2873e8d129607bf57d13d69a4ab69b5d51818ab SHA256 8f3eeb9c6b4d1d8b945ce2d894ec18bf61f1103849631edbd18a956630b35b7e
MD5 845770df17224c822030c30ad0a8a6a9 qt-gui-4.4.0_rc1.ebuild 4571
RMD160 ee2b943a9377502d51e929318e4730d26b0a8ef8 qt-gui-4.4.0_rc1.ebuild 4571
SHA256 8f3eeb9c6b4d1d8b945ce2d894ec18bf61f1103849631edbd18a956630b35b7e qt-gui-4.4.0_rc1.ebuild 4571
MISC ChangeLog 257 RMD160 adbc9a774cb46e0bc5c074c0a9b810d7d724822c SHA1 072dc3c56890f676dee45de640ab0b16281ece82 SHA256 7e15c6d3dfdffaf5809af4f5a4682052573055c6deb29d54e975f3c20e00af66
MD5 d5f5dd6656da92241040a5d15c5cfaf5 ChangeLog 257
RMD160 adbc9a774cb46e0bc5c074c0a9b810d7d724822c ChangeLog 257
SHA256 7e15c6d3dfdffaf5809af4f5a4682052573055c6deb29d54e975f3c20e00af66 ChangeLog 257
MISC metadata.xml 156 RMD160 d76590850d56864c8d99e6877ed15841b55ef1fc SHA1 e872bab086832a9db3f0fa9b1897c70577d3af21 SHA256 94c4f580c1a55f8a5e1a1dcdd6dedfea0b8bd78c1d7137c354938d73c49e4448
MD5 512150b47a904b0240101e319856aab1 metadata.xml 156
RMD160 d76590850d56864c8d99e6877ed15841b55ef1fc metadata.xml 156
SHA256 94c4f580c1a55f8a5e1a1dcdd6dedfea0b8bd78c1d7137c354938d73c49e4448 metadata.xml 156
MD5 82e8a2d695216d8ed9d69b21cb2b06fc files/digest-qt-gui-4.4.0_rc1 325
RMD160 b82b94eb49ac3711f85f127b3b2d336ebc7e2711 files/digest-qt-gui-4.4.0_rc1 325
SHA256 76d5f09c74420bfa920616103da36e3bab698f3932f4db60db3d499ff34abf0e files/digest-qt-gui-4.4.0_rc1 325



-- 
gentoo-commits@g.o mailing list