[gentoo-commits] gentoo-x86 commit in games-fps/etqw-bin: etqw-bin-1.5-r1.ebuild ChangeLog

[Ian Stakenvicius (axs)]

axs         14/07/07 18:03:58

  Modified:             ChangeLog
  Added:                etqw-bin-1.5-r1.ebuild
  Log:
  Bumped EAPI to 5, adjusted deps for gx86-multilib, added missing deps, dropped bundled libs.  Note, could not fully runtime-test as I don't have the PAKs
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 2B6559ED)

Revision  Changes    Path
1.7                  games-fps/etqw-bin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/etqw-bin/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/etqw-bin/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/etqw-bin/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/etqw-bin/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	1 Feb 2013 01:38:32 -0000	1.6
+++ ChangeLog	7 Jul 2014 18:03:58 -0000	1.7
@@ -1,6 +1,13 @@
 # ChangeLog for games-fps/etqw-bin
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/etqw-bin/ChangeLog,v 1.6 2013/02/01 01:38:32 tristan Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/etqw-bin/ChangeLog,v 1.7 2014/07/07 18:03:58 axs Exp $
+
+*etqw-bin-1.5-r1 (07 Jul 2014)
+
+  07 Jul 2014; Ian Stakenvicius (_AxS_) <axs@g.o>
+  +etqw-bin-1.5-r1.ebuild:
+  Bumped EAPI to 5, adjusted deps for gx86-multilib, added missing deps, dropped
+  bundled libs.  Note, could not fully runtime-test as I don't have the PAKs
 
   01 Feb 2013; Tristan Heaven <tristan@g.o> etqw-bin-1.5.ebuild:
   Use QA_PREBUILT, bug #430534
@@ -22,4 +29,3 @@
   06 Sep 2008; Tristan Heaven <nyhm@g.o> +metadata.xml,
   +etqw-bin-1.5.ebuild:
   Initial commit, bug #196452
-



1.1                  games-fps/etqw-bin/etqw-bin-1.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/etqw-bin/etqw-bin-1.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/etqw-bin/etqw-bin-1.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: etqw-bin-1.5-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/etqw-bin/etqw-bin-1.5-r1.ebuild,v 1.1 2014/07/07 18:03:58 axs Exp $

EAPI=5
inherit eutils games

DESCRIPTION="Enemy Territory: Quake Wars"
HOMEPAGE="http://zerowing.idsoftware.com/linux/etqw/"
SRC_URI="ftp://ftp.i3d.net/Games/Enemy%20Territory%20Quake%20Wars/Patches/ETQW-client-${PV}-full.x86.run"

LICENSE="ETQW"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="cdinstall"
RESTRICT="strip"

DEPEND="app-arch/unzip"
RDEPEND="sys-libs/glibc
	amd64? ( sys-libs/glibc[multilib] )
	|| (
		(
			>=sys-libs/zlib-1.2.8-r1[abi_x86_32(-)]
			>=virtual/jpeg-62:62[abi_x86_32(-)]
			>=media-libs/libsdl-1.2.15-r4[video,sound,opengl,abi_x86_32(-)]
			>=media-libs/alsa-lib-1.0.27.2[abi_x86_32(-)]
			>=x11-libs/libX11-1.6.2[abi_x86_32(-)]
			>=x11-libs/libXext-1.3.2[abi_x86_32(-)]
		)
		(
			app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-xlibs[-abi_x86_32(-)]
		)
	)
	cdinstall? ( games-fps/etqw-data )"

S=${WORKDIR}/data
dir=${GAMES_PREFIX_OPT}/etqw

QA_PREBUILT="${dir:1}/*.x86
	${dir:1}/*.so*"

src_unpack() {
	tail -c +194885 "${DISTDIR}"/${A} > ${A}.zip
	unpack ./${A}.zip
	rm -f ${A}.zip
}

src_install() {
	insinto "${dir}"
	doins -r base pb *.png
	dodoc *.txt

	exeinto "${dir}"
	doexe etqw{,ded,-rthread}.x86 openurl.sh libCgx86.so libSDL*.id.so*

	newicon etqw_icon.png etqw.png
	games_make_wrapper etqw ./etqw.x86 "${dir}" "${dir}"
	make_desktop_entry etqw "Enemy Territory: Quake Wars" etqw

	games_make_wrapper etqw-dedicated ./etqwded.x86 "${dir}" "${dir}"
	make_desktop_entry etqw-dedicated "Enemy Territory: Quake Wars (dedicated server)" etqw

	games_make_wrapper etqw-rthread ./etqw-rthread.x86 "${dir}" "${dir}"
	make_desktop_entry etqw-rthread "Enemy Territory: Quake Wars (SMP)" etqw

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	if ! use cdinstall ; then
		elog "You need to copy pak00*.pk4, zpak_*.pk4 and the megatextures"
		elog "directory to ${dir}/base before running the game."
	fi
	elog "To change the game language from English, add"
	elog "seta sys_lang \"your_language\" to your autoexec.cfg file."
	elog "Menu fonts may not show up until you do so."
}