[gentoo-commits] repo/gentoo:master commit in: media-sound/erec/

[Andreas Sturmlechner]

commit:     bbe0edcdd17fda4e14ad085b5c7ac02df2117d5a
Author:     Michael Mair-Keimberger <m.mairkeimberger <AT> gmail <DOT> com>
AuthorDate: Fri May 24 05:08:52 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat May 25 20:54:39 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bbe0edcd

media-sound/erec: EAPI=7 bump

Closes: https://bugs.gentoo.org/686642
Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger <AT> gmail.com>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/erec/erec-2.2.0.1-r1.ebuild | 46 +++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/media-sound/erec/erec-2.2.0.1-r1.ebuild b/media-sound/erec/erec-2.2.0.1-r1.ebuild
new file mode 100644
index 00000000000..527e1ace368
--- /dev/null
+++ b/media-sound/erec/erec-2.2.0.1-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Shared audio recording server"
+HOMEPAGE="https://bisqwit.iki.fi/source/erec.html"
+SRC_URI="https://bisqwit.iki.fi/src/arch/${P}.tar.bz2"
+
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+LICENSE="GPL-2+"
+SLOT="0"
+
+PATCHES=( "${FILESDIR}/${P}-gcc43.patch" )
+
+DOCS=( README )
+HTML_DOCS=( README.html )
+
+src_prepare() {
+	sed -i \
+		-e "s:BINDIR=/usr/local/bin:BINDIR=${D}usr/bin:" \
+		-e "s:^\\(ARGHLINK.*-L.*\\):#\\1:" \
+		-e "s:^#\\(ARGHLINK=.*a\\)$:\\1:" \
+		-e "s:\$(CXX):\$(CXX) \$(CXXFLAGS) -I\"${S}\"/argh:g" \
+		Makefile || die
+
+	sed -i \
+		 -e "s:CPPFLAGS=:CPPFLAGS=-I\"${S}\"/argh :" \
+		Makefile.sets || die
+
+	echo "" > .depend || die
+	echo "" > argh/.depend || die
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" \
+		CXXFLAGS="${CXXFLAGS}" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" -j1
+}
+
+src_install() {
+	dobin erec
+	einstalldocs
+}