[gentoo-commits] gentoo-x86 commit in net-im/kadu: metadata.xml kadu-0.11.0.ebuild ChangeLog

[Maciej Mrozowski (reavertm)]

reavertm    12/02/06 20:11:51

  Modified:             metadata.xml ChangeLog
  Added:                kadu-0.11.0.ebuild
  Log:
  Version bump, bug 402319.
  
  (Portage version: 2.2.0_alpha85/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 net-im/kadu/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/metadata.xml?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/metadata.xml?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/metadata.xml?r1=1.24&r2=1.25

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/kadu/metadata.xml,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- metadata.xml	16 Dec 2011 16:45:13 -0000	1.24
+++ metadata.xml	6 Feb 2012 20:11:50 -0000	1.25
@@ -12,6 +12,7 @@
 		<description>Please CC on bugs</description>
 	</maintainer>
 	<use>
+		<flag name="ayatana">Enables support for Ayatana notifications using <pkg>libindicate-qt</pkg></flag>
 		<flag name="gadu">Enables Gadu communication protocol</flag>
 		<flag name="mpd">Enables Music Player Daemon support</flag>
 		<flag name="phonon">Enables phonon audio plugin</flag>



1.120                net-im/kadu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/kadu/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	28 Jan 2012 02:56:07 -0000	1.119
+++ ChangeLog	6 Feb 2012 20:11:51 -0000	1.120
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/kadu
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/ChangeLog,v 1.119 2012/01/28 02:56:07 reavertm Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/ChangeLog,v 1.120 2012/02/06 20:11:51 reavertm Exp $
+
+*kadu-0.11.0 (06 Feb 2012)
+
+  06 Feb 2012; Maciej Mrozowski <reavertm@g.o> +kadu-0.11.0.ebuild,
+  metadata.xml:
+  Version bump, bug 402319.
 
   28 Jan 2012; Maciej Mrozowski <reavertm@g.o>
   -files/kadu-0.10.0-cmake.patch, -files/kadu-0.10.0-sdk-cmake.patch,



1.1                  net-im/kadu/kadu-0.11.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/kadu-0.11.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/kadu/kadu-0.11.0.ebuild?rev=1.1&content-type=text/plain

Index: kadu-0.11.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/kadu-0.11.0.ebuild,v 1.1 2012/02/06 20:11:50 reavertm Exp $

EAPI="4"

inherit base cmake-utils flag-o-matic

MY_P="${P/_/-}"

DESCRIPTION="An open source Gadu-Gadu and Jabber/XMPP protocol Instant Messenger client."
HOMEPAGE="http://www.kadu.net"
SRC_URI="http://download.kadu.im/stable/${MY_P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"
SLOT="0"
IUSE="ayatana +gadu mpd phonon sdk speech spell xmpp"
REQUIRED_USE="
	|| (
		gadu
		xmpp
	)
"
COMMON_DEPEND="
	>=app-crypt/qca-2.0.0-r2
	>=net-libs/libgadu-1.11.1[threads]
	x11-libs/libXfixes
	x11-libs/libXScrnSaver
	>=x11-libs/qt-dbus-4.7.0:4
	>=x11-libs/qt-gui-4.7.0:4
	>=x11-libs/qt-script-4.7.0:4
	>=x11-libs/qt-sql-4.7.0:4[sqlite]
	>=x11-libs/qt-webkit-4.7.0:4
	ayatana? ( dev-libs/libindicate-qt )
	gadu? ( >=x11-libs/qt-xmlpatterns-4.7.0:4 )
	mpd? ( media-libs/libmpdclient )
	phonon? (
		|| (
			media-libs/phonon
			>=x11-libs/qt-phonon-4.7.0:4
		)
	)
	spell? ( app-text/enchant )
	xmpp? (
		net-dns/libidn
		sys-libs/zlib
	)
"
DEPEND="${COMMON_DEPEND}
	x11-proto/fixesproto
	x11-proto/scrnsaverproto
"
RDEPEND="${COMMON_DEPEND}
	app-crypt/qca-ossl:2
	speech? ( app-accessibility/powiedz )
"

PLUGINS='amarok1_mediaplayer antistring auto_hide autoaway autoresponder autostatus cenzor chat_notify config_wizard desktop_docking docking encryption_ng encryption_ng_simlite exec_notify ext_sound falf_mediaplayer filedesc firewall freedesktop_notify hints history idle imagelink last_seen mediaplayer mprisplayer_mediaplayer pcspeaker qt4_docking qt4_docking_notify screenshot simpleview single_window sms sound sql_history tabs word_fix'

src_configure() {
	# Filter out dangerous flags
	filter-flags -fno-rtti
	strip-unsupported-flags

	# Ensure -DQT_NO_DEBUG is added
	append-cppflags -DQT_NO_DEBUG

	# Plugin selection
	if use gadu; then
		PLUGINS+=' gadu_protocol history_migration profiles_import'
	fi

	use mpd && PLUGINS+=' mpd_mediaplayer'
	use xmpp && PLUGINS+=' jabber_protocol'
	use phonon && PLUGINS+=' phonon_sound'
	use speech && PLUGINS+=' speech'
	use spell && PLUGINS+=' spellchecker'

	# Configure package
	local mycmakeargs=(
		-DBUILD_DESCRIPTION='Gentoo Linux'
		-DCOMPILE_PLUGINS="${PLUGINS}"
		-DNETWORK_IMPLEMENTATION="Qt"
		-DSIG_HANDLING_ENABLED=TRUE
		$(cmake-utils_use sdk INSTALL_SDK)
		$(cmake-utils_use_with ayatana INDICATE_QT)
		$(cmake-utils_use_with spell ENCHANT)
	)
	unset PLUGINS

	cmake-utils_src_configure
}