[gentoo-commits] gentoo-x86 commit in sci-chemistry/chemtool: chemtool-1.6.14.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        14/02/11 19:00:09

  Modified:             ChangeLog
  Added:                chemtool-1.6.14.ebuild
  Log:
  Version BUmp, #501004
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.35                 sci-chemistry/chemtool/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/chemtool/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/chemtool/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/chemtool/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/chemtool/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	14 Aug 2013 12:53:30 -0000	1.34
+++ ChangeLog	11 Feb 2014 19:00:09 -0000	1.35
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/chemtool
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/chemtool/ChangeLog,v 1.34 2013/08/14 12:53:30 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/chemtool/ChangeLog,v 1.35 2014/02/11 19:00:09 jlec Exp $
+
+*chemtool-1.6.14 (11 Feb 2014)
+
+  11 Feb 2014; Justin Lecher <jlec@g.o> +chemtool-1.6.14.ebuild:
+  Version BUmp, #501004
 
   14 Aug 2013; Patrick Lauer <patrick@g.o> chemtool-1.6.13.ebuild:
   Whitespace



1.1                  sci-chemistry/chemtool/chemtool-1.6.14.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/chemtool/chemtool-1.6.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/chemtool/chemtool-1.6.14.ebuild?rev=1.1&content-type=text/plain

Index: chemtool-1.6.14.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/chemtool/chemtool-1.6.14.ebuild,v 1.1 2014/02/11 19:00:09 jlec Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=true

inherit autotools-utils eutils

DESCRIPTION="A GTK program for drawing organic molecules"
HOMEPAGE="http://ruby.chemie.uni-freiburg.de/~martin/chemtool/"
SRC_URI="http://ruby.chemie.uni-freiburg.de/~martin/chemtool/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="emf gnome nls"

RDEPEND="
	dev-libs/glib:2
	media-gfx/transfig
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/pango
	emf? ( media-libs/libemf )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

AUTOTOOLS_IN_SOURCE_BUILD=1

PATCHES=(
	"${FILESDIR}"/1.6.13-no-underlinking.patch
)

src_configure() {
	local myeconfargs=(
		--without-kdedir
		$(use_with gnome gnomedir /usr)
		$(use_enable emf)
		--enable-undo
		--enable-menu
		)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	insinto /usr/share/${PN}/examples
	doins "${S}"/examples/*
	if ! use nls; then rm -rf "${ED}"/usr/share/locale || die; fi

	insinto /usr/share/pixmaps
	doins chemtool.xpm
	make_desktop_entry ${PN} Chemtool ${PN} "Education;Science;Chemistry"
}