[gentoo-commits] repo/gentoo:master commit in: media-gfx/geeqie/

[Bernard Cafarelli]

commit:     9dadab9b25973b41b03184474315fcf6986a7a88
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 30 20:23:38 2019 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Tue Jul 30 20:47:02 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9dadab9b

media-gfx/geeqie: 1.5 bump

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 media-gfx/geeqie/Manifest          |  1 +
 media-gfx/geeqie/geeqie-1.5.ebuild | 95 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/media-gfx/geeqie/Manifest b/media-gfx/geeqie/Manifest
index 95acd2ee962..9d22d0eaa1c 100644
--- a/media-gfx/geeqie/Manifest
+++ b/media-gfx/geeqie/Manifest
@@ -1 +1,2 @@
 DIST geeqie-1.4.tar.xz 35881152 BLAKE2B 2932ac379abaee2b742b66daff544f29d7bf0aac82ff97f92e10ac7902ad874badcbb143f562c665d94f6297331090d0746373979a745f338a738078b72538a4 SHA512 a88b6dcf30847e38c109f5bc6436d93f6b4e1336a094c6b8a45db117830117120bf58f390afcd8a4b7aaf2934f995c3f75ac33a7faf56bfc2bcc9bd4eebfb205
+DIST geeqie-1.5.tar.xz 1585780 BLAKE2B 6dc0a30c26f25988cbd3fa81a916642504e9f6f280b03d78c820cbf5b453d8a392d3c8da8d482de24b3c39e7e9ba0663879d651c60a8061b8034d2c526007944 SHA512 2b87d543d8d77a4fec331fd1b73ca2038912362fc1f94c9b0f163dcc7c2dd58118e175c5540aecafb0581708ea5c2a5a321dde09f644e2322bd4ca5c0284b722

diff --git a/media-gfx/geeqie/geeqie-1.5.ebuild b/media-gfx/geeqie/geeqie-1.5.ebuild
new file mode 100644
index 00000000000..5323596a4a9
--- /dev/null
+++ b/media-gfx/geeqie/geeqie-1.5.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg-utils
+
+DESCRIPTION="A lightweight GTK image viewer forked from GQview"
+HOMEPAGE="http://www.geeqie.org"
+SRC_URI="http://www.geeqie.org/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc exif ffmpegthumbnailer gpu-accel gtk3 jpeg lcms lirc lua map nls pdf tiff xmp"
+
+RDEPEND="
+	virtual/libintl
+	doc? ( app-text/gnome-doc-utils )
+	ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
+	gpu-accel? ( media-libs/clutter-gtk )
+	gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? ( x11-libs/gtk+:2 )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	lirc? ( app-misc/lirc )
+	lua? ( >=dev-lang/lua-5.1:= )
+	map? ( media-libs/libchamplain:0.12 )
+	pdf? ( >=app-text/poppler-0.62[cairo] )
+	tiff? ( media-libs/tiff:0 )
+	xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
+	!xmp? ( exif? ( >=media-gfx/exiv2-0.17:= ) )"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+REQUIRED_USE="gpu-accel? ( gtk3 )
+	map? ( gpu-accel )"
+
+src_prepare() {
+	default
+
+	# Remove -Werror (gcc changes may add new warnings)
+	sed -e '/CFLAGS/s/-Werror //g' -i configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="--disable-dependency-tracking
+		--with-readmedir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable debug debug-log)
+		$(use_enable ffmpegthumbnailer)
+		$(use_enable gpu-accel)
+		$(use_enable gtk3)
+		$(use_enable jpeg)
+		$(use_enable lcms)
+		$(use_enable lua)
+		$(use_enable lirc)
+		$(use_enable map)
+		$(use_enable nls)
+		$(use_enable pdf)
+		$(use_enable tiff)"
+
+	if use exif || use xmp; then
+		myconf="${myconf} --enable-exiv2"
+	else
+		myconf="${myconf} --disable-exiv2"
+	fi
+
+	econf ${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	rm -f "${D}/usr/share/doc/${PF}/COPYING"
+	# Application needs access to the uncompressed file
+	docompress -x /usr/share/doc/${PF}/README.md
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+
+	elog "Some plugins may require additional packages"
+	elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
+	elog "- RAW images plugin: media-gfx/ufraw"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}