[gentoo-commits] gentoo-x86 commit in sys-apps/mlocate: ChangeLog mlocate-0.24.ebuild

[Christian Faulhammer (fauli)]

fauli       11/05/06 22:36:14

  Modified:             ChangeLog
  Added:                mlocate-0.24.ebuild
  Log:
  version bump for bug 366237
  
  (Portage version: 2.1.9.42/cvs/Linux i686)

Revision  Changes    Path
1.87                 sys-apps/mlocate/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/mlocate/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/mlocate/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/mlocate/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/mlocate/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	9 Mar 2011 20:36:35 -0000	1.86
+++ ChangeLog	6 May 2011 22:36:14 -0000	1.87
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/mlocate
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/mlocate/ChangeLog,v 1.86 2011/03/09 20:36:35 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/mlocate/ChangeLog,v 1.87 2011/05/06 22:36:14 fauli Exp $
+
+*mlocate-0.24 (06 May 2011)
+
+  06 May 2011; Christian Faulhammer <fauli@g.o> +mlocate-0.24.ebuild:
+  version bump for bug 366237
 
   09 Mar 2011; Christian Faulhammer <fauli@g.o>
   mlocate-0.23.1-r1.ebuild:



1.1                  sys-apps/mlocate/mlocate-0.24.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/mlocate/mlocate-0.24.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/mlocate/mlocate-0.24.ebuild?rev=1.1&content-type=text/plain

Index: mlocate-0.24.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/mlocate/mlocate-0.24.ebuild,v 1.1 2011/05/06 22:36:14 fauli Exp $

EAPI="3"

inherit eutils

DESCRIPTION="Merging locate is an utility to index and quickly search for files"
HOMEPAGE="https://fedorahosted.org/mlocate/"
SRC_URI="https://fedorahosted.org/releases/m/l/mlocate/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="nls"

RDEPEND="!sys-apps/slocate
	!sys-apps/rlocate"
DEPEND="app-arch/xz-utils
	nls? ( sys-devel/gettext )"

pkg_setup() {
	enewgroup locate
}

src_configure() {
	econf $(use_enable nls) || die
}

src_compile() {
	emake groupname=locate || die
}

src_install() {
	emake groupname=locate DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog README NEWS

	insinto /etc
	doins "${FILESDIR}"/updatedb.conf || die
	doins "${FILESDIR}"/mlocate-cron.conf || die
	fperms 0644 /etc/{updatedb,mlocate-cron}.conf

	insinto /etc/cron.daily
	newins "${FILESDIR}/mlocate.cron-r2" mlocate
	fperms 0755 /etc/cron.daily/mlocate

	fowners 0:locate /usr/bin/locate
	fperms go-r,g+s /usr/bin/locate

	keepdir /var/lib/mlocate
	chown -R 0:locate "${D}"/var/lib/mlocate
	fperms 0750 /var/lib/mlocate
}

pkg_postinst() {
	elog "The database for the locate command is generated daily by a cron job,"
	elog "if you install for the first time you can run the updatedb command manually now."
	elog
	elog "Note that the /etc/updatedb.conf file is generic,"
	elog "please customize it to your system requirements."
}