[gentoo-commits] repo/gentoo:master commit in: net-dns/pdns-recursor/

[Sven Wegener]

commit:     8fbf54bc21dd4b5c777be76a031350782ced07e8
Author:     Sven Wegener <swegener <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 23 20:37:55 2022 +0000
Commit:     Sven Wegener <swegener <AT> gentoo <DOT> org>
CommitDate: Tue Aug 23 20:49:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8fbf54bc

net-dns/pdns-recursor: Version bump, security bug #866219

Bug: https://bugs.gentoo.org/866219
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Sven Wegener <swegener <AT> gentoo.org>

 net-dns/pdns-recursor/Manifest                   |  1 +
 net-dns/pdns-recursor/pdns-recursor-4.7.2.ebuild | 88 ++++++++++++++++++++++++
 2 files changed, 89 insertions(+)

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 30f5b141869d..39cb78d8c67a 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1 +1,2 @@
 DIST pdns-recursor-4.7.1.tar.bz2 1597536 BLAKE2B fc5d7ee80823ad55a986a9317d4be5be7d1ec1d1b993a5bb1bf0c138a901d4f81d4ebcef5e9774cd5de88c9f650053be26dc01dfd31b989dae25d53d12b87bad SHA512 7769c4c082bbf52b0e13adbe9c1c7272a638c0b2b11e1d76794cea66dfe8dc83b07989fa16707a7cc682e8c366ef4c1d37a614ad2841af33ccb9adec6270e07f
+DIST pdns-recursor-4.7.2.tar.bz2 1580602 BLAKE2B 2d32d553629f665f9060e58f994a0256adc936f6fdb32ecd236ba202731342fe7e17db6678649292b4d1dd97e8579851e38fe41fd4f122dbf3d63f3d71c5de13 SHA512 b80fb1f403d5b81cf7500f6fce64914ab858b7bd7f617265db9a11ea78786de702563482c5b9daa5c9da1c19a0d02d90fd1f4f14b740d2fd492def7f4b1a7def

diff --git a/net-dns/pdns-recursor/pdns-recursor-4.7.2.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.7.2.ebuild
new file mode 100644
index 000000000000..fe258d909f08
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.7.2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	elibc_glibc? (
+		arm? ( >=sys-libs/glibc-2.34 )
+		x86? ( >=sys-libs/glibc-2.34 )
+	)
+	dev-libs/openssl:=
+	>=dev-libs/boost-1.35:=[context]"
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+	append-lfs-flags
+	append-cppflags -D_TIME_BITS=64
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}