[gentoo-commits] repo/gentoo:master commit in: dev-python/lxml/

[Arthur Zamarin]

commit:     0692bac617843f0ef8648c8210aa5f63f027ce56
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 26 18:03:26 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sat Mar 26 18:04:47 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0692bac6

dev-python/lxml: drop 4.7.1

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/lxml/Manifest          |  1 -
 dev-python/lxml/lxml-4.7.1.ebuild | 97 ---------------------------------------
 2 files changed, 98 deletions(-)

diff --git a/dev-python/lxml/Manifest b/dev-python/lxml/Manifest
index 7796e6e0e6b5..1bbee16e748c 100644
--- a/dev-python/lxml/Manifest
+++ b/dev-python/lxml/Manifest
@@ -1,2 +1 @@
-DIST lxml-4.7.1.tar.gz 958025 BLAKE2B d48a7aec9537235207fa387af7c49fe055ffa8e03bcea3e59807dfe35c72f1b1e01586aded550b53d5b7fac733baa1d47fbeea8fba937844de6dab10e02a3832 SHA512 33c88ff07152437a09268f3348ada97549686b5a59e2135631991ecc79ad02f35c20aae5d8363d2795bf058b05ef70fa6fbb56b081308cd89b073e176f4872d9
 DIST lxml-4.8.0.tar.gz 959376 BLAKE2B a40be5e058153e1dc3f8501b645b0211f4498928ed71b161df54a67501356e9968064401b6d17e17dc8d62223b29e794eaa2bee7ff78ffee203d9f9a22f3e1c2 SHA512 bbcd8ea001cfa2820dcac4e00de6ded81700b2f0bd4a58bcdd4da05a19a107f57cd56280c4838fe19ee7ecd6be105878bf8c2f1c0e5111899c4ad1a2ba03537f

diff --git a/dev-python/lxml/lxml-4.7.1.ebuild b/dev-python/lxml/lxml-4.7.1.ebuild
deleted file mode 100644
index 8ddbda82c77d..000000000000
--- a/dev-python/lxml/lxml-4.7.1.ebuild
+++ /dev/null
@@ -1,97 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} pypy3 )
-
-inherit distutils-r1 optfeature toolchain-funcs
-
-DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
-HOMEPAGE="https://lxml.de/ https://pypi.org/project/lxml/ https://github.com/lxml/lxml"
-SRC_URI="https://github.com/lxml/lxml/archive/${P}.tar.gz"
-S=${WORKDIR}/lxml-${P}
-
-LICENSE="BSD ElementTree GPL-2 PSF-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
-IUSE="doc examples +threads test"
-RESTRICT="!test? ( test )"
-
-# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
-RDEPEND="
-	>=dev-libs/libxml2-2.9.12-r2
-	>=dev-libs/libxslt-1.1.28"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	dev-python/cython[${PYTHON_USEDEP}]
-	doc? (
-		$(python_gen_any_dep '
-			dev-python/docutils[${PYTHON_USEDEP}]
-			dev-python/pygments[${PYTHON_USEDEP}]
-			dev-python/sphinx[${PYTHON_USEDEP}]
-			dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
-		')
-	)
-	test? ( dev-python/cssselect[${PYTHON_USEDEP}] )
-	"
-
-DISTUTILS_IN_SOURCE_BUILD=1
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-4.6.0-tests-pypy.patch
-)
-
-python_check_deps() {
-	use doc || return 0
-	has_version "dev-python/docutils[${PYTHON_USEDEP}]" &&
-	has_version "dev-python/pygments[${PYTHON_USEDEP}]" &&
-	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
-	has_version "dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]"
-}
-
-python_prepare_all() {
-	# avoid replacing PYTHONPATH in tests.
-	sed -i -e '/sys\.path/d' test.py || die
-
-	# don't use some random SDK on Darwin
-	sed -i -e '/_ldflags =/s/=.*isysroot.*darwin.*None/= None/' \
-		setupinfo.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile() {
-	tc-export PKG_CONFIG
-	distutils-r1_python_compile
-}
-
-python_compile_all() {
-	use doc && emake html
-}
-
-python_test() {
-	cp -r -l src/lxml/tests "${BUILD_DIR}"/lib/lxml/ || die
-	cp -r -l src/lxml/html/tests "${BUILD_DIR}"/lib/lxml/html/ || die
-	ln -s "${S}"/doc "${BUILD_DIR}"/ || die
-
-	"${EPYTHON}" test.py -vv --all-levels -p || die "Test ${test} fails with ${EPYTHON}"
-}
-
-python_install_all() {
-	if use doc; then
-		local DOCS=( README.rst *.txt doc/*.txt )
-		local HTML_DOCS=( doc/html/. )
-	fi
-	if use examples; then
-		dodoc -r samples
-	fi
-
-	distutils-r1_python_install_all
-}
-
-pkg_postinst() {
-	optfeature "Support for BeautifulSoup as a parser backend" dev-python/beautifulsoup4
-	optfeature "Translates CSS selectors to XPath 1.0 expressions" dev-python/cssselect
-}