[gentoo-commits] repo/gentoo:master commit in: x11-misc/mozo/

[Adam Feldman]

commit:     57866a6cee443d6edbfe1e9c7d62105f85e0382f
Author:     Adam Feldman <NP-Hardass <AT> gentoo <DOT> org>
AuthorDate: Sun Sep  6 22:28:14 2020 +0000
Commit:     Adam Feldman <np-hardass <AT> gentoo <DOT> org>
CommitDate: Fri Sep 25 20:32:36 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=57866a6c

x11-misc/mozo: Update python, fix deps

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Adam Feldman <NP-Hardass <AT> gentoo.org>

 x11-misc/mozo/mozo-1.24.0-r1.ebuild | 69 +++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/x11-misc/mozo/mozo-1.24.0-r1.ebuild b/x11-misc/mozo/mozo-1.24.0-r1.ebuild
new file mode 100644
index 00000000000..8977a145b15
--- /dev/null
+++ b/x11-misc/mozo/mozo-1.24.0-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{3_6,3_7,3_8} )
+PYTHON_REQ_USE="xml"
+
+inherit mate python-r1
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Mozo menu editor for MATE"
+LICENSE="GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-python/pygobject-3:3[${PYTHON_USEDEP}]
+	>=mate-base/mate-menus-1.21.0[introspection]
+	x11-libs/gdk-pixbuf:2[introspection]
+	>=x11-libs/gtk+-3.22:3[introspection]
+	!!x11-misc/mate-menu-editor
+"
+
+RDEPEND="${COMMON_DEPEND}
+	virtual/libintl
+"
+
+DEPEND="${COMMON_DEPEND}
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	mate_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir mate_src_configure \
+		--disable-icon-update
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir emake check
+}
+
+src_install() {
+	installing() {
+		mate_src_install
+
+		# Massage shebang to make python_doscript happy
+		sed -e 's:#! '"${PYTHON}:#!/usr/bin/python:" \
+			-i mozo || die
+
+		python_doscript mozo
+		python_optimize
+	}
+
+	python_foreach_impl run_in_build_dir installing
+}