[gentoo-commits] repo/gentoo:master commit in: dev-libs/folks/

[Gilles Dartiguelongue]

commit:     b92b19196819f6ac090bd2efa2db9ee9f762d8f1
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 11 13:20:10 2018 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Tue Dec 11 13:21:06 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b92b1919

dev-libs/folks: fix problem building against tracker-2

Introspection files must be regenerated since they contain
hard-references to the installed tracker revision which causes problems
on tracker soversion changes like the 2.0 release. The easiest way to
do that is to re-generate sources from vala directly. This problem
should vanish if the project is ever ported to meson.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Gilles Dartiguelongue <eva <AT> gentoo.org>

 dev-libs/folks/folks-0.11.4-r1.ebuild | 87 +++++++++++++++++++++++++++++++++++
 1 file changed, 87 insertions(+)

diff --git a/dev-libs/folks/folks-0.11.4-r1.ebuild b/dev-libs/folks/folks-0.11.4-r1.ebuild
new file mode 100644
index 00000000000..821d24168b2
--- /dev/null
+++ b/dev-libs/folks/folks-0.11.4-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Library for aggregating people from multiple sources"
+HOMEPAGE="https://wiki.gnome.org/Projects/Folks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/25" # subslot = libfolks soname version
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+
+# TODO: --enable-profiling
+# Vala isn't really optional, https://bugzilla.gnome.org/show_bug.cgi?id=701099
+IUSE="bluetooth debug eds +telepathy test tracker utils"
+REQUIRED_USE="bluetooth? ( eds )"
+
+COMMON_DEPEND="
+	$(vala_depend)
+	>=dev-libs/glib-2.40:2
+	dev-libs/dbus-glib
+	>=dev-libs/gobject-introspection-1.30:=
+	>=dev-libs/libgee-0.10:0.8[introspection]
+	dev-libs/libxml2
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+
+	bluetooth? ( >=net-wireless/bluez-5 )
+	eds? ( >=gnome-extra/evolution-data-server-3.13.90:=[vala] )
+	telepathy? ( >=net-libs/telepathy-glib-0.19.9[vala] )
+	tracker? ( >=app-misc/tracker-1:0= )
+"
+# telepathy-mission-control needed at runtime; it is used by the telepathy
+# backend via telepathy-glib's AccountManager binding.
+RDEPEND="${COMMON_DEPEND}
+	net-im/telepathy-mission-control
+"
+# folks socialweb backend requires that libsocialweb be built with USE=vala,
+# even when building folks with --disable-vala.
+#
+# FIXME:
+# test? ( bluetooth? ( dbusmock is missing in the tree ) )
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50.0
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	test? (
+		sys-apps/dbus
+		bluetooth? (
+			>=gnome-extra/evolution-data-server-3.9.1
+			>=dev-libs/glib-2.40:2 ) )
+"
+
+src_prepare() {
+	# Force re-generation of introspection files, otherwise it does not match installed libs
+	find -name "*.vala" -exec touch {} \; || die
+
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Rebuilding docs needs valadoc, which has no release
+	gnome2_src_configure \
+		$(use_enable bluetooth bluez-backend) \
+		$(use_enable debug) \
+		$(use_enable eds eds-backend) \
+		$(use_enable eds ofono-backend) \
+		$(use_enable telepathy telepathy-backend) \
+		$(use_enable tracker tracker-backend) \
+		$(use_enable utils inspect-tool) \
+		$(use_enable test modular-tests) \
+		--enable-vala \
+		--enable-import-tool \
+		--disable-docs \
+		--disable-fatal-warnings \
+		--disable-libsocialweb-backend
+}
+
+src_test() {
+	dbus-launch virtx emake check
+}