[gentoo-commits] gentoo-x86 commit in media-libs/libmediainfo: libmediainfo-0.7.36-r1.ebuild ChangeLog libmediainfo-0.7.36.ebuild

[Tim Harder (radhermit)]

radhermit    10/10/29 05:56:16

  Modified:             ChangeLog
  Added:                libmediainfo-0.7.36-r1.ebuild
  Removed:              libmediainfo-0.7.36.ebuild
  Log:
  Revision bump and remove old. Fixes linking problem (bug #343125 by Jouni Rinne) and use emake instead of einstall.
  
  (Portage version: 2.2.0_alpha2/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  media-libs/libmediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	28 Oct 2010 07:07:58 -0000	1.4
+++ ChangeLog	29 Oct 2010 05:56:16 -0000	1.5
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libmediainfo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.4 2010/10/28 07:07:58 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.5 2010/10/29 05:56:16 radhermit Exp $
+
+*libmediainfo-0.7.36-r1 (29 Oct 2010)
+
+  29 Oct 2010; Tim Harder <radhermit@g.o>
+  -libmediainfo-0.7.36.ebuild, +libmediainfo-0.7.36-r1.ebuild:
+  Revision bump and remove old. Fixes linking problem (bug #343125 by Jouni
+  Rinne) and use emake instead of einstall.
 
 *libmediainfo-0.7.36 (28 Oct 2010)
 



1.1                  media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild?rev=1.1&content-type=text/plain

Index: libmediainfo-0.7.36-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild,v 1.1 2010/10/29 05:56:16 radhermit Exp $

EAPI="2"

inherit autotools multilib

MY_PN="MediaInfo"
DESCRIPTION="MediaInfo libraries"
HOMEPAGE="http://mediainfo.sourceforge.net/"
SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"

S="${WORKDIR}/${MY_PN}Lib/Project/GNU/Library"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl debug doc libmms static-libs"

RDEPEND="sys-libs/zlib
	>=media-libs/libzen-0.4.14[static-libs=]
	curl? ( net-misc/curl )
	libmms? ( >=media-libs/libmms-0.4 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

src_prepare() {
	# https://bugs.launchpad.net/libmms/+bug/531326
	sed -i -e 's/mmsx/mms/g' \
		"${WORKDIR}/${MY_PN}Lib/Source/MediaInfo/Reader/Reader_libmms.cpp" \
		|| die "sed failed"

	# Fix linking problem for bug #343125
	sed -i -e "s:\(#define LIBCURL_DLL_RUNTIME\)://\1:" \
		"${WORKDIR}/${MY_PN}Lib/Source/MediaInfo/Reader/Reader_libcurl.cpp" \
		|| die "sed failed"

	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		--enable-shared \
		$(use_enable debug) \
		$(use_with curl libcurl) \
		$(use_with libmms) \
		$(use_enable static-libs static) \
		$(use_enable static-libs staticlibs)
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
		doxygen Doxyfile || die "doxygen failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	insinto "/usr/$(get_libdir)/pkgconfig"
	doins "${PN}.pc" || die

	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
		insinto "/usr/include/${MY_PN}/${x}"
		doins "${WORKDIR}/${MY_PN}Lib/Source/${MY_PN}/${x}/"*.h || die
	done

	dodoc "${WORKDIR}/${MY_PN}Lib/"*.txt
	if use doc; then
		dohtml "${WORKDIR}/${MY_PN}Lib/Source/Doc/Documentation.html" || die
		dohtml -r "${WORKDIR}/${MY_PN}Lib/Doc" || die
	fi
}