[gentoo-commits] gentoo-x86 commit in net-libs/libgadu: libgadu-1.12.1.ebuild ChangeLog

[Manuel Rueger (mrueg)]

mrueg       15/01/03 13:43:05

  Modified:             ChangeLog
  Added:                libgadu-1.12.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.91                 net-libs/libgadu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libgadu/ChangeLog?rev=1.91&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libgadu/ChangeLog?rev=1.91&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libgadu/ChangeLog?r1=1.90&r2=1.91

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libgadu/ChangeLog,v
retrieving revision 1.90
retrieving revision 1.91
diff -u -r1.90 -r1.91
--- ChangeLog	23 Sep 2014 00:55:37 -0000	1.90
+++ ChangeLog	3 Jan 2015 13:43:05 -0000	1.91
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libgadu
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libgadu/ChangeLog,v 1.90 2014/09/23 00:55:37 reavertm Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libgadu/ChangeLog,v 1.91 2015/01/03 13:43:05 mrueg Exp $
+
+*libgadu-1.12.1 (03 Jan 2015)
+
+  03 Jan 2015; Manuel Rüger <mrueg@g.o> +libgadu-1.12.1.ebuild:
+  Version bump.
 
   23 Sep 2014; Maciej Mrozowski <reavertm@g.o> -libgadu-1.11.0.ebuild,
   -libgadu-1.11.1.ebuild:



1.1                  net-libs/libgadu/libgadu-1.12.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libgadu/libgadu-1.12.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libgadu/libgadu-1.12.1.ebuild?rev=1.1&content-type=text/plain

Index: libgadu-1.12.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libgadu/libgadu-1.12.1.ebuild,v 1.1 2015/01/03 13:43:05 mrueg Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=1

inherit autotools-utils

DESCRIPTION="This library implements the client side of the Gadu-Gadu protocol"
HOMEPAGE="http://toxygen.net/libgadu/"
SRC_URI="https://github.com/wojtekka/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="LGPL-2.1"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos"
SLOT="0"
IUSE="doc gnutls ssl static-libs test threads"

REQUIRED_USE="
	gnutls? ( ssl )
"
COMMON_DEPEND="
	>=dev-libs/protobuf-c-0.15
	sys-libs/zlib
	ssl? (
		gnutls? ( net-libs/gnutls )
		!gnutls? ( >=dev-libs/openssl-0.9.6m )
	)
"
DEPEND="${COMMON_DEPEND}
	doc? ( app-doc/doxygen )
	test? (
		dev-libs/expat
		dev-libs/libxml2:2
		net-misc/curl
	)
"
RDEPEND="${COMMON_DEPEND}
	!=net-im/kadu-0.6.0.2
	!=net-im/kadu-0.6.0.1
"

AUTOTOOLS_IN_SOURCE_BUILD=1

PATCHES=(
	"${FILESDIR}/${PN}-1.12.0-tests.patch"
)

DOCS=(AUTHORS ChangeLog NEWS README)

src_configure() {
	local myeconfargs=(
		--with-protobuf
		$(use_enable test tests)
		$(use_with threads pthread)
	)

	if use ssl; then
		myeconfargs+=(
			$(use_with gnutls gnutls)
			$(use_with !gnutls openssl)
		)
	else
		myeconfargs+=(
			--without-gnutls
			--without-openssl
		)
	fi

	autotools-utils_src_configure
}

src_install() {
	use doc && HTML_DOCS=(docs/html/)
	autotools-utils_src_install
}