[gentoo-commits] gentoo-x86 commit in dev-util/weka: weka-3.6.6-r1.ebuild ChangeLog weka-3.6.6.ebuild

[Miroslav Sulc (fordfrog)]

fordfrog    11/12/25 22:52:32

  Modified:             ChangeLog
  Added:                weka-3.6.6-r1.ebuild
  Removed:              weka-3.6.6.ebuild
  Log:
  dev-util/weka: added icon and desktop entry
  
  (Portage version: 2.1.10.43/cvs/Linux x86_64)

Revision  Changes    Path
1.44                 dev-util/weka/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/weka/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/weka/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/weka/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/weka/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	25 Dec 2011 22:42:24 -0000	1.43
+++ ChangeLog	25 Dec 2011 22:52:32 -0000	1.44
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/weka
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/weka/ChangeLog,v 1.43 2011/12/25 22:42:24 fordfrog Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/weka/ChangeLog,v 1.44 2011/12/25 22:52:32 fordfrog Exp $
+
+*weka-3.6.6-r1 (25 Dec 2011)
+
+  25 Dec 2011; Miroslav Šulc <fordfrog@g.o> -weka-3.6.6.ebuild,
+  +weka-3.6.6-r1.ebuild:
+  Added icon and desktop entry (bug #389877, thanks to Randall Wald
+  <rdwald@×××××.com>)
 
 *weka-3.6.6 (25 Dec 2011)
 



1.1                  dev-util/weka/weka-3.6.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/weka/weka-3.6.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/weka/weka-3.6.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: weka-3.6.6-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/weka/weka-3.6.6-r1.ebuild,v 1.1 2011/12/25 22:52:32 fordfrog Exp $

EAPI="3"

JAVA_PKG_IUSE="doc source"

inherit eutils java-pkg-2 java-ant-2 versionator

MY_P="${PN}-$(replace_all_version_separators '-')"
DESCRIPTION="A Java data mining package"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip"
HOMEPAGE="http://www.cs.waikato.ac.nz/ml/weka/"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"
DEPEND=">=virtual/jdk-1.5
	app-arch/unzip
	>=dev-java/javacup-0.11a_beta20060608:0"
RDEPEND=">=virtual/jre-1.5
	>=dev-java/javacup-0.11a_beta20060608:0"
IUSE=""

S="${WORKDIR}/${MY_P}"

EANT_BUILD_TARGET="exejar"
EANT_DOC_TARGET="docs"
JAVA_ANT_IGNORE_SYSTEM_CLASSES="true"

weka_get_max_memory() {
	if use amd64; then
		echo 512m
	else
		echo 256m
	fi
}

java_prepare() {
	unzip -qq "${PN}-src.jar" -d . || die "Failed to unpack the source"
	rm -v *.jar lib/*.jar || die
	rm -rf doc || die
	java-pkg_jar-from --into lib javacup
	epatch "${FILESDIR}"/${P}-build.xml.patch
	sed -i -e "s/256m/$(weka_get_max_memory)/g" build.xml || die
}

src_install() {
	java-pkg_dojar dist/${PN}.jar
	java-pkg_dolauncher weka --main "${PN}.gui.GUIChooser"

	# Really need a virtual to list all available drivers and pull the ones
	# instaled
	java-pkg_register-optional-dependency hsqldb,jdbc-mysql,mckoi-1

	use source && java-pkg_dosrc src/main/java/weka/

	dodoc README || die
	if use doc; then
		java-pkg_dojavadoc doc/
		insinto /usr/share/doc/${PF}
		doins WekaManual.pdf || die
	fi

	dodir /usr/share/${PN}/data/
	insinto /usr/share/${PN}/data/
	doins data/*

	newicon "${S}/weka.gif" "${PN}".png
	make_desktop_entry "${PN}" "Waikato Environment for Knowledge Analysis" "${PN}" "Education;Science;ArtificialIntelligence;" "Comment=Start Weka"
}