[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-streamdev: vdr-streamdev-0.5.0_pre20100124.ebuild ChangeLog

[Joerg Bornkessel (hd_brummy)]

hd_brummy    10/02/25 21:05:13

  Modified:             ChangeLog
  Added:                vdr-streamdev-0.5.0_pre20100124.ebuild
  Log:
  new snapshot; vdr-1.7.10 ready
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.9                  media-plugins/vdr-streamdev/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-streamdev/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-streamdev/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-streamdev/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-streamdev/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	7 Jul 2009 12:12:16 -0000	1.8
+++ ChangeLog	25 Feb 2010 21:05:12 -0000	1.9
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/vdr-streamdev
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-streamdev/ChangeLog,v 1.8 2009/07/07 12:12:16 zzam Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-streamdev/ChangeLog,v 1.9 2010/02/25 21:05:12 hd_brummy Exp $
+
+*vdr-streamdev-0.5.0_pre20100124 (25 Feb 2010)
+
+  25 Feb 2010; Joerg Bornkessel <hd_brummy@g.o>
+  +vdr-streamdev-0.5.0_pre20100124.ebuild:
+  new snapshot; vdr-1.7.10 ready
 
 *vdr-streamdev-0.5.0_pre20090706 (07 Jul 2009)
 



1.1                  media-plugins/vdr-streamdev/vdr-streamdev-0.5.0_pre20100124.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-streamdev/vdr-streamdev-0.5.0_pre20100124.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-streamdev/vdr-streamdev-0.5.0_pre20100124.ebuild?rev=1.1&content-type=text/plain

Index: vdr-streamdev-0.5.0_pre20100124.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-streamdev/vdr-streamdev-0.5.0_pre20100124.ebuild,v 1.1 2010/02/25 21:05:12 hd_brummy Exp $

EAPI="2"

MY_P="${PN}-${PV/_pre/-pre-}"
inherit vdr-plugin eutils

DESCRIPTION="vdr Plugin: Client/Server streaming plugin"
HOMEPAGE="http://www.magoa.net/linux/"
SRC_URI="http://vdr.websitec.de/download/${PN}/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="+client +server"

DEPEND=">=media-video/vdr-1.6.0"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P#vdr-}"

EXTERNREMUX_PATH=/usr/share/vdr/streamdev/externremux.sh

pkg_setup() {
	vdr-plugin_pkg_setup

	if ! use client && ! use server; then
		die "no plugins selected, change useflags and enable at least client or server!"
	fi
}

src_prepare() {
	vdr-plugin_src_prepare
	cd "${S}"

	# Moving externremux.sh out of /root
	sed -i remux/extern.c \
		-e "s#/root/externremux.sh#${EXTERNREMUX_PATH}#"

	# make subdir libdvbmpeg respect CXXFLAGS
	sed -i Makefile \
		-e '/CXXFLAGS.*+=/s:^:#:'
	sed -i libdvbmpeg/Makefile \
		-e 's:CFLAGS =  -g -Wall -O2:CFLAGS = $(CXXFLAGS) :'

	for flag in client server; do
		if ! use ${flag}; then
			sed -i Makefile \
				-e '/^all:/s/libvdr-$(PLUGIN)-'${flag}'.so//'
		fi
	done

	fix_vdr_libsi_include server/livestreamer.c
}

src_install() {
	vdr-plugin_src_install

	cd "${S}"
	if use server; then
		insinto /etc/vdr/plugins/streamdev
		newins streamdev/streamdevhosts.conf streamdevhosts.conf
		chown vdr:vdr "${D}"/etc/vdr -R
	fi
}

pkg_postinst() {
	vdr-plugin_pkg_postinst

	elog "If you want to use the externremux-feature, then put"
	elog "your custom script as ${EXTERNREMUX_PATH}."

	if [[ -e "${ROOT}"/etc/vdr/plugins/streamdevhosts.conf ]]; then
		einfo "move config file to new config DIR ${ROOT}/etc/vdr/plugins/streamdev/"
		mv "${ROOT}"/etc/vdr/plugins/streamdevhosts.conf "${ROOT}"/etc/vdr/plugins/streamdev/streamdevhosts.conf
	fi
}