[gentoo-commits] gentoo-x86 commit in www-apps/mythweb: ChangeLog mythweb-0.27.1.ebuild

[Richard Freeman (rich0)]

rich0       14/06/01 12:10:41

  Modified:             ChangeLog
  Added:                mythweb-0.27.1.ebuild
  Log:
  bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x08C170DE55EC123A)

Revision  Changes    Path
1.102                www-apps/mythweb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/mythweb/ChangeLog?rev=1.102&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/mythweb/ChangeLog?rev=1.102&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/mythweb/ChangeLog?r1=1.101&r2=1.102

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/mythweb/ChangeLog,v
retrieving revision 1.101
retrieving revision 1.102
diff -u -r1.101 -r1.102
--- ChangeLog	3 Oct 2013 18:21:01 -0000	1.101
+++ ChangeLog	1 Jun 2014 12:10:41 -0000	1.102
@@ -1,6 +1,11 @@
 # ChangeLog for www-apps/mythweb
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/mythweb/ChangeLog,v 1.101 2013/10/03 18:21:01 rich0 Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/mythweb/ChangeLog,v 1.102 2014/06/01 12:10:41 rich0 Exp $
+
+*mythweb-0.27.1 (01 Jun 2014)
+
+  01 Jun 2014; Richard Freeman <rich0@g.o> +mythweb-0.27.1.ebuild:
+  bump
 
 *mythweb-0.27 (03 Oct 2013)
 



1.1                  www-apps/mythweb/mythweb-0.27.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/mythweb/mythweb-0.27.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/mythweb/mythweb-0.27.1.ebuild?rev=1.1&content-type=text/plain

Index: mythweb-0.27.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/mythweb/mythweb-0.27.1.ebuild,v 1.1 2014/06/01 12:10:41 rich0 Exp $

EAPI=4

inherit eutils webapp

#BACKPORTS="4f6ac2a60b"
# Release version
MY_PV="${PV%_p*}"
MY_P="mythweb-${MY_PV}"

DESCRIPTION="PHP scripts intended to manage MythTV from a web browser."
HOMEPAGE="http://www.mythtv.org"
LICENSE="GPL-2"
SRC_URI="https://github.com/MythTV/mythweb/archive/v${MY_PV}.tar.gz -> mythweb-${MY_PV}.tar.gz
	${BACKPORTS:+http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
IUSE=""
KEYWORDS="~amd64 ~ppc ~x86"

RDEPEND="dev-lang/php[json,mysql,session,posix]
	virtual/httpd-php
	dev-perl/DBI
	dev-perl/DBD-mysql
	dev-perl/HTTP-Date
	dev-perl/Net-UPnP"

DEPEND="${RDEPEND}"

need_httpd_cgi

S="${WORKDIR}/${MY_P}"

src_prepare() {
	cd "${S}"/../

	[[ -n ${BACKPORTS} ]] && \
		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/../patches" \
			epatch

	epatch_user
}

src_configure() {
	:
}

src_compile() {
	:
}

src_install() {
	webapp_src_preinst

	# Install docs
	cd "${S}"
	dodoc README INSTALL

	# Install htdocs files
	insinto "${MY_HTDOCSDIR}"
	doins mythweb.php
	doins -r classes
	doins -r configuration
	doins -r data
	doins -r includes
	doins -r js
	doins -r modules
	doins -r skins
	doins -r tests
	exeinto "${MY_HTDOCSDIR}"
	doexe mythweb.pl

	# Install our server config files
	webapp_server_configfile apache mythweb.conf.apache mythweb.conf
	webapp_server_configfile lighttpd mythweb.conf.lighttpd mythweb.conf
	webapp_server_configfile nginx "${FILESDIR}"/mythweb.conf.nginx \
		mythweb.include

	# Data needs to be writable and modifiable by the web server
	webapp_serverowned -R "${MY_HTDOCSDIR}"/data

	# Message to display after install
	webapp_postinst_txt en "${FILESDIR}"/0.25-postinstall-en.txt

	# Script to set the correct defaults on install
	webapp_hook_script "${FILESDIR}"/reconfig

	webapp_src_install
}