[gentoo-commits] repo/gentoo:master commit in: media-libs/aubio/

[Lars Wendler]

commit:     9a4fc0238e3cb400d531479d045dd6dd167fa605
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 25 08:21:19 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Sep 25 08:21:19 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a4fc023

media-libs/aubio: Bump to version 0.4.7

Package-Manager: Portage-2.3.50, Repoman-2.3.11

 media-libs/aubio/Manifest           |   1 +
 media-libs/aubio/aubio-0.4.7.ebuild | 112 ++++++++++++++++++++++++++++++++++++
 2 files changed, 113 insertions(+)

diff --git a/media-libs/aubio/Manifest b/media-libs/aubio/Manifest
index c44983e3ee0..1241c55db3e 100644
--- a/media-libs/aubio/Manifest
+++ b/media-libs/aubio/Manifest
@@ -2,3 +2,4 @@ DIST aubio-0.4.1.tar.bz2 288136 BLAKE2B ba7368fab21fec73dc555ea0d7291eea010a415d
 DIST aubio-0.4.2.tar.bz2 304216 BLAKE2B aab7e55d580105e6180503503ae2970d150d86e445d5c1b10d3f39c8cdf7496d0c280a57a2fc7ad3ea5142996d56c53cd2e1c6f736fb1a98b9b142438c919e04 SHA512 b57b6d147b305a264f0055726f76a8452f784b556a7fda911f056adbedd2855048e93c0e21b9f359e3f442f1542189aff0c214dd85141e2e06048a07f47703ff
 DIST aubio-0.4.5.tar.bz2 350615 BLAKE2B 2108b4e2c9ef7f15631d785f71d6bce6804b0b61a5022e75a841e9e0772b6a4e9e53fe11c74e3907aa74eb1191bc0a5082f4854d2fe0746e14a4f9ac50ae06b2 SHA512 0aeaee5efc117201ca7b1fe2a421826ade83ce5b3ba50c27a8cf65debeedb20dd5a5ac28e20935bb29ca2b0d1b70cf93feee298989dfc79978f689e989235608
 DIST aubio-0.4.6.tar.bz2 363016 BLAKE2B 3847ed02b7d64d9796bd1f5a06044d945f5859ab87a762978bf2b0b6650cc0e19c9b8eec99a793e14dd25c06f66d2bffd453ecca824fbc5f47700fda7f78854b SHA512 0e5cab0c88d51f2fb70c0d85e1c067a7b3758fbffdbd5026686726379aa36203adb63ed3f8e40c83ea02930e0ffc4e6c246803f1d518d448d47a01984678e77d
+DIST aubio-0.4.7.tar.bz2 372173 BLAKE2B 544239b215dd87d4cf4a6ed6b5dd856411d0a3f1c3242e3e1077fa0780160785a9934884a1f0d0dc80fe21b1d417bc3800db59842ec300a4c29d75b7942cba05 SHA512 30c614f2b502b993df28d4746a99421fe0aada33c98c42ea19c271554b29b360cb4d4f6650c1b1da508da4bc341348c5944cb452f69b2bf354ca6348f84de260

diff --git a/media-libs/aubio/aubio-0.4.7.ebuild b/media-libs/aubio/aubio-0.4.7.ebuild
new file mode 100644
index 00000000000..9cb10b60097
--- /dev/null
+++ b/media-libs/aubio/aubio-0.4.7.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='threads(+)'
+
+inherit distutils-r1 waf-utils multilib eutils
+
+DESCRIPTION="Library for audio labelling"
+HOMEPAGE="https://aubio.org/"
+SRC_URI="https://aubio.org/pub/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0/5"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc double-precision examples ffmpeg fftw jack libav libsamplerate sndfile python"
+
+RDEPEND="
+	ffmpeg? (
+		!libav? ( >=media-video/ffmpeg-2.6:0= )
+		libav? ( >=media-video/libav-9:0= )
+	)
+	fftw? ( sci-libs/fftw:3.0 )
+	jack? ( virtual/jack )
+	libsamplerate? ( media-libs/libsamplerate )
+	python? ( dev-python/numpy[${PYTHON_USEDEP}] ${PYTHON_DEPS} )
+	sndfile? ( media-libs/libsndfile )
+"
+DEPEND="
+	${RDEPEND}
+	${PYTHON_DEPS}
+	app-text/txt2man
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS ChangeLog README.md )
+PYTHON_SRC_DIR="${S}"
+
+src_prepare() {
+	default
+	sed -i -e "s:doxygen:doxygen_disabled:" wscript || die
+}
+
+src_configure() {
+	python_setup
+	waf-utils_src_configure \
+		--enable-complex \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable double-precision double) \
+		$(use_enable fftw fftw3f) \
+		$(use_enable fftw fftw3) \
+		$(use_enable ffmpeg avcodec) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable sndfile)
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	waf-utils_src_compile --notests
+
+	if use doc; then
+		cd "${S}"/doc || die
+		emake dirhtml
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	waf-utils_src_compile --alltests
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_test
+	fi
+}
+
+src_install() {
+	waf-utils_src_install
+
+	if use examples; then
+		# install dist_noinst_SCRIPTS from Makefile.am
+		dodoc -r examples
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		DOCS="" distutils-r1_src_install
+		newdoc python/README.md README.python
+	fi
+
+	if use doc; then
+		dodoc doc/*.txt
+		docinto html
+		dodoc -r doc/_build/dirhtml/.
+	fi
+
+	find "${ED}" -name "*.a" -delete || die
+}