[gentoo-commits] repo/gentoo:master commit in: dev-python/dulwich/

[Michał Górny]

commit:     1909e1ebe530f44751263230cabcad11fce1422b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 30 05:49:01 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct 30 06:38:44 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1909e1eb

dev-python/dulwich: Bump to 0.20.50

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/dulwich/Manifest               |  1 +
 dev-python/dulwich/dulwich-0.20.50.ebuild | 59 +++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/dulwich/Manifest b/dev-python/dulwich/Manifest
index 55fa46047cca..ee7d775e744c 100644
--- a/dev-python/dulwich/Manifest
+++ b/dev-python/dulwich/Manifest
@@ -1 +1,2 @@
 DIST dulwich-0.20.46.tar.gz 426530 BLAKE2B 702564597a0367f454a396e4917d4fcd8b963d1847ddef688dccc7d7501f0073ae9a0ab422f31b8b0648210dafa953744ccf496b41fc75c7bea5090d75bf142c SHA512 4cc86afe90139d813d11ac2a8b96e84ca60ea28baab83a2af8da9a7cef2f3cdac647af858f5fc3806ae741a0b4fcf592d94f228adf8ab7b5b600be41f6acc356
+DIST dulwich-0.20.50.tar.gz 430389 BLAKE2B 1ea86fe00fa560311bdcff8c51904982a506fa670efb503f9103c5fb25036a792a87583fdf6435a6a6ec7bd6aaa2277c621359e1d99f55450c247fdc4be74e51 SHA512 506cc76f7deb8247b910fa4971e28eeda6ddd34703ac3c7a2f3b6525e6a9229bbec527b1965bebf7aa3da17b5adbd146916f247acacf9caf86d2494e60cc8626

diff --git a/dev-python/dulwich/dulwich-0.20.50.ebuild b/dev-python/dulwich/dulwich-0.20.50.ebuild
new file mode 100644
index 000000000000..afced5638714
--- /dev/null
+++ b/dev-python/dulwich/dulwich-0.20.50.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python implementation of the Git file formats and protocols"
+HOMEPAGE="
+	https://github.com/jelmer/dulwich/
+	https://pypi.org/project/dulwich/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+ Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		!hppa? ( !ia64? ( !s390? (
+			dev-python/gevent[${PYTHON_USEDEP}]
+			dev-python/geventhttpclient[${PYTHON_USEDEP}]
+		) ) )
+		app-crypt/gpgme[python,${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/fastimport[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs
+
+python_test() {
+	# remove interference from the tests that do stuff like user.name
+	unset GIT_AUTHOR_NAME GIT_AUTHOR_EMAIL GIT_AUTHOR_DATE \
+		GIT_COMMITTER_NAME GIT_COMMITTER_EMAIL GIT_COMMITTER_DATE EMAIL
+	# Do not use make check which rebuilds the extension and uses -Werror,
+	# causing unexpected failures.
+	"${EPYTHON}" -m unittest -v dulwich.tests.test_suite ||
+		die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}