[gentoo-commits] gentoo-x86 commit in sys-libs/ss: ChangeLog ss-1.40.4.ebuild

[Mike Frysinger (vapier)]

vapier      08/01/01 12:51:23

  Modified:             ChangeLog
  Added:                ss-1.40.4.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.4_rc12)

Revision  Changes    Path
1.44                 sys-libs/ss/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	12 Dec 2007 01:24:40 -0000	1.43
+++ ChangeLog	1 Jan 2008 12:51:22 -0000	1.44
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/ss
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v 1.43 2007/12/12 01:24:40 ranger Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v 1.44 2008/01/01 12:51:22 vapier Exp $
+
+*ss-1.40.4 (01 Jan 2008)
+
+  01 Jan 2008; Mike Frysinger <vapier@g.o>
+  +files/ss-1.40.4-check.patch, +ss-1.40.4.ebuild:
+  Version bump.
 
   12 Dec 2007; Brent Baude <ranger@g.o> ss-1.40.3.ebuild:
   Marking ss-1.40.3 ppc64 stable as dep for bug 201546



1.1                  sys-libs/ss/ss-1.40.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ss-1.40.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ss-1.40.4.ebuild?rev=1.1&content-type=text/plain

Index: ss-1.40.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ss-1.40.4.ebuild,v 1.1 2008/01/01 12:51:22 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="Subsystem command parsing library"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/e2fsprogs-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND="~sys-libs/com_err-${PV}"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/e2fsprogs-${PV}

env_setup() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.39-makefile.patch
	epatch "${FILESDIR}"/${PN}-1.40.4-check.patch #201762
}

src_compile() {
	env_setup

	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	econf \
		--enable-${libtype}-shlibs \
		--with-ldopts="${LDFLAGS}" \
		$(use_enable nls) \
		|| die
	emake -C lib/ss COMPILE_ET=compile_et || die "make ss failed"
}

src_test() {
	env_setup

	ln -s $(${CC} -print-file-name=libcom_err.so) lib/libcom_err.so
	emake -j1 -C lib/ss check || die "make check failed"
}

src_install() {
	env_setup

	dodir /usr/share/man/man1
	make -C lib/ss DESTDIR="${D}" install || die

	# Move shared libraries to /lib/, install static libraries to /usr/lib/,
	# and install linker scripts to /usr/lib/.
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)/ || die "move .so"
	dolib.a lib/libss.a || die "dolib.a"
	gen_usr_ldscript libss.so
}



-- 
gentoo-commits@g.o mailing list