[gentoo-commits] gentoo-x86 commit in games-action/hotline-miami: metadata.xml ChangeLog hotline-miami-1.0.9a.ebuild Manifest

[Julian Ospald (hasufell)]

hasufell    13/11/24 18:14:46

  Added:                metadata.xml ChangeLog hotline-miami-1.0.9a.ebuild
                        Manifest
  Log:
  initial import
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.1                  games-action/hotline-miami/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>games</herd>
	<maintainer>
		<email>hasufell@g.o</email>
		<name>Julian Ospald</name>
	</maintainer>
	<use>
		<flag name='bundled-libs'>Use bundled libraries.</flag>
		<flag name='launcher'>Install qt launcher</flag>
	</use>
</pkgmetadata>



1.1                  games-action/hotline-miami/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for games-action/hotline-miami
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/games-action/hotline-miami/ChangeLog,v 1.1 2013/11/24 18:14:46 hasufell Exp $

*hotline-miami-1.0.9a (24 Nov 2013)

  24 Nov 2013; Julian Ospald <hasufell@g.o>
  +hotline-miami-1.0.9a.ebuild, +metadata.xml:
  initial import




1.1                  games-action/hotline-miami/hotline-miami-1.0.9a.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/hotline-miami-1.0.9a.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/hotline-miami-1.0.9a.ebuild?rev=1.1&content-type=text/plain

Index: hotline-miami-1.0.9a.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/hotline-miami/hotline-miami-1.0.9a.ebuild,v 1.1 2013/11/24 18:14:46 hasufell Exp $

# TODO: unbundle Qt5
#		remove emul-linux-x86* deps (bug 484060)

EAPI=5

inherit eutils games

DESCRIPTION="High-octane action game overflowing with raw brutality"
HOMEPAGE="http://www.devolverdigital.com/games/view/hotline-miami"
SRC_URI="hotlinemiami_v${PV}-Linux_28-05-2013.tar.gz"

LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bundled-libs +launcher"
RESTRICT="bindist fetch splitdebug"

MYGAMEDIR=${GAMES_PREFIX_OPT}/${PN}
QA_PREBUILT="${MYGAMEDIR#/}/lib/*
	${MYGAMEDIR#/}/Hotline
	${MYGAMEDIR#/}/hotline_launcher"

RDEPEND="
	amd64? (
		|| ( x11-libs/libX11[abi_x86_32] app-emulation/emul-linux-x86-xlibs )
		!bundled-libs? (
			media-gfx/nvidia-cg-toolkit[multilib]
			|| (
				( app-emulation/emul-linux-x86-soundlibs )
				( media-libs/libogg[abi_x86_32]
				media-libs/libvorbis[abi_x86_32]
				media-libs/openal[abi_x86_32] )
			)
		)
		launcher? (
			|| (
				( app-emulation/emul-linux-x86-xlibs )
				( media-libs/freetype[abi_x86_32]
				x11-libs/libXext[abi_x86_32]
				x11-libs/libXrandr[abi_x86_32]
				x11-libs/libXrender[abi_x86_32]
				x11-libs/libxcb[abi_x86_32] )
			)
		)
	)
	x86? (
		x11-libs/libX11
		!bundled-libs? (
			media-gfx/nvidia-cg-toolkit
			media-libs/libogg
			media-libs/libvorbis
			media-libs/openal
		)
		launcher? (
			media-libs/freetype
			x11-libs/libXext
			x11-libs/libXrandr
			x11-libs/libXrender
			x11-libs/libxcb
		)
	)"

S=${WORKDIR}

pkg_nofetch() {
	einfo "Please buy & download ${SRC_URI} from:"
	einfo "  https://www.humblebundle.com/store"
	einfo "and move it to ${DISTDIR}"
}

src_install() {
	insinto "${MYGAMEDIR}"
	doins HotlineMiami_GL.wad

	exeinto "${MYGAMEDIR}"
	doexe Hotline
	use launcher && doexe hotline_launcher

	exeinto "${MYGAMEDIR}/lib"
	use launcher && doexe lib/libQt5*
	use bundled-libs && doexe libCg* libopenal*

	games_make_wrapper ${PN} "./Hotline" "${MYGAMEDIR}" "${MYGAMEDIR}/lib"
	make_desktop_entry ${PN}
	if use launcher ; then
		games_make_wrapper ${PN}-launcher "./hotline_launcher" "${MYGAMEDIR}" "${MYGAMEDIR}/lib"
		make_desktop_entry ${PN}-launcher "${PN} (launcher)"
	fi

	prepgamesdirs
}



1.1                  games-action/hotline-miami/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/hotline-miami/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
DIST hotlinemiami_v1.0.9a-Linux_28-05-2013.tar.gz 190790687 SHA256 070300558ba52f75455d1645bba6dd956f460ada0d3839f8b3c3ac712ba957da SHA512 db9c6b11ac11933879e0f328c0fe1d4727d8d894716c0de457b4b948d4c11e901ffc6d83b140c83a82dc8ac82a8736976aecb3a2b90619dd904a54361c9510e9 WHIRLPOOL de1467ac72055bb9698435c91433798f86ee571534afc6311f764ba11fba827090fa4f10c3dde163deda1fe109430129385e0778972ba6ecdca144a99d36b3a3
EBUILD hotline-miami-1.0.9a.ebuild 2229 SHA256 8c94b332ec39a225b2940142eaf8318fb115f22588531331f7e7f1f2be96b666 SHA512 651f8948f8a481a1143b67af57c826f07c692e68e6aed554fefaeda2c29790095b79b6d3b60db9ebb0302a6b40e59bb694978e4d14a818b0ca9e3da840aedcbc WHIRLPOOL 82687251f2d146b2aa712101e5941352496e5025b3d64b4dcfef415198f47b9acf758decc5e40ad6cf88cfe5b7bfbd4e2c3a807819008bce3ce0391ea1ff1069
MISC ChangeLog 280 SHA256 3ecc4ec6f7136d37a0c3254a76c88d5623560f7b9b5db61c864e0f1ce0cfdd61 SHA512 51a70f1c8bc69dccd2300a50ceff8844c237f6d1ec7a77a2d4eb49143e1325918df96134c338deb49c183fc01b11a7258b82e98ba0c2c782e303148f4b12d7c1 WHIRLPOOL 1f368efb2262ccbb89a2ca14558e21f891679afc06972a9e7de23dca3408553d94306d3d6c9801c0b4aec73b9434e16efd480984f5ea7f30f7edbb0cef8714f7
MISC metadata.xml 378 SHA256 fad4f0c4d2e1d99c2f576527b249783ca61741d0a26c4c88f91feaeef7e4924e SHA512 7db361177e0be68e196418237054575e8cb2f23c3d44151fc8ad972bcd45a70412dd3cc8534bf385cff0cc18ee1952472cc395a2ec7852b36ae26941ead826b1 WHIRLPOOL e2229c123f39d1579ffe7534ceb4961ac6b8c81a101c8b22372af1124ff8cb517d19293b77c7f8040e0cc8226b58e2f15c2d81892622ed05dbb17b3ba2eb6bea