[gentoo-commits] repo/gentoo:master commit in: sys-apps/polychromatic/

[Maciej Barć]

commit:     5187885286ad0374ddaebcac0f56d602ac959865
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 24 20:32:31 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sat Sep 24 21:10:28 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=51878852

sys-apps/polychromatic: new package; add version 0.7.3 and live

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 sys-apps/polychromatic/Manifest                   |  1 +
 sys-apps/polychromatic/metadata.xml               | 21 +++++++
 sys-apps/polychromatic/polychromatic-0.7.3.ebuild | 67 +++++++++++++++++++++++
 sys-apps/polychromatic/polychromatic-9999.ebuild  | 67 +++++++++++++++++++++++
 4 files changed, 156 insertions(+)

diff --git a/sys-apps/polychromatic/Manifest b/sys-apps/polychromatic/Manifest
new file mode 100644
index 000000000000..cbef51a41ea3
--- /dev/null
+++ b/sys-apps/polychromatic/Manifest
@@ -0,0 +1 @@
+DIST polychromatic-0.7.3.tar.gz 1513522 BLAKE2B 85dab08c90843f050175de8b53c34dfab4c87dde6d7daaffb36bfad09e165aa8220a943b47ae7b09fb3c45589165051ae27b9c5e17f4c94479e6a8575b593ef4 SHA512 bdd816fcbae8ce2e12367afd455941afb754f7ddb9f6337c6b675a3059c1dc6d64b1a7809efce9b909b8aee2025b496dc0b870d2e56a09da7fde7f8b5d733c5f

diff --git a/sys-apps/polychromatic/metadata.xml b/sys-apps/polychromatic/metadata.xml
new file mode 100644
index 000000000000..41de43439b95
--- /dev/null
+++ b/sys-apps/polychromatic/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="person">
+    <email>xgqt@g.o</email>
+    <name>Maciej Barć</name>
+  </maintainer>
+  <longdescription>
+    Polychromatic is a vendor agnostic front-end for managing lighting, RGB
+    effects and some special functionality for keyboards, mice, keypads and
+    just about any other gaming peripheral on your GNU/Linux system. The
+    software aims to make it easy to create and co-ordinate lighting effects
+    that work across all compatible hardware, even if you switch to another
+    brand also supported by Polychromatic.
+  </longdescription>
+  <upstream>
+    <bugs-to>https://gitlab.com/polychromatic/polychromatic/-/issues/</bugs-to>
+    <remote-id type="gitlab">polychromatic/polychromatic</remote-id>
+  </upstream>
+</pkgmetadata>

diff --git a/sys-apps/polychromatic/polychromatic-0.7.3.ebuild b/sys-apps/polychromatic/polychromatic-0.7.3.ebuild
new file mode 100644
index 000000000000..83047579b56e
--- /dev/null
+++ b/sys-apps/polychromatic/polychromatic-0.7.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson python-single-r1 readme.gentoo-r1 xdg
+
+DESCRIPTION="RGB lighting management software for GNU/Linux powered by OpenRazer"
+HOMEPAGE="https://polychromatic.app/
+	https://github.com/polychromatic/polychromatic/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.20:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/PyQt5[svg,${PYTHON_USEDEP}]
+		dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/colour[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		sys-apps/openrazer[client,${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${RDEPEND}
+	dev-util/intltool
+	dev-lang/sassc
+"
+
+DOC_CONTENTS="To automatically start up Polychromatic on session login copy
+/usr/share/polychromatic/polychromatic-autostart.desktop file into Your user's
+~/.config/autostart/ directory."
+
+src_install() {
+	meson_src_install
+	python_optimize
+	readme.gentoo_create_doc
+
+	# Do not force polychromatic to autostart on session login.
+	# Move it into /usr/share/polychromatic and treat it as an example file
+	# that could be installed into user's ~/.config/autostart/ directory.
+	mv "${ED}"/etc/xdg/autostart/${PN}-autostart.desktop \
+	   "${ED}"/usr/share/${PN}/${PN}-autostart.desktop || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}

diff --git a/sys-apps/polychromatic/polychromatic-9999.ebuild b/sys-apps/polychromatic/polychromatic-9999.ebuild
new file mode 100644
index 000000000000..83047579b56e
--- /dev/null
+++ b/sys-apps/polychromatic/polychromatic-9999.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson python-single-r1 readme.gentoo-r1 xdg
+
+DESCRIPTION="RGB lighting management software for GNU/Linux powered by OpenRazer"
+HOMEPAGE="https://polychromatic.app/
+	https://github.com/polychromatic/polychromatic/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.20:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/PyQt5[svg,${PYTHON_USEDEP}]
+		dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/colour[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		sys-apps/openrazer[client,${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${RDEPEND}
+	dev-util/intltool
+	dev-lang/sassc
+"
+
+DOC_CONTENTS="To automatically start up Polychromatic on session login copy
+/usr/share/polychromatic/polychromatic-autostart.desktop file into Your user's
+~/.config/autostart/ directory."
+
+src_install() {
+	meson_src_install
+	python_optimize
+	readme.gentoo_create_doc
+
+	# Do not force polychromatic to autostart on session login.
+	# Move it into /usr/share/polychromatic and treat it as an example file
+	# that could be installed into user's ~/.config/autostart/ directory.
+	mv "${ED}"/etc/xdg/autostart/${PN}-autostart.desktop \
+	   "${ED}"/usr/share/${PN}/${PN}-autostart.desktop || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}