[gentoo-commits] repo/gentoo:master commit in: dev-python/nbconvert/

[Michał Górny]

commit:     393bfea6ccfecd1de5c2ab63411f7fc3fd5e82b5
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 25 06:39:42 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Sep 25 07:45:15 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=393bfea6

dev-python/nbconvert: Bump to 6.2.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nbconvert/Manifest               |  1 +
 dev-python/nbconvert/nbconvert-6.2.0.ebuild | 71 +++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 88f54fefe08..524cfbd65ad 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1 +1,2 @@
 DIST nbconvert-6.0.7.tar.gz 896833 BLAKE2B 1b5b39144509aa9f61dc1e9675b112d69ed2e2f9859f3ce7ccfac517d89fff0010062c03ded1c3db571c84dd8d4f8ba12e4851245f370d2e671d24921dd50ab6 SHA512 3c78fa4d777a79a08606a39bb31f6b329dc9d28c1ef2ea9f3253746dce853a295e8fe85b14c65b04762aa5acd5facc879232a375875a2ca6dc9477cc1ab88786
+DIST nbconvert-6.2.0.tar.gz 898501 BLAKE2B 6dfcd33c4bf625a2f68dd4b89cc15d100a2b036e08f3918731f019d171224c218f669e07fd7d6aed712c52448dbf71e6173a49b560faa7d5f13e3cce62df0fff SHA512 ed67cafd23dbe9d8e08292877cae9c889518218659f2ca615fe52fe937f70cdca3e300a28dbda81578ede7784458443bb9fa1994e05c154dd5473015b91c9af3

diff --git a/dev-python/nbconvert/nbconvert-6.2.0.ebuild b/dev-python/nbconvert/nbconvert-6.2.0.ebuild
new file mode 100644
index 00000000000..7278542508d
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.2.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.7.4[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+		media-gfx/inkscape
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		nbconvert/exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		'nbconvert/tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	distutils_install_for_testing bdist_egg
+	cd "${TEST_DIR}"/lib || die
+	epytest --pyargs nbconvert
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}