[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-calculator/

[Matt Turner]

commit:     86f59c3d317e1641990daca810e2d80298b41165
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 30 21:57:03 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 30 21:58:40 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=86f59c3d

gnome-extra/gnome-calculator: Version bump to 40.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-calculator/Manifest              |  1 +
 .../gnome-calculator/gnome-calculator-40.1.ebuild  | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index 158bbbd6428..8577915a857 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-calculator-3.38.2.tar.xz 1004684 BLAKE2B c2b6a0ff2e6a91c43a1670945af989b715f0f7369050dac13bec02898ef6780ec4484c6ee9f6e6bb19b8ecc9d7d8c2df0c824ac9c3309783cbc89b96fe1f16b9 SHA512 41e58b34640e795108a552aa0d95b03f0c84c4d5af6eef7fe8350c5f4e031a0fad7cad73034b38b2121f09687815b6b10a6a86fb00c7cbf720ccb06a8eea0403
 DIST gnome-calculator-40.0.tar.xz 1022596 BLAKE2B 9522c8698492eeb07fbd86e8baeaee67433a1d43b2c97c4c895ca7ac8958a01c4e05c73598b1c14a2b333bfbc156b824669b20e878fcb681ade99c1ceef5ce72 SHA512 f22e9a9ade2f236142b7ebc3e54ed07834b049087ed8606571730e3bef2ab86317718df622368515266ba9578f660d7cd892cf87cf43bca9441369c838967c5d
+DIST gnome-calculator-40.1.tar.xz 1023164 BLAKE2B 977fc227adaa50efa271776035a11ca79166a703c9c8d618c13af477056622a9faa42c3a8876257a117486399e91fceec7a19b930293883078846a645db912fe SHA512 f46acc802ef130ec59e4376a02032ab683e6d166d691d7c5f626e2a978f017f171c0e8ad50991d1828cb325b1bd53f63ef256b9b24860842224fa3dd7e27f4da

diff --git a/gnome-extra/gnome-calculator/gnome-calculator-40.1.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-40.1.ebuild
new file mode 100644
index 00000000000..17bd94f4fdf
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-40.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=x11-libs/gtk+-3.24.1:3
+	>=gui-libs/libhandy-1.0.0:1=
+	>=x11-libs/gtksourceview-4.0.2:4
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:2.4[vala]
+	x11-libs/gtksourceview:4[vala]
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+	# Automagic dep on valadoc - don't bother for now
+	sed -e '/subdir.*doc/d' -i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}