[gentoo-commits] gentoo-x86 commit in dev-python/pyzmq: pyzmq-14.0.1.ebuild ChangeLog

[Tiziano Mueller (dev-zero)]

dev-zero    13/12/03 08:14:54

  Modified:             ChangeLog
  Added:                pyzmq-14.0.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.11.63/cvs/Linux x86_64, signed Manifest commit with key 0x1E0CA85F!)

Revision  Changes    Path
1.38                 dev-python/pyzmq/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyzmq/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyzmq/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyzmq/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pyzmq/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	29 Nov 2013 22:46:24 -0000	1.37
+++ ChangeLog	3 Dec 2013 08:14:54 -0000	1.38
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyzmq
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyzmq/ChangeLog,v 1.37 2013/11/29 22:46:24 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyzmq/ChangeLog,v 1.38 2013/12/03 08:14:54 dev-zero Exp $
+
+*pyzmq-14.0.1 (03 Dec 2013)
+
+  03 Dec 2013; Tiziano Müller <dev-zero@g.o> +pyzmq-14.0.1.ebuild:
+  Version bump.
 
   29 Nov 2013; Pacho Ramos <pacho@g.o> pyzmq-13.1.0.ebuild:
   amd64 stable, bug #488738



1.1                  dev-python/pyzmq/pyzmq-14.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyzmq/pyzmq-14.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyzmq/pyzmq-14.0.1.ebuild?rev=1.1&content-type=text/plain

Index: pyzmq-14.0.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pyzmq/pyzmq-14.0.1.ebuild,v 1.1 2013/12/03 08:14:54 dev-zero Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit distutils-r1 toolchain-funcs

DESCRIPTION="PyZMQ is a lightweight and super-fast messaging library built on top of the ZeroMQ library"
HOMEPAGE="http://www.zeromq.org/bindings:python http://pypi.python.org/pypi/pyzmq"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="examples green test"

PY2_USEDEP=$(python_gen_usedep 'python2*')

RDEPEND=">=net-libs/zeromq-2.1.9
	green? ( dev-python/gevent[${PY2_USEDEP}] )"
DEPEND="${RDEPEND}
	test? (
		!arm? ( dev-python/cffi[${PYTHON_USEDEP}] )
		dev-python/nose[${PY2_USEDEP}]
		dev-python/gevent[${PY2_USEDEP}]
		dev-python/cython[${PY2_USEDEP}]
	)"

REQUIRED_USE="test? ( !arm )"

python_configure_all() {
	tc-export CC
}

python_compile() {
	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
	distutils-r1_python_compile
}

python_test() {
	if [[ "${EPYTHON}" == python3* ]]; then
		einfo "Skipping python3 due to many incompatibilities"
	else
		nosetests -svw "${BUILD_DIR}/lib/" || die "Tests fail with ${EPYTHON}"
	fi
}

python_install_all() {
	distutils-r1_python_install_all
	if use examples; then
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi
}