[gentoo-commits] gentoo-x86 commit in app-admin/gkrellm: ChangeLog metadata.xml gkrellm-2.3.2.ebuild gkrellm-2.2.5.ebuild gkrellm-2.2.10.ebuild gkrellm-2.3.0.ebuild gkrellm-2.2.9-r1.ebuild

[Jim Ramsay (lack)]

lack        08/11/05 18:18:10

  Modified:             ChangeLog metadata.xml
  Added:                gkrellm-2.3.2.ebuild
  Removed:              gkrellm-2.2.5.ebuild gkrellm-2.2.10.ebuild
                        gkrellm-2.3.0.ebuild gkrellm-2.2.9-r1.ebuild
  Log:
  Version cleanup, and version bump. Should address bug 224571 and bug 240052
  (Portage version: 2.2_rc12/cvs/Linux 2.6.26-gentoo-r1 i686)

Revision  Changes    Path
1.161                app-admin/gkrellm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/ChangeLog?rev=1.161&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/ChangeLog?rev=1.161&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/ChangeLog?r1=1.160&r2=1.161

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/gkrellm/ChangeLog,v
retrieving revision 1.160
retrieving revision 1.161
diff -u -r1.160 -r1.161
--- ChangeLog	27 Sep 2008 16:29:07 -0000	1.160
+++ ChangeLog	5 Nov 2008 18:18:10 -0000	1.161
@@ -1,6 +1,17 @@
 # ChangeLog for app-admin/gkrellm
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/ChangeLog,v 1.160 2008/09/27 16:29:07 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/ChangeLog,v 1.161 2008/11/05 18:18:10 lack Exp $
+
+*gkrellm-2.3.2 (05 Nov 2008)
+
+  05 Nov 2008; Jim Ramsay <lack@g.o>
+  -files/gkrellm-2.2.9-build.patch, -files/gkrellm-2.2.9-gnutls.patch,
+  -files/gkrellm-2.2.10-Makefile.patch, -files/gkrellm-mbmon-amd64.patch,
+  -files/gkrellm-2.2.10-build.patch, -files/gkrellm-2.2.10-gnutls.patch,
+  metadata.xml, -gkrellm-2.2.5.ebuild, -gkrellm-2.2.9-r1.ebuild,
+  -gkrellm-2.2.10.ebuild, -gkrellm-2.3.0.ebuild, +gkrellm-2.3.2.ebuild:
+  Version cleanup, and version bump. Should address bug 224571 and bug
+  240052.
 
   27 Sep 2008; Raúl Porcel <armin76@g.o> gkrellm-2.3.1.ebuild:
   arm stable wrt #231166



1.4                  app-admin/gkrellm/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/gkrellm/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	22 Feb 2007 21:47:23 -0000	1.3
+++ metadata.xml	5 Nov 2008 18:18:10 -0000	1.4
@@ -6,4 +6,18 @@
 		<email>lack@g.o</email>
 		<name>Jim Ramsay</name>
 	</maintainer>
+	<use>
+		<flag name="hddtemp">Enable monitoring harddrive temperatures via
+			<pkg>app-admin/hddtemp</pkg></flag>
+		<flag name="gnutls">Enable SSL support for mail checking with
+			<pkg>net-libs/gnutls</pkg> (overrides 'ssl' USE flag)</flag>
+		<flag name="ssl">Enable SSL support for mail checking with
+			<pkg>dev-libs/openssl</pkg></flag>
+		<flag name="lm_sensors">Enable monitoring sensors via
+			<pkg>sys-apps/lm_sensors</pkg></flag>
+		<flag name="X">Build both the X11 gui (gkrellm) and the server
+			(gkrellmd).  Disabling this flag builds the server only.</flag>
+		<flag name="ntlm">Enable NTLM authentication for mail checking with
+			<pkg>net-libs/libntlm</pkg></flag>
+	</use>
 </pkgmetadata>



1.1                  app-admin/gkrellm/gkrellm-2.3.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.2.ebuild?rev=1.1&content-type=text/plain

