[gentoo-commits] gentoo-x86 commit in sys-apps/pcsc-tools: pcsc-tools-1.4.23.ebuild ChangeLog pcsc-tools-1.4.21.ebuild

[Diego Petteno (flameeyes)]

flameeyes    14/09/29 20:21:03

  Modified:             ChangeLog
  Added:                pcsc-tools-1.4.23.ebuild
  Removed:              pcsc-tools-1.4.21.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key D4301342)

Revision  Changes    Path
1.18                 sys-apps/pcsc-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-tools/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-tools/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-tools/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pcsc-tools/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	26 Jan 2014 16:54:39 -0000	1.17
+++ ChangeLog	29 Sep 2014 20:21:03 -0000	1.18
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pcsc-tools
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-tools/ChangeLog,v 1.17 2014/01/26 16:54:39 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-tools/ChangeLog,v 1.18 2014/09/29 20:21:03 flameeyes Exp $
+
+*pcsc-tools-1.4.23 (29 Sep 2014)
+
+  29 Sep 2014; Diego E. Pettenò <flameeyes@g.o>
+  +pcsc-tools-1.4.23.ebuild, -pcsc-tools-1.4.21.ebuild:
+  Version bump.
 
 *pcsc-tools-1.4.22 (26 Jan 2014)
 



1.1                  sys-apps/pcsc-tools/pcsc-tools-1.4.23.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-tools/pcsc-tools-1.4.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-tools/pcsc-tools-1.4.23.ebuild?rev=1.1&content-type=text/plain

Index: pcsc-tools-1.4.23.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-tools/pcsc-tools-1.4.23.ebuild,v 1.1 2014/09/29 20:21:03 flameeyes Exp $

EAPI="4"

inherit eutils fdo-mime multilib toolchain-funcs

DESCRIPTION="PC/SC Architecture smartcard tools"
HOMEPAGE="http://ludovic.rousseau.free.fr/softwares/pcsc-tools/"
SRC_URI="http://ludovic.rousseau.free.fr/softwares/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
IUSE="gtk network-cron"

RDEPEND=">=sys-apps/pcsc-lite-1.4.14"

DEPEND="${RDEPEND}
	virtual/pkgconfig"
RDEPEND="${RDEPEND}
	dev-perl/pcsc-perl
	gtk? ( dev-perl/gtk2-perl )"

src_prepare() {
	sed -i -e 's:-Wall -O2:$(CFLAGS):g' Makefile
}

src_compile() {
	# explicitly only build the pcsc_scan application, or the man
	# pages will be gzipped first, and then unpacked.
	emake pcsc_scan CC=$(tc-getCC)
}

src_install() {
	# install manually, makes it much easier since the Makefile
	# requires fiddling with
	dobin ATR_analysis scriptor pcsc_scan
	doman pcsc_scan.1 scriptor.1p ATR_analysis.1p

	dodoc README Changelog

	if use gtk; then
		domenu gscriptor.desktop
		dobin gscriptor
		doman gscriptor.1p
	fi

	if use network-cron ; then
		exeinto /etc/cron.monthly
		newexe "${FILESDIR}"/smartcard.cron update-smartcard_list
	fi

	insinto /usr/share/pcsc
	doins smartcard_list.txt
}

pkg_postinst() {
	use gtk && fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}