[gentoo-commits] gentoo-x86 commit in www-client/epiphany: epiphany-3.12.0.ebuild ChangeLog

[Gilles Dartiguelongue (eva)]

eva         14/04/27 21:47:45

  Modified:             ChangeLog
  Added:                epiphany-3.12.0.ebuild
  Log:
  Version bump for Gnome 3.12.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.306                www-client/epiphany/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.306&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.306&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?r1=1.305&r2=1.306

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v
retrieving revision 1.305
retrieving revision 1.306
diff -u -r1.305 -r1.306
--- ChangeLog	27 Apr 2014 09:10:40 -0000	1.305
+++ ChangeLog	27 Apr 2014 21:47:45 -0000	1.306
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/epiphany
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.305 2014/04/27 09:10:40 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.306 2014/04/27 21:47:45 eva Exp $
+
+*epiphany-3.12.0 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@g.o> +epiphany-3.12.0.ebuild,
+  +files/epiphany-3.12.0-missing-symbol.patch:
+  Version bump for Gnome 3.12.
 
   27 Apr 2014; Pacho Ramos <pacho@g.o> -epiphany-3.8.2.ebuild:
   drop old



1.1                  www-client/epiphany/epiphany-3.12.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/epiphany-3.12.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/epiphany-3.12.0.ebuild?rev=1.1&content-type=text/plain

Index: epiphany-3.12.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-3.12.0.ebuild,v 1.1 2014/04/27 21:47:45 eva Exp $

EAPI="5"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

inherit autotools eutils gnome2 pax-utils versionator virtualx

DESCRIPTION="GNOME webbrowser based on Webkit"
HOMEPAGE="http://projects.gnome.org/epiphany/"

# TODO: coverage
LICENSE="GPL-2"
SLOT="0"
IUSE="+jit +nss test"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

COMMON_DEPEND="
	>=app-crypt/gcr-3.5.5
	>=app-crypt/libsecret-0.14
	>=app-text/iso-codes-0.35
	>=dev-libs/glib-2.38:2
	>=dev-libs/libxml2-2.6.12:2
	>=dev-libs/libxslt-1.1.7
	>=gnome-base/gsettings-desktop-schemas-0.0.1
	>=net-dns/avahi-0.6.22[dbus]
	>=net-libs/webkit-gtk-2.4:3[jit?]
	>=net-libs/libsoup-2.42.1:2.4
	>=x11-libs/gtk+-3.11.6:3
	>=x11-libs/libnotify-0.5.1:=
	gnome-base/gnome-desktop:3=

	dev-db/sqlite:3
	x11-libs/libwnck:3
	x11-libs/libX11

	x11-themes/gnome-icon-theme
	x11-themes/gnome-icon-theme-symbolic

	nss? ( dev-libs/nss )
"
# epiphany-extensions support was removed in 3.7; let's not pretend it still works
RDEPEND="${COMMON_DEPEND}
	!www-client/epiphany-extensions
"
# paxctl needed for bug #407085
# eautoreconf requires gnome-common-3.5.5
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.50
	sys-apps/paxctl
	sys-devel/gettext
	virtual/pkgconfig
"

# Tests refuse to run with the gsettings trick for some reason
RESTRICT="test"

src_prepare() {
	# Fix missing symbol in webextensio.so
	epatch "${FILESDIR}"/${P}-missing-symbol.patch

	eautoreconf
	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		--enable-shared \
		--disable-static \
		--with-distributor-name=Gentoo \
		$(use_enable nss) \
		$(use_enable test tests) \
		ITSTOOL=$(type -P true)
}

src_compile() {
	# needed to avoid "Command line `dbus-launch ...' exited with non-zero exit status 1"
	unset DISPLAY
	gnome2_src_compile
}

src_test() {
	# FIXME: this should be handled at eclass level
	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die

	unset DISPLAY
	GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
}

src_install() {
	DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"
	gnome2_src_install
	use jit && pax-mark m "${ED}usr/bin/epiphany"
}