[gentoo-commits] gentoo-x86 commit in media-video/makemkv: ChangeLog makemkv-1.7.6.ebuild

[Matthew Marlow (mattm)]

mattm       12/07/02 04:00:21

  Modified:             ChangeLog
  Added:                makemkv-1.7.6.ebuild
  Log:
  Bump for release 1.7.6 - upstream has changed download pkg naming rules, will need to double check for any other significant changes.
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  media-video/makemkv/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/makemkv/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	2 Jul 2012 03:46:19 -0000	1.5
+++ ChangeLog	2 Jul 2012 04:00:20 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/makemkv
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/makemkv/ChangeLog,v 1.5 2012/07/02 03:46:19 mattm Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/makemkv/ChangeLog,v 1.6 2012/07/02 04:00:20 mattm Exp $
+
+*makemkv-1.7.6 (02 Jul 2012)
+
+  02 Jul 2012; Matthew Marlowe <mattm@g.o> +makemkv-1.7.6.ebuild:
+  Bump for release 1.7.6 - upstream has changed download pkg naming rules, will
+  need to double check for any other significant changes.
 
 *makemkv-1.7.4-r1 (02 Jul 2012)
 



1.1                  media-video/makemkv/makemkv-1.7.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/makemkv-1.7.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/makemkv-1.7.6.ebuild?rev=1.1&content-type=text/plain

Index: makemkv-1.7.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/makemkv/makemkv-1.7.6.ebuild,v 1.1 2012/07/02 04:00:20 mattm Exp $

EAPI=3

RESTRICT="mirror"

inherit multilib eutils

MY_P="makemkv-oss-${PV}"
MY_PB="makemkv-bin-${PV}"

DESCRIPTION="Tool for ripping Blu-Ray, HD-DVD and DVD discs and copying content to a Matroska container"
HOMEPAGE="http://www.makemkv.com/"
SRC_URI="http://www.makemkv.com/download/${MY_P}.tar.gz
	http://www.makemkv.com/download/${MY_PB}.tar.gz"

LICENSE="MakeMKV-EULA"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="x11-libs/qt-gui:4
	dev-libs/openssl:0
	media-libs/mesa
	dev-libs/expat
	x11-libs/qt-dbus:4
	sys-libs/zlib"
RDEPEND="${DEPEND}"

QA_PREBUILT="opt/bin/makemkvcon"
DEFAULT_PROFILE="default.mmcp.xml"

src_prepare() {
	epatch "${FILESDIR}/${P}-makefile.linux.patch"
	cd "${MY_P}"
}

src_compile() {
	cd "${MY_P}"
	emake GCC="$(tc-getCC) ${CFLAGS} ${LDFLAGS}" -f makefile.linux || die "make failed"
}

src_install() {
	# install oss package
	cd "${MY_P}"
	dolib.so out/libdriveio.so.0 || die "dolib.so out/libdriveio.so.0 died"
	dolib.so out/libmakemkv.so.1 || die "dolib.so out/libmakemkv.so.1 died"
	dosym libdriveio.so.0 /usr/$(get_libdir)/libdriveio.so.0.${PV} || die "dosym libdriveio.so.0 died "
	dosym libdriveio.so.0 /usr/$(get_libdir)/libdriveio.so || die "dosym libdriveio.so.0 died "
	dosym libmakemkv.so.1 /usr/$(get_libdir)/libmakemkv.so.1.${PV} || die "dosym libmakemkv.so.1 died"
	dosym libmakemkv.so.1 /usr/$(get_libdir)/libmakemkv.so || die "dosym libmakemkv.so.1 died"
	into /opt
	dobin out/makemkv || die "dobin makemkv died"

	newicon makemkvgui/src/img/128/mkv_icon.png ${PN}.png
	make_desktop_entry ${PN} "MakeMKV" ${PN} "Qt;AudioVideo;Video"

	# install bin package
	cd "${WORKDIR}/${MY_PB}/bin"
	if use x86; then
		dobin i386/makemkvcon || die "dobin makemkvcon died"
	elif use amd64; then
		dobin amd64/makemkvcon || die "dobin makemkvcon died"
	fi

	# install license and default profile
	cd "${WORKDIR}/${MY_PB}/src"
	into /usr
	dodoc eula_en_linux.txt
	insinto /usr/share/${PF}
	doins share/${DEFAULT_PROFILE}
}

pkg_postinst() {
	elog "While MakeMKV is in beta mode, upstream has provided a license"
	elog "to use if you do not want to purchase one."
	elog ""
	elog "See this forum thread for more information, including the key:"
	elog "http://www.makemkv.com/forum2/viewtopic.php?f=5&t=1053"
	elog ""
	elog "Note that beta license may have an expiration date and you will"
	elog "need to check for newer licenses/releases. "
	elog ""
	elog "If this is a new install, remember to copy the default profile"
	elog "to the config directory:"
	elog "cp /usr/share/${PF}/${DEFAULT_PROFILE} ~/.MakeMKV/${DEFAULT_PROFILE}"
}