Index: gkrellm-2.3.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.2.ebuild,v 1.1 2008/11/05 18:18:10 lack Exp $

EAPI=2

inherit eutils multilib toolchain-funcs

DESCRIPTION="Single process stack of various system monitors"
HOMEPAGE="http://www.gkrellm.net/"
SRC_URI="http://members.dslextreme.com/users/billw/${PN}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="hddtemp gnutls lm_sensors nls ssl ntlm X kernel_FreeBSD"

RDEPEND=">=dev-libs/glib-2
	hddtemp? ( app-admin/hddtemp )
	gnutls? ( net-libs/gnutls )
	!gnutls? ( ssl? ( dev-libs/openssl ) )
	lm_sensors? ( sys-apps/lm_sensors )
	nls? ( virtual/libintl )
	ntlm? ( net-libs/libntlm )
	X? ( >=x11-libs/gtk+-2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

pkg_setup() {
	enewgroup gkrellmd
	enewuser gkrellmd -1 -1 -1 gkrellmd
	TARGET=
	use kernel_FreeBSD && TARGET="freebsd"
}

src_prepare() {
	sed -e 's:-O2 ::' \
		-e 's:override CC:CFLAGS:' \
		-i */Makefile || die "sed Makefile(s) failed"

	sed -e 's:#user\tnobody:user\tgkrellmd:' \
		-e 's:#group\tproc:group\tgkrellmd:' \
		-i server/gkrellmd.conf || die "sed gkrellmd.conf failed"

	sed -e "s:/usr/lib:/usr/$(get_libdir):" \
		-e "s:/usr/local/lib:/usr/local/$(get_libdir):" \
		-i src/${PN}.h || die "sed ${PN}.h failed"
}

src_compile() {
	if use X ; then
		local sslopt=""
		if use gnutls; then
			sslopt="without-ssl=yes"
		elif use ssl; then
			sslopt="without-gnutls=yes"
		else
			sslopt="without-ssl=yes without-gnutls=yes"
		fi

		emake ${TARGET} \
			CC="$(tc-getCC)" \
			LINK_FLAGS="$LDFLAGS -Wl,-E" \
			STRIP="" \
			INSTALLROOT="/usr" \
			INCLUDEDIR="/usr/include/gkrellm2" \
			LOCALEDIR="/usr/share/locale" \
			$(use nls || echo enable_nls=0) \
			$(use lm_sensors || echo without-libsensors=yes) \
			${sslopt} \
		|| die "emake failed"
	else
		cd server
		emake ${TARGET} \
			CC="$(tc-getCC)" \
			LINK_FLAGS="$LDFLAGS -Wl,-E" \
			STRIP="" \
			$(use lm_sensors || echo without-libsensors=yes) \
		|| die "emake failed"
	fi
}

src_install() {
	if use X ; then
		emake install${TARGET:+_}${TARGET} \
			$(use nls || echo enable_nls=0) \
			STRIP="" \
			INSTALLDIR="${D}/usr/bin" \
			INCLUDEDIR="${D}/usr/include" \
			LOCALEDIR="${D}/usr/share/locale" \
			PKGCONFIGDIR="${D}/usr/$(get_libdir)/pkgconfig" \
			MANDIR="${D}/usr/share/man/man1" \
		|| die "emake install failed"

		dohtml *.html

		newicon src/icon.xpm ${PN}.xpm
		make_desktop_entry ${PN} GKrellM ${PN}
	else
		dobin server/gkrellmd || die "dobin failed"

		insinto /usr/include/gkrellm2
		doins server/gkrellmd.h || die "doins failed"
	fi

	doinitd "${FILESDIR}"/gkrellmd || die "doinitd failed"
	doconfd "${FILESDIR}"/gkrellmd.conf || die "doconfd failed"

	insinto /etc
	doins server/gkrellmd.conf || die "doins failed"

	dodoc Changelog CREDITS README
}

pkg_postinst() {
	if use X ; then
		ewarn "The old executable name 'gkrellm2' has been removed."
		ewarn "Run 'gkrellm' instead."
	fi
}